Arduino mit Touchscreen verliert Kalibrierung nach Neustart

[Nick N. (nick_hb)]

Moin zusammen,

da ich hier bereits einige Male wirklich gute Hinweise sammeln konnte 
und nun bei meinem neuen Projekt nicht wirklich weiter komme, wollte ich 
es einmal mit einem eigenen Thread versuchen.

Ich habe mir ein TouchScreen Panel mit passendem Shield für einen 
Arduino Mega 2560 geholt, um allg. Erfahrungen mit Displays zu sammeln.

http://www.sainsmart.com/arduino/arduino-shields/lcd-shields/sainsmart-3-2-tft-lcd-display-touch-panel-pcb-adapter-sd-slot-for-arduino-2560.html

http://www.sainsmart.com/arduino/arduino-shields/lcd-shields/sainsmart-tft-lcd-adjustable-shield-for-arduino-mega-2560-r3-1280-a082-plug.html

Bis Dato habe ich mich an die Bibliotheken

UTFT
http://www.rinkydinkelectronics.com/library.php?id=51

und UTouch
http://www.rinkydinkelectronics.com/library.php?id=55

gehalten.

UTouch enthält einige Beispiele für das Touch Display, welche an sich 
auch alle funktionieren.
Zunächst habe ich das UTouch_Calibration.ino example implementiert, um 
die entsprechenden Kalibrierdaten zu erhalten und in eine Header Datei 
"UTouchCD.h" einzubinden.
Danach funktionierten auch soweit alle anderen Beispiele und auch die 
Touchfunktion.



Nun zu meinem eigentlichen Problem
Wenn ich die Hardware (Arduino) neustarte (einmal von der 
Spannungsversorgung - 12V oder USB - trenne), verliert er die 
Kalibrierung für die Touchfunktion. Das äußert sich so, dass ein Druck 
auf Pos. X an Pos. Y erkannt wird.

Wenn ich das Programm anschließend mit der Arduino Software wieder neu 
implementiere, funktioniert wieder alles wunderbar (Druck auf Pos. X 
wird an Pos. X erkannt) ohne, dass etwas verändert wurde.


Was ich bereits Probiert habe
Es war nicht besonders umfangreich, aber ich habe versucht die 
Kalibrierdaten /CAL_X, CAL_Y, CAL_S/ außerhalb der Header Datei direkt 
in die /void loop()/, /void setup()/,... zu schreiben. Leider ohne 
erfolg.



Hoffe ich habe das Problem und die verwendete Hard-, Software 
ausreichend beschrieben und ihr könnt mir weiterhelfen.

Viele Grüße


UTouch_ButtonTest.ino

// UTouch_ButtonTest 
// Copyright (C)2015 Rinky-Dink Electronics, Henning Karlsen. All right reserved
// web: http://www.RinkyDinkElectronics.com/
//
// This program is a quick demo of how create and use buttons.
//
// This program requires the UTFT library.
//
// It is assumed that the display module is connected to an
// appropriate shield or that you know how to change the pin 
// numbers in the setup.
//

#include <UTFT.h>
#include <UTouch.h>
#include <UTouchCD.h>

// Initialize display
// ------------------
// Set the pins to the correct ones for your development board
// -----------------------------------------------------------
// Standard Arduino Uno/2009 Shield            : <display model>,19,18,17,16
// Standard Arduino Mega/Due shield            : <display model>,38,39,40,41
// CTE TFT LCD/SD Shield for Arduino Due       : <display model>,25,26,27,28
// Teensy 3.x TFT Test Board                   : <display model>,23,22, 3, 4
// ElecHouse TFT LCD/SD Shield for Arduino Due : <display model>,22,23,31,33
//
// Remember to change the model parameter to suit your display module!
UTFT    myGLCD(ITDB32S,38,39,40,41);

// Initialize touchscreen
// ----------------------
// Set the pins to the correct ones for your development board
// -----------------------------------------------------------
// Standard Arduino Uno/2009 Shield            : 15,10,14, 9, 8
// Standard Arduino Mega/Due shield            :  6, 5, 4, 3, 2
// CTE TFT LCD/SD Shield for Arduino Due       :  6, 5, 4, 3, 2
// Teensy 3.x TFT Test Board                   : 26,31,27,28,29
// ElecHouse TFT LCD/SD Shield for Arduino Due : 25,26,27,29,30
//
UTouch  myTouch( 6, 5, 4, 3, 2);

// Declare which fonts we will be using
extern uint8_t BigFont[];

int x, y;
char stCurrent[20]="";
int stCurrentLen=0;
char stLast[20]="";

/*************************
**   Custom functions   **
*************************/


void drawButtons()
{
// Draw the upper row of buttons
  for (x=0; x<5; x++)
  {
    myGLCD.setColor(0, 0, 255);
    myGLCD.fillRoundRect (10+(x*60), 10, 60+(x*60), 60);
    myGLCD.setColor(255, 255, 255);
    myGLCD.drawRoundRect (10+(x*60), 10, 60+(x*60), 60);
    myGLCD.printNumI(x+1, 27+(x*60), 27);
  }
// Draw the center row of buttons
  for (x=0; x<5; x++)
  {
    myGLCD.setColor(0, 0, 255);
    myGLCD.fillRoundRect (10+(x*60), 70, 60+(x*60), 120);
    myGLCD.setColor(255, 255, 255);
    myGLCD.drawRoundRect (10+(x*60), 70, 60+(x*60), 120);
    if (x<4)
      myGLCD.printNumI(x+6, 27+(x*60), 87);
  }
  myGLCD.print("0", 267, 87);
// Draw the lower row of buttons
  myGLCD.setColor(0, 0, 255);
  myGLCD.fillRoundRect (10, 130, 150, 180);
  myGLCD.setColor(255, 255, 255);
  myGLCD.drawRoundRect (10, 130, 150, 180);
  myGLCD.print("Clear", 40, 147);
  myGLCD.setColor(0, 0, 255);
  myGLCD.fillRoundRect (160, 130, 300, 180);
  myGLCD.setColor(255, 255, 255);
  myGLCD.drawRoundRect (160, 130, 300, 180);
  myGLCD.print("Enter", 190, 147);
  myGLCD.setBackColor (0, 0, 0);
}

void updateStr(int val)
{
  if (stCurrentLen<20)
  {
    stCurrent[stCurrentLen]=val;
    stCurrent[stCurrentLen+1]='\0';
    stCurrentLen++;
    myGLCD.setColor(0, 255, 0);
    myGLCD.print(stCurrent, LEFT, 224);
  }
  else
  {
    myGLCD.setColor(255, 0, 0);
    myGLCD.print("BUFFER FULL!", CENTER, 192);
    delay(500);
    myGLCD.print("            ", CENTER, 192);
    delay(500);
    myGLCD.print("BUFFER FULL!", CENTER, 192);
    delay(500);
    myGLCD.print("            ", CENTER, 192);
    myGLCD.setColor(0, 255, 0);
  }
}

// Draw a red frame while a button is touched
void waitForIt(int x1, int y1, int x2, int y2)
{
  myGLCD.setColor(255, 0, 0);
  myGLCD.drawRoundRect (x1, y1, x2, y2);
  while (myTouch.dataAvailable())
    myTouch.read();
  myGLCD.setColor(255, 255, 255);
  myGLCD.drawRoundRect (x1, y1, x2, y2);
}

/*************************
**  Required functions  **
*************************/

void setup()
{
// Initial setup
  myGLCD.InitLCD();
  myGLCD.clrScr();

  myTouch.InitTouch();
  myTouch.setPrecision(PREC_MEDIUM);

  myGLCD.setFont(BigFont);
  myGLCD.setBackColor(0, 0, 255);
  drawButtons();  
}

void loop()
{
  while (true)
  {
    if (myTouch.dataAvailable())
    {
      myTouch.read();
      x=myTouch.getX();
      y=myTouch.getY();
      
      if ((y>=10) && (y<=60))  // Upper row
      {
        if ((x>=10) && (x<=60))  // Button: 1
        {
          waitForIt(10, 10, 60, 60);
          updateStr('1');
        }
        if ((x>=70) && (x<=120))  // Button: 2
        {
          waitForIt(70, 10, 120, 60);
          updateStr('2');
        }
        if ((x>=130) && (x<=180))  // Button: 3
        {
          waitForIt(130, 10, 180, 60);
          updateStr('3');
        }
        if ((x>=190) && (x<=240))  // Button: 4
        {
          waitForIt(190, 10, 240, 60);
          updateStr('4');
        }
        if ((x>=250) && (x<=300))  // Button: 5
        {
          waitForIt(250, 10, 300, 60);
          updateStr('5');
        }
      }

      if ((y>=70) && (y<=120))  // Center row
      {
        if ((x>=10) && (x<=60))  // Button: 6
        {
          waitForIt(10, 70, 60, 120);
          updateStr('6');
        }
        if ((x>=70) && (x<=120))  // Button: 7
        {
          waitForIt(70, 70, 120, 120);
          updateStr('7');
        }
        if ((x>=130) && (x<=180))  // Button: 8
        {
          waitForIt(130, 70, 180, 120);
          updateStr('8');
        }
        if ((x>=190) && (x<=240))  // Button: 9
        {
          waitForIt(190, 70, 240, 120);
          updateStr('9');
        }
        if ((x>=250) && (x<=300))  // Button: 0
        {
          waitForIt(250, 70, 300, 120);
          updateStr('0');
        }
      }

      if ((y>=130) && (y<=180))  // Upper row
      {
        if ((x>=10) && (x<=150))  // Button: Clear
        {
          waitForIt(10, 130, 150, 180);
          stCurrent[0]='\0';
          stCurrentLen=0;
          myGLCD.setColor(0, 0, 0);
          myGLCD.fillRect(0, 224, 319, 239);
        }
        if ((x>=160) && (x<=300))  // Button: Enter
        {
          waitForIt(160, 130, 300, 180);
          if (stCurrentLen>0)
          {
            for (x=0; x<stCurrentLen+1; x++)
            {
              stLast[x]=stCurrent[x];
            }
            stCurrent[0]='\0';
            stCurrentLen=0;
            myGLCD.setColor(0, 0, 0);
            myGLCD.fillRect(0, 208, 319, 239);
            myGLCD.setColor(0, 255, 0);
            myGLCD.print(stLast, LEFT, 208);
          }
          else
          {
            myGLCD.setColor(255, 0, 0);
            myGLCD.print("BUFFER EMPTY", CENTER, 192);
            delay(500);
            myGLCD.print("            ", CENTER, 192);
            delay(500);
            myGLCD.print("BUFFER EMPTY", CENTER, 192);
            delay(500);
            myGLCD.print("            ", CENTER, 192);
            myGLCD.setColor(0, 255, 0);
          }
        }
      }
    }
  }
}

UTouchCD.h

// UTouchCD.h
// ----------
//
// Since there are slight deviations in all touch screens you should run a
// calibration on your display module. Run the UTouch_Calibration sketch
// that came with this library and follow the on-screen instructions to
// update this file.
//
// Remember that is you have multiple display modules they will probably 
// require different calibration data so you should run the calibration
// every time you switch to another module.
// You can, of course, store calibration data for all your modules here
// and comment out the ones you dont need at the moment.
//

// These calibration settings works with my ITDB02-3.2S.
// They MIGHT work on your 320x240 display module, but you should run the
// calibration sketch anyway. If you are using a display with any other
// resolution you MUST calibrate it as these settings WILL NOT work.


#define CAL_X 0x0038CF1AUL
#define CAL_Y 0x03C60110UL
#define CAL_S 0x000EF13FUL

[Frank E. (Firma: Q3) (qualidat)]

Um diese Uhrzeit kann ich den Sourcecode nicht mehr nachvollziehen, aber 
ganz allgemein: Man sollte die bei der Kalibrierung gefundenen 
Korrekturdaten ins EEPROM schreiben, dann überstehen sie auch den 
nächsten Neustart.

Siehe: http://arduino.cc/en/Tutorial/EEPROMWrite

[Nick_N (Gast)]

Hey Frank,

vielen Dank für die schnelle Antwort. Leider bin ich noch nicht dazu 
gekommen mich mit der Lösung zu beschäftigen, werde aber auf jeden Fall 
die Tage Rückmeldung geben! :-)

[Kabookie (Gast)]

Hallo Nick,
ich habe leider genau das selbe Problem. Hast du inzwischen eine Lösung 
gefunden?
beste Grüße

[Nick N. (nick_hb)]

Hi Kabookie,

es hat sich rausgestellt, dass in einer der Konfig-Dateien von "UTouch" 
ein Fehler war.

Die Datei selbst findest du unter:

/Users/<Benutzer>/Documents/Arduino/libraries/UTouch/hardware/avr

und dort "HW_AVR.inc".

Was du nun macht ist in der letzten For-Schleife einen Delay einbauen, 
damit er zwischen dem Hochziehen der beiden clk Pins und der erneuten 
Abfrage einen Moment wartet.

void UTouch::touch_WriteData(byte data)
{
  byte temp;

  temp=data;
  cbi(P_CLK, B_CLK);

  for(byte count=0; count<8; count++)
  {
    if(temp & 0x80)
      sbi(P_DIN, B_DIN);
    else
      cbi(P_DIN, B_DIN);
    temp = temp << 1; 
    cbi(P_CLK, B_CLK);                
    sbi(P_CLK, B_CLK);
  }
}

word UTouch::touch_ReadData()
{
  word data = 0;

  for(byte count=0; count<12; count++)
  {
    data <<= 1;
    sbi(P_CLK, B_CLK);
    cbi(P_CLK, B_CLK);
    delayMicroseconds(1);
    if (rbi(P_DOUT, B_DOUT))
      data++;
  }
  return(data);
}

Und schon sollte das Ganze funktionieren.
Viel Erfolg

[Kabookie (Gast)]

Hallo Nick,
hat super funktioniert! Danke für die schnelle Hilfe!
beste Grüße

[Mares (Gast)]

Hallo zusammen
Habe das gleiche Problem.
Habe IDE 1.8.3 folgende Utouch / URTouch Dateien versucht.

void URTouch::touch_WriteData(byte data)
{
  byte temp;

  temp=data;
  cbi(P_CLK, B_CLK);

  for(byte count=0; count<8; count++)
  {
    if(temp & 0x80)
      sbi(P_DIN, B_DIN);
    else
      cbi(P_DIN, B_DIN);
    temp = temp << 1;
    cbi(P_CLK, B_CLK);
    sbi(P_CLK, B_CLK);
  }
}

word URTouch::touch_ReadData()
{
  word data = 0;

  for(byte count=0; count<12; count++)
  {
    data <<= 1;
    sbi(P_CLK, B_CLK);
    cbi(P_CLK, B_CLK);
    if (rbi(P_DOUT, B_DOUT))
      data++;
  }
  return(data);
}







oder



void UTouch::touch_WriteData(byte data)
{
  byte temp;

  temp=data;
  cbi(P_CLK, B_CLK);

  for(byte count=0; count<8; count++)
  {
    if(temp & 0x80)
      sbi(P_DIN, B_DIN);
    else
      cbi(P_DIN, B_DIN);
    temp = temp << 1;
    cbi(P_CLK, B_CLK);
    sbi(P_CLK, B_CLK);
  }
}

word UTouch::touch_ReadData()
{
  word data = 0;

  for(byte count=0; count<12; count++)
  {
    data <<= 1;
    sbi(P_CLK, B_CLK);
    cbi(P_CLK, B_CLK);
    if (rbi(P_DOUT, B_DOUT))
      data++;
  }
  return(data);
}




Leider ohne Erfolg.

Wer kann helfen?

Gruss

[Nick N. (nick_hb)]

@Mares

Guck mal zwei Beträge nach oben. In deiner 
/Users/<Benutzer>/Documents/Arduino/libraries/UTouch/hardware/avr/HW_AVR 
.inc
Datei fehlt ein delay.

Hast dir die anderen Beiträge nicht angeguckt?

Gruß Nick

[Erich J. (erich24)]

Hallo allgemein

Dank Nick hab ich zufällig auch ein Problem mit meinem 7" Display
am Arduino Mega gelöst. Mit einem Mega Clone liefen die Testprogramme 
nur manchmal. Da ich auch original Megas habe, probierte ich diese mit 
dem TFT Touch -> die Programme liefen sofort problemlos.

Dann habe ich obigen Beitrag vom Nick gelesen und die Änderungen 
durchgeführt und siehe -> nun laufen auch die Clone problemlos mit dem 
Touch.

Vielen Dank für den Tip
Erich