DMX Demultiplexer (Atmega8515-16)

[Rouven F. (Firma: Keine) (madmax1973)]

Hallo Leute ich brauche mal etwas Hilfe von den Programmieren unter 
euch.
Ich bin gerade dabei mir einen DMX Demultiplexer aufzubauen.
Projekt habe ich im Netz gefunden allerdings möchte ich das ding etwas 
modifiziert haben. Und zwar ist das ein Analog Demux Spannung am Ausgang 
von 0-5V je nach DMX Wert. Ich möchte es aber so haben das der Ausgang 
TTL wird dh. ab dem DMX wert 127 einfach an dh. auf den Ausgang 5V. 
Dafür müsste der Code umgeschrieben werden bzw angepasst. Der Code ist 
offiziell verfügbar und darf auch geändert werden.

;**** A P P L I C A T I O N   N O T E   ************************************
;*
;* Title    : 8ch DMX512 Demultiplexer 
;* Version    : v1.2
;* Last updated          : 02.11.07
;* Target    : Transceiver Rev.3.01 [ATmega8515]
;*
;* written by hendrik hoelscher, www.hoelscher-hi.de
;***************************************************************************
; This program is free software; you can redistribute it and/or 
; modify it under the terms of the GNU General Public License 
; as published by the Free Software Foundation; either version2 of 
; the License, or (at your option) any later version. 
;
; This program is distributed in the hope that it will be useful, 
; but WITHOUT ANY WARRANTY; without even the implied warranty of 
; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU 
; General Public License for more details. 
;
; If you have no copy of the GNU General Public License, write to the 
; Free Software Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA. 
;
; For other license models, please contact the author.
;
;***************************************************************************

.include "m8515def.inc"

;Register and Pin definitions

.def tempL         = r16
.def tempH        = r17
.def Flags        = r18
.def DMXstate      = r19
.def null        = r2
.def status        = r3
.def IndPat        = r4
.def dimm_count      = r20
.def SREGbuf      = r5

.equ DMX_FIELD=    0x60     ;SRAM-Beginn
.equ DMX_CHANNELS= 8
.equ PWM_FIELD=     0x68
.equ F_OSC=        8000
.equ WIDTH=        105      ;Offset zwischen Steps
.equ IND_OFFSET=   550       ;Offset für indicator-Timer (14Hz)

;***** special Flags

#define  VALID_DMX       (0)
#define  SIGNAL_COMING  (1)

#define  DO_IND      (6)
#define  DATA_REFRESHED (7)
#define  DATA_IND    (7)



;interrupt vectors
  
  rjmp init     ;reset vector address
  reti      ;External Interrupt0 Vector Address
  reti      ;External Interrupt1 Vector Address
  reti      ;Input Capture1 Interrupt Vector Address
  rjmp LED_indicator    ;Output Compare1A Interrupt Vector Address
  reti      ;Output Compare1B Interrupt Vector Address
  reti      ;Overflow1 Interrupt Vector Address
  reti      ;Overflow0 Interrupt Vector Address
  reti      ;SPI Interrupt Vector Address
  rjmp get_byte  ;UART Receive Complete Interrupt Vector Address
  reti      ;UART Data Register Empty Interrupt Vector Address
  reti      ;UART Transmit Complete Interrupt Vector Address
  reti      ;Analog Comparator Interrupt Vector Address
  reti      ;External Interrupt2 Vector Address
  rjmp pwm    ;Output Compare0 Interrupt Vector Address
  reti      ; EEPROM Interrupt Vector Address
  reti      ; SPM complete Interrupt Vector Address
  reti      ; SPM complete Interrupt Vector Address

; INIT

init:

; Stack
  ldi    tempH,high(RAMEND)
  ldi    tempL,low(RAMEND)
  out    SPH,tempH
  out    SPL,tempL

; WATCHDOG
  wdr
  ldi   tempL, (1<<WDE)|(1<<WDCE)
  out   WDTCR, tempL
  ldi   tempL, (1<<WDE)|(1<<WDCE)|(1<<WDP2)|(1<<WDP1)
  out   WDTCR, tempL
  wdr                        ;set prescaler @0,5s

; PortA
  ser   tempL
  out   DDRA, tempL
  clr   tempL
  out   PortA, tempL               ;low Outputs

; PortB
  ;**unused**

; PortD
  ldi   tempL, 0b10000100
  out   DDRD, tempL
  ldi   tempL, 0b01111000
  out   PortD, tempL               ;DMX & Spare , LED1 on

; PortE
  ldi   tempL, 0b00000001
  out   DDRE, tempL
  ser    tempL
  out   PortE, tempL               ;LED2 off, BIT9 & OPTION Pullup

; Timers
  ldi   tempL, (1<<CS00)|(1<<WGM01)        ;set counter0 @clock frequency, CTC mode
  out   TCCR0, tempL
  ldi    tempL, WIDTH
  out    OCR0, tempL
  clr    tempL
  out    TCCR1A, tempL
  ldi   tempL, (1<<CS10)|(1<<CS12)|(1<<WGM12)   ;set counter1 @clock/1024 frequency
  out   TCCR1B, tempL
  ldi    tempL, low(IND_OFFSET)
  ldi    tempH, high(IND_OFFSET)
  out    OCR1AH, tempH
  out    OCR1AL, tempL
  ldi   tempL,   (1<<OCIE0)|(1<<OCIE1A)      ;aktivate compare interrupts
  out   TIMSK, tempL
    
  rcall  init_dmx
  rcall  init_indicate
  
; set Register
  clr   null
  ldi   dimm_count, 0xFF
  ldi    Flags, 0                ;clear Flags
  
; memory
    ldi    ZH, high(PWM_FIELD)
    ldi    ZL,  low(PWM_FIELD)
    ldi   tempL, DMX_CHANNELS
  write_mem:  
    st     Z+, null
    dec    tempL
    brne  write_mem    

    wdr
    sei

    clr   tempL                ;wait for perepherials 
    clr    tempH
  init_loop:
    dec    tempL
    brne  init_loop
    dec    tempH
    brne  init_loop

main:   sbrs  Flags, DO_IND
    rjmp  main
    cbr    Flags, (1<<DO_IND)
    rcall  indicate_flags            ;LED indicator

    rjmp  main

; ***************************PWM-Ausgabe ****************************************
pwm:              ; CALLED EVERY 12.5µs (80kHz)
    in      SREGbuf, SREG
    push  tempL


    ldi    ZH,high(PWM_FIELD)      ;set data-pointer  
    ldi    ZL,low(PWM_FIELD);


      ld    tempL,Z+          ;1
    cp    tempL, dimm_count
    ror    status
    ld    tempL,Z+          ;2
    cp    tempL, dimm_count
    ror    status
    ld    tempL,Z+          ;3
    cp    tempL, dimm_count
    ror    status
    ld    tempL,Z+          ;4
    cp    tempL, dimm_count
    ror    status
    ld    tempL,Z+          ;5 
    cp    tempL, dimm_count
    ror    status
    ld    tempL,Z+          ;6 
    cp    tempL, dimm_count
    ror    status
    ld    tempL,Z+          ;7 
    cp    tempL, dimm_count
    ror    status
    ld    tempL,Z            ;8 
    cp    tempL, dimm_count
    ror    status


      sbic  PinD, PD4
      com    status
      out   PORTA,status  ;fire
      
    sbrc  dimm_count, 7
    rjmp  pwm_inc
    sbr    dimm_count, (1<<7)      ;toggle msb
     pwm_exit:
    pop    tempL
    out     SREG, SREGbuf
    reti

  
  pwm_inc:
    inc    dimm_count
    cbr    dimm_count, (1<<7)
    tst    dimm_count
    brne  pwm_exit

    ldi    dimm_count, 0x80
    out    TCNT0, null

    ldi    ZH,high(DMX_FIELD)      ;refresh  
    ldi    ZL,low(DMX_FIELD);
    ld    tempL, Z+
    std    Z +7, tempL
    ld    tempL, Z+
    std    Z +7, tempL
    ld    tempL, Z+
    std    Z +7, tempL
    ld    tempL, Z+
    std    Z +7, tempL
    ld    tempL, Z+
    std    Z +7, tempL
    ld    tempL, Z+
    std    Z +7, tempL
    ld    tempL, Z+
    std    Z +7, tempL
    ld    tempL, Z
    std    Z +8, tempL

    rjmp  pwm_exit

    
;****************************** LED INDICATOR ***********************************

LED_indicator:
    in      SREGbuf, SREG
    wdr            ;reset Watchdog
    sbr    Flags, (1<<DO_IND)
    out    SREG, SREGbuf
    reti


nix: rjmp nix


.include "lib_dmx_in.asm"
.include "lib_indicate.asm"

im Anhang auch mal die drei original Dateien die dem Projektarchiv 
angehören.

schönen Gruss

[Max D. (max_d)]

Willst du einen fertigen DMX-Demultiplexer haben ?
oder willst du verstehen wie alles funktioniert ?

[Rouven F. (Firma: Keine) (madmax1973)]

Klar möchte ich verstehen was am Code geändert werden muss :-) die 
Platine ist fertig geht jetzt nur noch um den geänderten Code

[Max D. (max_d)]

Der Code in diesem Projekt ist optimierter Assemblercode und dafür 
ausgelegt an PORTA die Soft-PWM zu machen. Als Anfangspunkt nicht ideal. 
Wenn es nur um das "geht irgendwie" geht, dann kann man die PWM-Funktion 
unterdrücken indem man dem "dimm_count" register einen festen 
Schwellwert (127) zuweißt anstatt es zu inkrementieren.


Die "saubere" Lösung wäre allerdings den Code entsprechend neu zu 
schreiben.

Wenn du das Gesamtkonzept verstehen willst, dann würde ich dir empfehlen 
ein komplett eigenes Projekt zu basteln. DMX ist von den Ansprüchen ja 
relativ überschaubar.

[Rouven F. (Firma: Keine) (madmax1973)]

Komplett neu schreiben wäre sicherlich die beste Lösung und auch um es 
zu verstehen. Das würde ich im zweiten schritt machen. Im moment geht es 
mir erstmal darum zu testen ob das was ich mit dem Demux vor habe so 
überhaupt läuft. Darum würde mir für den Anfang hauptsache geht erstmal 
reichen.

[Max D. (max_d)]

Dann würde ich wie gesagt einfach dimm_count mit 127 laden und die 
increment routine rausschmeißen.

Ist aber wie gesagt etwas pfuschig, aber sollte funktionieren.

[Rouven F. (Firma: Keine) (madmax1973)]

Hast du ein Beispiel wie ich das im Code ändern muss ?
Kenne mich mit assembler nicht aus

[janku88 (Gast)]

Hallo,

bin beim Suchen auf diesen Beitrag gestoßen, da ich das gleiche machen 
will um Relais für ein Switchpack damit anzusteuern.

Mit den Denkanstößen von hier bin ich am Ende drauf gekommen. Die 
Änderungen sind ziemlich übersichtlich.
Vieleicht ist das Problem hier ja noch aktuell ;)

Im Bereich "PWM-Ausgabe" Unterprogramm pwm:
Für alle Känle Die Zeilen "cp tempL, dimm_count" (vergleiche DMX Wert 
mit PWM Counter) auskommentieren oder löschen und "cpi tempL, 0x80" 
(vgl. DMX mit Konstante) an der gleichen Stelle einfügen. Die Konstante 
kann für jeden Kanal unterschiedlich, je nachdem wo der Schaltpunkt hin 
soll, angepasst werden (0 bis 255; hier im Beispiel 128)

  ld tempL, Z+          ;1
  ;cp tempL, dimm_count
  cpi tempL, 0x80
  ror status

Zusätzlich kann zum Umschalten aller Kanäle zwischen low/high aktiv die 
Zeile "com status" aus-/einkommentiert werden.

Viele Grüße