Attiny84 - Interrupt an PIN8 PCINT10 triggert nur jedes 2. mal

[Matthias (Gast)]

Hallo,

ich finde den Fehler nicht. PIN8 ist mit Pulldown an GND und eine 
parallel an den auslösenden Taster (VCC) angeschlossene LED leuchtet bei 
jeder Betätigung -> Fehler kann nur im Code versteckt sein.

#include <avr/sleep.h>
#include <avr/interrupt.h>

const int PIN2Free = 2;

const int aRDelay = A0;

const int dRFritzLEDWLAN = 1;
const int dROKFritzLEDINet = 6;
const int dROKP7 = 7;
const int dRBell = 8;

const int dWWLANOn =  3;
const int dWNETIO =  4;
const int dWWLANOff =  5;
const int dWLiftHandset =  9;
const int dWRedial = 10;

volatile int ISRTrigger=0;

volatile uint8_t portbhistory;
volatile uint8_t portahistory;

  
void setup() {

  pinMode(0, INPUT);
  pinMode(dRFritzLEDWLAN, INPUT);
  pinMode(dROKFritzLEDINet, INPUT);
  pinMode(dROKP7, INPUT);
  pinMode(dRBell, INPUT);

  pinMode(PIN2Free, OUTPUT);
  digitalWrite(PIN2Free, LOW);

  pinMode(dWWLANOn, OUTPUT);
  digitalWrite(dWWLANOn, LOW);

  pinMode(dWNETIO, OUTPUT);
  digitalWrite(dWNETIO, LOW);
  
  pinMode(dWWLANOff, OUTPUT);
  digitalWrite(dWWLANOff, LOW);

  pinMode(dWRedial, OUTPUT);
  digitalWrite(dWRedial, LOW);

  pinMode(dWLiftHandset, OUTPUT); 
  digitalWrite(dWLiftHandset, LOW);
  
  SetWMA1000();
  
  portahistory = PINA;
  portbhistory = PINB;
  
}


void sleep() {

  GIMSK |= _BV(PCIE0);
  GIMSK |= _BV(PCIE1);

  PCMSK0 |= _BV(PCINT1);
  PCMSK0 |= _BV(PCINT6);
  PCMSK1 |= _BV(PCINT10);
  ADCSRA &= ~_BV(ADEN);
  set_sleep_mode(SLEEP_MODE_PWR_DOWN);

  sleep_enable();
  sei();
  sleep_cpu();

  cli();  

  PCMSK1 &= ~_BV(PCINT10);
  PCMSK0 &= ~_BV(PCINT6);
  PCMSK0 &= ~_BV(PCINT1);
  sleep_disable();
  ADCSRA |= _BV(ADEN);

}


ISR(PCINT0_vect) {
  
  uint8_t changedbits;

  changedbits = PINA ^ portahistory;
  portahistory = PINA;

  if(changedbits & (1 << PCINT1)){
    ISRTrigger=dRFritzLEDWLAN;
  }

  if(changedbits & (1 << PCINT6)){
    if (digitalRead(dROKFritzLEDINet)==HIGH){
      ISRTrigger=dROKFritzLEDINet;
    }
  }
  
}


ISR(PCINT1_vect) {

  uint8_t changedbits;
  
  changedbits = PINB ^ portbhistory;
  portbhistory = PINB;

  if(changedbits & (1 << PCINT10)){
    if (digitalRead(dRBell)==HIGH){
      ISRTrigger=dRBell;
    }
  }
  
}


void SetWMA1000(){
  if (digitalRead(dRFritzLEDWLAN)==HIGH) {
    digitalWrite(dWWLANOff, HIGH);
    delay(500);
    digitalWrite(dWWLANOff, LOW);
  }
  else {
    digitalWrite(dWWLANOn, HIGH);  
    delay(500);
    digitalWrite(dWWLANOn, LOW);
  }
}


void loop() {

  sleep();
  
  if (ISRTrigger==dRFritzLEDWLAN){
    unsigned long ticker=0;
    int state=digitalRead(dRFritzLEDWLAN);
    while (ticker < 50000){
      if (digitalRead(dRFritzLEDWLAN)!=state){
        state=1-state;
        ticker=0;
      }
      else{
        ticker++;
      }
    }
    SetWMA1000();
  }
  else if (ISRTrigger==dROKFritzLEDINet){  
    digitalWrite(dWNETIO, HIGH);
    delay(500);
    digitalWrite(dWNETIO, LOW);
  }        
  else if (ISRTrigger==dRBell){  
    digitalWrite(dWLiftHandset, HIGH);
    delay(250);
    digitalWrite(dWRedial, HIGH);
    delay(250); 
    digitalWrite(dWRedial, LOW);
    delay(8000+analogRead(0)/1.023*5);
    digitalWrite(dWLiftHandset, LOW);
  }
  
  ISRTrigger=0;
  
}

Vielleicht ist jemand so freundlich mir Anfänger bei der Fehlersuche zu 
helfen.

Danke

Matthias

[Georg G. (df2au)]

Als erstes solltest du dein Programm zusammenstreichen, bis nur noch 
deine ISR und die Auswertung da sind. Und dann sehen wir weiter.

[Stefan F. (Gast)]

Falls es hier um schnell aufeinander folgende Signale geht, könnte es 
sein, dass deine digitalRead() Aufrufe in den Interruptroutinen zu viel 
Zeit verplempern. Um das zu lösen, kannst du direkt aus dem PINx 
Register lesen.

Dann ist mir aufgefallen, dass du beiden ISR jeweils zweimal das PINx 
Register liest - in der Hoffnung, dass da auch zweimal der selbe Wert 
bei heraus kommt. Das ist aber nicht unbedingt der Fall, das Signal 
könnte sich zwischenzeitlich geändert haben. Lies nur einmal in eine 
zusätzliche Zwischen-Variable.

In der Loop willst du im Prinzip ständig schlafen - außer es kommt ein 
Signal rein. Richtig? Due musst hier beachten, dass das Aufwachen eine 
beträchtliche Zeit kostet. Ich hatte mich auch schonmal gewundert, warum 
mein µC zwar aufwachte, danach aber der Meinung war, dass das kein 
Signal sei. Er war einfach zu träge, bis er aufgewacht war, war das 
Signal schon wieder weg.

[Matthias (Gast)]

Danke Stefanus für die Antwort.

Die Signale sind Türklingel über Relais geschalten, Fritzbox WLAN LED 
und Fritzbox Internet LED - alles Signale im Sekundenbereich und länger 
als die Aufwachzeit.

Habe die Schaltung jetzt so umgebaut, dass die Eingänge auf INT1, INT5 
und INT6 liegen und nur ein ISR benötigt wird.

Hier zickt jetzt auch der andere Eingang, den ich im ISR mit digitalRead 
auf HIGH abfrage - um direkt aus dem PINx Register zu lesen, werde ich 
hoffentlich ein Beispiel finden.

[Stefan F. (Gast)]

Bei Relais fällt mir direkt das Kontaktprellen ein. Hast du das bedacht?

[Matthias (Gast)]

Nein, hab nicht gewusst dass es beim Relais so was gibt - wie erwähnt 
Anfänger

Seit ich den ISR Code wie folgt

ISR(PCINT0_vect) {
  
  byte PinVal=PINA;

  IRQFritzLEDWLAN = PinVal & (1<<PCINT1);
  IRQFritzLEDWLAN = IRQFritzLEDWLAN >> PCINT1;

  IRQBell = PinVal & (1<<PCINT5);
  IRQBell = IRQBell >> PCINT5;

  IRQOKFritzLEDINet = PinVal & (1<<PCINT6);
  IRQOKFritzLEDINet = IRQOKFritzLEDINet >> PCINT6;
  
}

geändert habe, funktioniert es einwandfrei

Habe im Loop in der Zustandsabfrage trotzdem noch eine 50ms 
Prellsicherheit eingepflegt

Danke