Veständnissfragen zum PWM_Assemlercodebespiel

[Rudi R. (microwitsch)]

     include      "P16F887.INC"      ; Device specifics include file
      errorlevel -302
;
  __CONFIG  _CONFIG1, _LVP_OFF & _FCMEN_ON & _IESO_OFF & _BOR_OFF & _CPD_OFF & _CP_OFF & _MCLRE_ON  
                      & _PWRTE_ON & _WDT_OFF & _INTRC_OSC_NOCLKOUT       
  __CONFIG  _CONFIG2, _WRT_OFF & _BOR21V 
;
 
;**********************Header**********************************************
;************************DEFINING VARIABLES********************************
      cblock       0x70            ; Block of interrupt-context-save-variables placed into shared memory
      w_temp                       ; Variable at address 70h
      pclath_temp                  ; Variable at address 71h
      status_temp                  ; Variable at address 72h
      endc
      
      #define      DARK PORTB,0    ; Push-button "DARK" is connected
                                   ; to PORTB,0 pin
      #define      BRIGHT PORTB,1  ; Push-button "BRIGHT" is connected
                                   ; to PORTB,1 pin
;************************PROGRAM START*************************************

      org          0x0000          ; First program instruction address
      goto         main            ; Jump to label "main"

;************************INTERRUPT ROUTINE*********************************

      org          0x0004          ; Interrupt vector
      
      movwf        w_temp          ; Save register W
      
      swapf        STATUS,W          ; Save register STATUS
      movwf        status_temp
      
      movf         PCLATH,W          ; Save register PCLATH
      movwf        pclath_temp
      
      banksel      CCPR1L
      btfss        DARK            ; Tests push-button "DARK"
      decf         CCPR1L          ; Push-button is pressed - decrement CCP1L by 1
      btfss        BRIGHT          ; Testing push-button "BRIGHT"
      incf         CCPR1L          ; Push-button is pressed - increment CCP1L by 1

      banksel      PIR1            ; Selects bank containing PIR1
      bcf          PIR1,TMR1IF     ; Clears interrupt flag TMR1IF
      
      bsf          TMR1H,7         ; Accelerates timer TMR0 counting
      bsf          TMR1H,6         ;
      
      movf         pclath_temp,w   ; PCLATH is given its original content
      movwf        PCLATH
      swapf        status_temp,w   ; STATUS is given its original content
      movwf        STATUS
      swapf        w_temp,f        ; W is given its original content
      swapf        w_temp,w
      
      retfie                       ; Return from interrupt routine
      
;************************ MAIN PROGRAM **************************************

main                              ; Start of the main program
      banksel      ANSEL          ; Selects bank containing register ANSEL
      clrf         ANSEL          ; Clears registers ANSEL and ANSELH
      clrf         ANSELH         ; All pins are digital
      
      banksel      OPTION_REG     ; Selects bank containing register ANSEL
      bcf          OPTION_REG,7   ; Pull-up resistors enabled      
      bsf          WPUB,0         ; Pull-up resistors enabled
      bsf          WPUB,1         ; on port B pins 0 and 1
      
      banksel      TRISC          ; Selects bank containing register TRISC
      clrf         TRISC          ; All port C pins are configured as outputs
      
      banksel      T1CON          ; Selects bank containing register T1CON
      bcf          T1CON,TMR1CS   ; TMR1 operates as a timer
      bcf          T1CON,T1CKPS0  ; Prescaler rate is 1:8
      bcf          T1CON,T1CKPS1
      bsf          T1CON,TMR1ON   ; Activates timer TMR1
      
      banksel      PIE1           ; Selects bank containing register PIE1
      bsf          PIE1,TMR1IE    ; Interrupt TMR1 is enabled
      bsf          INTCON,PEIE    ; Peripheral modules interrupts are
                                  ; enabled
      bsf          INTCON,GIE     ; Global interrupt enabled
      
      banksel      T2CON      
      movlw        B'11111101'    ; Prescaler TMR2 = 1:4 
      movwf        T2CON
      banksel      PR2
      movlw        B'11111111'    ; Number in register PR2
      movwf        PR2
      
      banksel      CCP1CON
      movlw        B'00001100'    ; Bits to configure CCP1 module_Bit 0-3=1100 = PWM mode; P1A, P1C active-high; P1B, P1D active-high
      movwf        CCP1CON
loop
      goto         loop           ; Remain here
      end                         ; End of program

Da ich noch neu bin in Sachen PIC-Programmierung hier mal eine Frage 
bezüglich meines Verständnisses des hier angehägtem PWM-Codes:

Die Taster, die hier die hier die Pulsdauer steuern sollen, werden doch 
mit dem Interrupthandler des Timers 1 verbunden oder?

In der Interruptroutine werden die Zustände per Scleife überprüft und 
die Pulsweitenregister dekrementiert oder inkrementiert,so das sich der 
PWM-Output bzw.eine Ausgangsleistung anpassen lässt.