ESP32 + 9DoF Deep Sleep

No movement detected, entering deep sleep...

ets Jul 29 2019 12:21:46

rst:0x5 (DEEPSLEEP_RESET),boot:0x13 (SPI_FAST_FLASH_BOOT)

configsip: 0, SPIWP:0xee

clk_drv:0x00,q_drv:0x00,d_drv:0x00,cs0_drv:0x00,hd_drv:0x00,wp_drv:0x00

mode:DIO, clock div:2

load:0x3fff0030,len:1184

load:0x40078000,len:13232

load:0x40080400,len:3028

entry 0x400805e4

Woke up

#include <Arduino.h>

#include <Wire.h>

#include <Adafruit_Sensor.h>

#include <Adafruit_LSM303_U.h>

#include <Adafruit_9DOF.h>

#include <esp_sleep.h>

#include <WiFi.h>

#include <LSM303.h>

/* Sensor-Initialisierung */

Adafruit_LSM303_Accel_Unified accel = Adafruit_LSM303_Accel_Unified(30301);

Adafruit_LSM303_Mag_Unified mag = Adafruit_LSM303_Mag_Unified(30302);

LSM303 lsm; // 9DOF-Objekt

// Bewegungserkennungs-Parameter

float movementThreshold = 0.05; // Schwellenwert für Bewegungserkennung

sensors_event_t lastAccelEvent;

sensors_event_t lastMagEvent;

unsigned long noMovementDuration = 0;

const unsigned long noMovementThreshold = 2000; // 2 Sekunden ohne Bewegung

// Pin-Zuweisungen

const int sda = 21;

const int scl = 22;

const int intPin = 15; // Interrupt-Pin für LSM303

// Funktion zur Bewegungserkennung

bool detectMovement(sensors_event_t *currentEvent) {

    float deltaY = abs(currentEvent->acceleration.y - lastAccelEvent.acceleration.y);

    float deltaZ = abs(currentEvent->acceleration.z - lastAccelEvent.acceleration.z);

    return (deltaY > movementThreshold || deltaZ > movementThreshold);

}

void setup() {

    Serial.begin(115200);

    Serial.println("Woke up");

    // I2C-Initialisierung

    Wire.begin(sda, scl);

    delay(500);

    // LSM303 Initialisierung

    if (!lsm.init()) {

        Serial.println("Failed to initialize LSM303. Check your wiring!");

        while (1);

    }

    // Sensor initialisieren

    if (!accel.begin()) {

        Serial.println(F("Ooops, no LSM303 accel detected ... Check your wiring!"));

        while (1);

    }

    if (!mag.begin()) {

        Serial.println("Ooops, no LSM303 mag detected ... Check your wiring!");

        while (1);

    }

    // Konfiguration des LSM303 Accelerometers

    lsm.writeAccReg(LSM303::CTRL_REG1_A, 0x27); // Normal Mode, 50Hz, alle Achsen aktiv

    lsm.writeAccReg(LSM303::CTRL_REG2_A, 0x00); // Kein High-Pass Filter

    lsm.writeAccReg(LSM303::CTRL_REG3_A, 0b01000100); // Interrupt auf INT1 enabled

    lsm.writeAccReg(LSM303::CTRL_REG4_A, 0x00); // +-2g Empfindlichkeit

    lsm.writeAccReg(LSM303::INT1_CFG_A, 0b00101010); // ZHIE und ZLIE aktiv

    lsm.writeAccReg(LSM303::INT1_THS_A, 80); // Bewegungsschwelle, ~16mg pro LSB

    lsm.writeAccReg(LSM303::INT1_DURATION_A, 0x00); // Dauer für Interrupt, 0ms

    // ESP32 Konfiguration für Deep Sleep

    esp_sleep_enable_ext0_wakeup(GPIO_NUM_15, 1); // Wakeup bei INT1

    WiFi.mode(WIFI_OFF); // Deaktiviert WiFi

    btStop(); // Deaktiviert Bluetooth

    setCpuFrequencyMhz(80); // CPU-Frequenz reduzieren

    // Speichere initiale Sensorwerte

    accel.getEvent(&lastAccelEvent);

    mag.getEvent(&lastMagEvent);

}

void loop() {

    // Neue Sensorwerte lesen

    sensors_event_t magEvent;

    mag.getEvent(&magEvent);

    sensors_event_t accelEvent;

    accel.getEvent(&accelEvent);

    // Bewegungserkennung

    if (detectMovement(&accelEvent)) {

        // Bewegung erkannt: Daten ausgeben

        Serial.println(F("Movement detected! Sensor data:"));

        Serial.print(F("ACCEL X: ")); Serial.print(accelEvent.acceleration.x);

        Serial.print(F(" Y: ")); Serial.print(accelEvent.acceleration.y);

        Serial.print(F(" Z: ")); Serial.println(accelEvent.acceleration.z);

        Serial.print(F("MAG X: ")); Serial.print(magEvent.magnetic.x);

        Serial.print(F(" Y: ")); Serial.print(magEvent.magnetic.y);

        Serial.print(F(" Z: ")); Serial.println(magEvent.magnetic.z);

        Serial.println();

        // Letzte Werte aktualisieren

        lastAccelEvent = accelEvent;

        lastMagEvent = magEvent;

        // Bewegung erkannt, ESP bleibt wach

        noMovementDuration = 0;

        delay(1000); // Verzögerung für Ausgabe

    } else {

        // Keine Bewegung erkannt

        noMovementDuration += 1000;

        delay(1000);

        // Übergang in Deep Sleep

        if (noMovementDuration >= noMovementThreshold) {

            Serial.println(F("No movement detected, entering deep sleep..."));

            esp_deep_sleep_start();

        }

    }

}