Warum funktioniert dieses LCD-Programm nicht?

[Florian G. (suffix)]

Hallo,

ich habe versucht, die Routinen hier ausm Wiki für den 
8Bit-Betriebsmodus umzuschrieben.

PORTD ist der Datenport.
PORTB ist zum kontrollieren von RS und EN da.

Bitte schaut euch einma meine Programme an, fragt bei unlaren Befehlen 
und weißt auf Fehler hin, damit ich einen Sofrware-Fehler ausschließen 
kann, wobei die Hardware funktionieren sollte.

;lcd-routines.asm 

.equ LCD_PORT = PORTD
.equ LCD_CTRL_PORT = PORTB
.equ PIN_EN = 0
.equ PIN_RS = 1
.equ XTAL = 4000000



;LCD enablen
lcd_enable:  sbi LCD_CTRL_PORT, PIN_EN    ; Enable high
             nop                          ; 3 Taktzyklen warten
             nop
             nop
             cbi LCD_CTRL_PORT, PIN_EN    ; Enable wieder low
             ret                          ; Und wieder zurück


;kurze Pause
delay50us:   push r16                     ; 50us Pause
      ldi  r16, ( XTAL * 50 / 3 ) / 1000000
delay50us_:
             dec  r16
             brne delay50us_
      pop  r16
             ret                          ; wieder zurück
 
;Längere Pause für manche Befehle
delay5ms:  push r16                     ; 5ms Pause
      push r17
             ldi  r16, ( XTAL * 5 / 607 ) / 1000
WGLOOP0:     ldi  r17, $C9
WGLOOP1:     dec  r17
             brne WGLOOP1
             dec  r16
             brne WGLOOP0
      pop  r17
      pop  r16
             ret                          ; wieder zurück


 ; Sendet den Befehl zur Löschung des Displays
lcd_clear:
           push  r16
           ldi   r16,0b00000001       ; Display löschen
           rcall lcd_command
           rcall delay5ms
           pop   r16
           ret

 ; Cursor Home
lcd_home:
           push  r16
           ldi   r16,    0b00000010     ; Cursor Home
           rcall lcd_command  
           rcall delay5ms
           pop   r16
           ret
  

 ; Initialisierung: muss ganz am Anfang des Programms aufgerufen werden
lcd_init:
           push  r16
       push   r17
       push  r18
           ldi   r18,6
powerupwait:
           rcall delay5ms
           dec   r18
           brne  powerupwait
           ldi   r16,      0b00000011   ; muss 3mal hintereinander gesendet
           out   LCD_PORT, r16          ; werden zur Initialisierung
           rcall lcd_enable             ; 1
           rcall delay5ms
           rcall lcd_enable             ; 2
           rcall delay5ms
           rcall lcd_enable             ; und 3!
           rcall delay5ms

           ldi   r16,      0b00111000   ; 4 Bot, 2 Zeilen
           rcall lcd_command
           ldi   r16,      0b00001100   ; Display on, Cursor off
           rcall lcd_command
           ldi   r16,      0b00000100   ; endlich fertig
           rcall lcd_command

           pop   r18
       pop   r17
       pop   r16
           ret


lcd_data:

       push  r17
           push  r18

           sbi   LCD_CTRL_PORT, PIN_RS

           out   LCD_PORT, r16           ; ausgeben
           rcall lcd_enable              ; Enable-Routine aufrufen

           rcall delay50us               ; Delay-Routine aufrufen

           pop   r18
           pop   r17
           ret                           ; zurück zum Hauptprogramm


lcd_command:

       push  r17
           push  r18

           cbi   LCD_CTRL_PORT, PIN_RS

           out   LCD_PORT, r16           ; ausgeben
           rcall lcd_enable              ; Enable-Routine aufrufen

           rcall delay50us               ; Delay-Routine aufrufen

           pop   r18
           pop   r17
           ret                           ; zurück zum Hauptprogramm

       .EXIT

;testfile.asm
    .include "m16def.inc"
    .CSEG          ;Flash-Speicher verwenden
    .def akku = r16
    rjmp start        ;Interrupts überspringen
    .ORG $2A
start:   ldi  akku,LOW(RAMEND)  ;Stapel initialisieren
    out  SPL,akku
    ldi akku,HIGH(RAMEND)
    out SPH,akku
    ser akku
    out DDRB,akku
    out DDRD,akku 
    rcall lcd_init
    rcall lcd_clear
    ldi akku,'T'
    rcall lcd_data
loop:  rjmp loop
    .include "lcd_routines.asm"
    .EXIT

[/avrasm]

[jack (Gast)]

Funktioniert denn das Programm nicht?

[jack (Gast)]

Quatsch, sollte heißen:
Wie äußert sich denn der Fehler?

[Otto (Gast)]

Oder was macht das Programm und was nicht...

geht z. B. das enable (scope)

Wird das Display initialisiert ?

Gruss Otto

[Suffix (Gast)]

 Aso, das hatte ich ganz vergessen. Das display bleibt einfach aus und 
macht nichts. Die enable und die rs leitung gehen 2mal kurz auf high und 
bleiben dann high. Datenleitungen gehen auch mehrmalsauf high und 
bleiben es dann. Sieht so aus, als würde er mitten im programm hängen 
bleiben. Mfg suffix

[ich (Gast)]

Probier das mal aus

[Florian G. (suffix)]

was braucht man denn für dieses skript für vorraussetzungen an Hardware 
und was muss man wann wohin schreiben, um zb ein einfaches T auszugeben?

Hat noch jemand einen Vorschlag, was bei meinem Skript nicht stimmen 
könnte?

[Stefan W. (wswbln)]

Florian Glaser wrote:

>            ldi   r16,      0b00111000   ; 4 Bot, 2 Zeilen

...was sind "4 Bot"??  ;-)

Schaltest Du das Display in den 4-Bit-Modus (sorry, hab' gerade kein 
Datenblatt greifbar)? - dann klappt's mit dem 8-Bit Port nicht so gut...

[Florian G. (suffix)]

das ist noch aus dem Originaltext. das soll schon 4bit heißen, aebr laut 
http://www.mikrocontroller.net/articles/HD44780 stellt man mit diesem 
befehl den 8bit-modus ein. Mit Display hat 4*20 Zeichen, aber eigentlich 
sollte es doch auch erstmal mit 2 Zeilen klappen?

Ich habe das Originalprogramm für den 4bit-Modus mit entsprechender 
Beschaltung getestet. Das funktionierte wunderbar, das ist es ja, was 
mich frustiert. Mein Programm ist soweit ok?

[Florian G. (suffix)]

Keiner was gefunden?

[Michael U. (Gast)]

Hallo,

powerupwait:
           rcall delay5ms
           dec   r18
           brne  powerupwait
           ldi   r16,      0b00000011   ; muss 3mal hintereinander 
gesendet
           out   LCD_PORT, r16          ; werden zur Initialisierung
           rcall lcd_enable             ; 1

wenn das Dein Code ist, stimmt es nicht.
Du sendest 3x 0x03, Du musst aber 3x 0x30 also 0b00110000 senden...
Danach die 0x38 ist dann ok.

Gruß aus Berlin
Michael

[Florian G. (suffix)]

Da hast du natürlich recht. Habe ich eben korrigiert, funktioniert 
wunderbar! Danke für eure Hilfe!