Fehler bei UART unter ASM, nicht bei C-Programm

[Meiermann (Gast)]

Hallo allerseits,

ich nutze hier einen ATmega16 mit externem Quarz (14.7456 MHz).
Für UART habe ich einen USB-Serial-Wandler aus dem nur noch RX und TX 
raus/reinführen.

Nach dem Löten prüfe ich den UART immer mit einem C-Programm, welches 
die empfangenen Bytes wieder zurücksendet. Das funktioniert hier, die 
Einstellungen sind: 115200 Baud, 1 Stop, keine Parity.

Nun wollte ich ein Programm in Assembler schreiben, und damit ich da 
halbwegs debuggen kann, wollte ich von dort den UART nutzen, um Daten 
zurückzusenden.

Da keine Daten zurückkamen, habe ich mein C-Programm auf ASM übersetzt 
und das eingespielt. Nun kommen zwar Bytes zurück, aber nie genau die 
die man sendet. Sende ich 0 kommt 0xFF, sende ich 0xAA kommt 0xAB 
(manchmal kommt auch was ganz anderes, weswegen ich glaube, dass es 
irgendwie mit dem UART-Timing zusammenhängt).

Die beiden Programm sind hier: (C-Programm, funktioniert)

#include <avr/io.h>
#include <inttypes.h>
#include <avr/interrupt.h>

// Baudrate, das L am Ende ist wichtig, NICHT UL verwenden!

#define FR_CPU 14745600L
#define BAUD 115200L

// Berechnungen
// clever runden
#define UBRR_VAL  ((FR_CPU+BAUD*8)/(BAUD*16)-1)  
// Reale Baudrate
#define BAUD_REAL (FR_CPU/(16*(UBRR_VAL+1)))  
// Fehler in Promille 
#define BAUD_ERROR ((BAUD_REAL*1000)/BAUD-1000) 
 
#if ((BAUD_ERROR > 10) || (BAUD_ERROR < -10))
  #error Systematischer Fehler der Baudrate grösser 1% und damit zu hoch! 
#endif


int main (void) {

UCSRB |= (1<<RXEN)|(1<<TXEN);               // UART RX/TX einschalten
UCSRC |= (1<<URSEL)|(1<<UCSZ1)|(1<<UCSZ0);  // Asynchron 8N1 
UBRRH = UBRR_VAL >> 8;
UBRRL = UBRR_VAL & 0xFF;

while(1) { // endloses while(1) -- Hauptschleife

if (UCSRA & (1<<RXC))   // prüfen ob Zeichen verfuegbar
  {// USART - Eingang verarbeiten
  uint8_t x = UDR;
  UDR = x;  // Rücksendung als Echo
  }

}// endloses while(1)
// Ende
return 0;
}

und (ASM-Programm, gibt Unerwartetes zurück)

.include "m16def.inc"

.equ XTAL = 14745600

.def var1    = r16    ; temp-var für Hauptprogramm
.def var2    = r17    ; temp-var für Hauptprogramm



; USART
.equ F_CPU = 14745600                           ; Systemtakt in Hz
.equ BAUD  = 115200                             ; Baudrate

; USART  Berechnungen
.equ UBRR_VAL   = ((F_CPU+BAUD*8)/(BAUD*16)-1)  ; clever runden
.equ BAUD_REAL  = (F_CPU/(16*(UBRR_VAL+1)))     ; Reale Baudrate
.equ BAUD_ERROR = ((BAUD_REAL*1000)/BAUD-1000)  ; Fehler in Promille
 
.if ((BAUD_ERROR>10) || (BAUD_ERROR<-10))       ; max. +/-10 Promille Fehler
  .error "Systematischer Fehler der Baudrate grösser 1 Prozent und damit zu hoch!"
.endif


; ########################################################################################
.org 0x0000
        rjmp    Programmstart    ; Reset Handler
; ########################################################################################



Programmstart:
    ; Stackpointer initialisieren
        ldi     r17      , LOW(RAMEND)
        out     SPL      , r17
        ldi     r17      , HIGH(RAMEND)
        out     SPH      , r17
  

    ; Enable USART (Baudrate einstellen)
    ldi     var1    , HIGH(UBRR_VAL)
    sts     UBRRH    , var1
    ldi     var1    , LOW(UBRR_VAL)
    sts     UBRRL    , var1
    ; USART (Frame-Format: 8 Bit)
    ldi     var1    , (1<<URSEL)|(1<<UCSZ1)|(1<<UCSZ0)
    out     UCSRC    , var1
    ; RX und TX erlauben
    ldi     var1    , (1<<TXEN)|(1<<RXEN)
    out     UCSRB    , var1

Hauptprogramm:  
    ;USART prüfen / lesen
    sbis  UCSRA    , RXC
    rjmp  Hauptprogramm

    in    var1    , UDR
WaitUDRE:
    sbis  UCSRA    , UDRE
    rjmp  WaitUDRE
    
    out    UDR      , var1
    
    rjmp  Hauptprogramm

Kann es sein, dass der Fehler über die Baud-Ratenformel kommt?

Gruß,
Meiermann

[spess53 (Gast)]

Hi

Eigentlich ist die Initialisierung im C-Programm falsch. Siehe 
Datenblatt:

'Accessing UBRRH/ UCSRC Registers'.

MfG Spess

[Meiermann (Gast)]

Hm, das stimmt wohl, aber unter 'USART Initialization' im gleichen 
Datenblatt steht das Codebeispiel (fast genau) wie bei mir.

Sehr sonderbar alles, zumal das C-Programm ja funktioniert.

Die Reihenfolge der Register-Eintragungen habe ich mal im ASM der des 
C-Programms angegleichen, das Verhalten ändert sich aber trotzdem nicht.

[Lothar M. (Firma: Titel) (lkmiller) (Moderator)]

Meiermann schrieb:
> Kann es sein, dass der Fehler über die Baud-Ratenformel kommt?
Hast du einfach mal nachgerechnet?
Was kommt raus, wenn du die Werte "hart" einträgst?

[spess53 (Gast)]

Hi

In deinem ASM-Pprogramm ist ein gravierender Fehler:

>    ldi     var1    , HIGH(UBRR_VAL)
>    sts     UBRRH    , var1
>    ldi     var1    , LOW(UBRR_VAL)
>    sts     UBRRL    , var1

Die Adressen von UBRRH und UBRRL sind für IO-Adressen. Die kannst du 
nicht mit sts/lds verwenden.

MfG Spess

[Meiermann (Gast)]

Tatsache, out statt sts und schon geht alles :).

Wäre mir im Leben nicht aufgefallen, da viele Programmbeispiele von out 
auf sts geändert werden müssen, wegen der Reichweite...

Danke!
Ich hab sonst schon jede Zeite 3 mal neu 
geschrieben/geändert/umgruppiert.

[Klaus2m5 (Gast)]

spess53 schrieb:
> Die Adressen von UBRRH und UBRRL sind für IO-Adressen. Die kannst du
> nicht mit sts/lds verwenden.

Vermutlich ursprünglich für einen der neueren AVRs unsauber 
programmiert.

In jedem Fall richtig wäre es so:

.macro output
  .if @0 < 0x40
    out  @0, @1
  .else
    sts  @0, @1
  .endif
.endm 
...
    ldi     var1    , HIGH(UBRR_VAL)
    output  UBRRH    , var1
    ldi     var1    , LOW(UBRR_VAL)
    output  UBRRL    , var1
...