Pic Assembler Pseudo-Befehl DA?

[M. J. (manfred-64)]

Hallo,

ich steh Heut mal wieder völlig auf'm Schlauch,
peils nicht mit dem Pseudo-Befehl DA

Sprut erklärt das so:

DA   Ablage von 14-Bit-Zahlen/Text im Programmspeicher
Syntax:   DA <string>
DA <zahlenwert>
Beschreibung   Der DA-Befehl erzeugt 14-Bit Zahlen, und fügt sie an der 
aktuellen Stelle im Programmcode ein. Er ist vor allem zur Speicherung 
von Text gedacht. Wird der DA-Befehl von einem String gefolgt, so werden 
immer 2 Zeichen des Strings in den 7-Bit ASCII-Code gewandelt, und zu 
einer 14-Bit-Zahl zusammengefasst. Wird der DA-Befehl dagegen von einem 
Zahlenwert gefolgt, so wird dieser 14-bittig im Programmspeicher 
abgelegt. Was die Originalzahl größer als 14 Bit, so wird sie 
abgeschnitten.

Beispiel:
DA  "abcdef"  ; erzeugter Code: 0x30E2 0x31E4 0x32E6 0x3380

Kann das Beispiel schon mal nicht nachvollziehen :´(
sehe keinen Zusammenhang mit dem ASCII-Code ???

Mir ist auch nicht klar wie ich dann damit im Programm arbeite bzw. wie 
bekomme ich diese Werte ins W-Register

Kann das einer mal für Dummys erklären Bitte :)


mfg
Manfred

[(prx) A. K. (prx)]

Manfred John schrieb:

> DA  "abcdef"  ; erzeugter Code: 0x30E2 0x31E4 0x32E6 0x3380

0x30E2 = 0b11000011100010
           1100001         = 0x61 = a
                  1100010  = 0x62 = b

[(prx) A. K. (prx)]

Manfred John schrieb:

> Mir ist auch nicht klar wie ich dann damit im Programm arbeite bzw. wie
> bekomme ich diese Werte ins W-Register

Bei alten PIC16 konnte man nur über ein angesprungenes RETLW Daten aus 
dem ROM laden, da geht das nicht. Neuere PIC16 haben Steuerregister 
dafür.

[M. J. (manfred-64)]

A. K. schrieb:
> 0x30E2 = 0b11000011100010
>            1100001         = 0x61 = a
>                   1100010  = 0x62 = b

Autsch, hat ich selber sehen müssen (na ja hab höllisch Kopfschmerzen)


A. K. schrieb:
> Bei alten PIC16 konnte man nur über ein angesprungenes RETLW Daten aus
> dem ROM laden, da geht das nicht. Neuere PIC16 haben Steuerregister
> dafür.

ka ob das mein 16F727 kann, nach welchen Steuerregistern muss ich denn 
da Ausschau halten?

EDIT:
Ich kann nichts finden mit dem das "Auslesen" beim 16F727 möglich wäre.
Leider kenn ich auch nicht die Technik mit der das bei Pic's die diese 
Möglichkeit bieten funktioniert!

[Holger W. (holgerw)]

Hier mal ein Auszug aus einer Routine für den 16F mit der ich Strings 
ausgebe, Achtung, für die Routine darf der Text keine 256Byte Grenze 
überschreiten.
Vielleicht hilft es dir ja.

MSG:   addwf PCL ,F 
        dt "Testtring",0


; NUllterminierten String ausgeben (evtl. 256 Byte Grenze beachten !)
LCD_WrtTXT:   
  MOVLW   0
LCD_WrtTXT_lp:   
  MOVWF   LCD_TXTPTR     ; aktuelle Stringposition
  CALL   MSG         ; <-- hier wird das Zeichen geholt
  ANDLW   0x0FF          ; Ende der Nachricht wenn NULL
  BTFSC   STATUS, Z
  GOTO   LCD_WrtTXT_END             
  call  OutLcdDaten    ; Zeichen ausgeben
  MOVF   LCD_TXTPTR,W
  ADDLW   1             ; und das nächste Zeichen
  GOTO   LCD_WrtTXT_lp
LCD_WrtTXT_END:

Holger

[(prx) A. K. (prx)]

Manfred John schrieb:

> Ich kann nichts finden mit dem das "Auslesen" beim 16F727 möglich wäre.

Beispiel: PIC16LF1904: PMDATL/H PMADRL/H.

Bei 727 geht das möglicherweise nicht in der 7/7 Variante.

[(prx) A. K. (prx)]

Holger W. schrieb:

> Hier mal ein Auszug aus einer Routine für den 16F mit der ich Strings
> ausgebe, Achtung, für die Routine darf der Text keine 256Byte Grenze
> überschreiten.

Das ist allerdings die klassische Variante mit Strings in 1x8 Bit pro 14 
Bit via RETLW.

[M. J. (manfred-64)]

A. K. schrieb:
> Beispiel: PIC16LF1904: PMDATL/H PMADRL/H.
>
> Bei 727 geht das möglicherweise nicht in der 7/7 Variante.

Nein der hat das leider nich muss mich ich halt mit RETLW zufrieden 
geben :)

@Holger W.
Danke fürs Beispiel, so in etwa hatte ich das vor.


Danke euch
mfg
Manfred

[John B. (johnbauer)]

Manfred John schrieb:
> ka ob das mein 16F727 kann, nach welchen Steuerregistern muss ich denn
> da Ausschau halten?
>
> EDIT:
> Ich kann nichts finden mit dem das "Auslesen" beim 16F727 möglich wäre.
> Leider kenn ich auch nicht die Technik mit der das bei Pic's die diese
> Möglichkeit bieten funktioniert!

Also lt. Datenblatt kann der PIC16F727 im Betrieb seinen Flash-Speicher 
auslesen.

Kapitel 18: PROGRAM MEMORY READ

Gruß
John

[M. J. (manfred-64)]

John Bauer schrieb:
> Also lt. Datenblatt kann der PIC16F727 im Betrieb seinen Flash-Speicher
> auslesen.
>
> Kapitel 18: PROGRAM MEMORY READ

Danke!
hät ich nicht mehr da nach gesucht. (ka wie so ich da nix gefunden 
hatte)

Wenn auch a biserl umständlich für ASCII und ich nich wirklich 
Platzmangel habe, werd ich's damit machen.
Immerhin sind die Daten dann schön "aufgeräumt" und ich spar mir das 
aufpassen auf die 0xFF grenzen :)

Bin mir nur noch nicht ganz klar wie ich mir die Einsprungadressen 
"merke"
Ist es möglich die oberen Bits des PC auszulesen o. den Stack um sowas 
in der Art zu realisieren:
______________________________________
Pagesel
Call LABEL1
Pagesel
Call LABEL2
.
.

LABEL2
gemerkter PC + x
loop
programm-mem auslesen
.
.

LABEL1
PC auslesen
Return
DA "abcdef",0
_____________________________________

Sind die Adressen von Labels eventuell auch noch einfacher verwerten?
oder bin ich da völlig auf dem Holzweg :-/


mfg
Manfred

[John B. (johnbauer)]

Hallo Manfred,
hier ist mal ein Beispiel das ich mal für den PIC16F74 programmiert 
habe.
Die Variable "Text" muss in Bank2 oder in den Bereich, der in Bank2 
gespiegelt wird.

Gruß
John

;###### Macros ######

Print macro Text_Label
   banksel PMADRH          ; Bank 2
   movlw   high Text_Label ; high-Adresse von Text (Program Memory)
   movwf   PMADRH
   movlw   low Text_Lebel  ; low-Adresse von Text (Program Memory)
   movwf   PMADR
   call    LCD_Text
   endm

Print_P macro Displ_pos, Text_Label
   Set_Cu  Displ_pos
   banksel PMADRH          ; Bank 2
   movlw   high Text_Label ; high-Adresse von Text (Program Memory)
   movwf   PMADRH
   movlw   low Text_Label  ; low-Adresse von Text (Program Memory)
   movwf   PMADR
   call    LCD_Text
   endm

Set_Cu macro Cursor_pos    ; Cursorposition setzten (Hex-Adresse von LCD)
   movlw   Cursor_pos
   iorlw   0x80
   call    LCD_C
   endm


;###### Aufruf im Programm ######

   Set_Cu  0x02            ; Cursorposition setzen (Hex-Adresse von LCD)
   Print   Text_1          ; Text 1 ab Cursorposition ausgeben
   Print_P 0x16, Text2     ; Text 2 ab Position 0x16 ausgeben
   banksel ...             ; Print und Set_Cu ändern die Speicherbank -> danach
                           ; auf die, für den weiteren Programmablauf erforderliche
                           ; Bank, umschalten

;###### Unterprogramme ######

LCD_Text  
   banksel PMCON1          ; Bank 3
   bsf     PMCON1, RD      ; lesen starten
   nop
   nop
   banksel PMDATH          ; Bank 2
   movfw   PMDATH          ; 6 Bit von high-byte in Text
   movwf   Text
   rlf     PMDATA, W       ; Bit 7 von low-byte in Carry
   rlf     Text, F         ; Bit 7 in Text als Bit 0
   movf    Text, W
   btfsc   STATUS, Z       ; ist Zeichen 'Null'?
   goto    Text_End        ;  - ja
   call    LCD_D           ;  - nein: Zeichen ausgeben
   banksel PMDATA          ; Bank 2
   movfw   PMDATA          ; 2. Zeichen laden
   andlw   0x7F            ; nur untere 7bit
   btfsc   STATUS, Z       ; ist Zeichen 'Null'?
   goto    Text_End        ;  - ja
   call    LCD_D           ;  - nein: Zeichen ausgeben
   banksel PMADR           ; Bank 2
   incf    PMADR, F        ; low-Byte um 1 erhöhen (Flash-Adresse +1)
   btfsc   STATUS, Z       ; Überlauf?
   incf    PMADRH, F       ;  - ja: high-Byte um 1 erhöhen
   goto    LCD_Text
Text_End
   return


LCD_D                      ; Unterprogramm um ein Zeichen an
                           ; Cursorposition auszugeben (RS=1)

LCD_C                      ; Unterprogramm um einen Befehl an
                           ; LCD zu senden (RS=0)


Text_1   da   "Temperatur\x00"  ; "Temperatur"
Text_2   da   "\x01C\x00"       ; "°C" (Benutzer def. Zeichen "°" in Adr. 0x01 von LCD)
Text_3   da   "          \x00"  ; Leerzeichen um einen Bereich vom LCD zu löschen

   END                     ; directive 'end of program'

[Peter D. (peda)]

John Bauer schrieb:
> Hallo Manfred,
> hier ist mal ein Beispiel das ich mal für den PIC16F74 programmiert
> habe.

Ein wirklich sehr beeindruckendes Beispiel, wie kompliziert doch die 
PIC-Programmierung in Assembler ist.

Im Gegensatz dazu sieht die gleiche Aufgabe für den 8051 erheblich 
einfacher aus:

;       Demo: Textausgabe aus dem Flash des 8051
;       ========================================
;
main:
        mov     dptr, #text1            ; lade Datenpointer mit Textadresse
        call    lcd_text                ; Aufruf Ausgabefunktion

        mov     dptr, #text2            ; lade Datenpointer mit Textadresse
        call    lcd_text                ; Aufruf Ausgabefunktion

        jmp     $                       ; Endlos-Schleife
;--------------------------------------------------------------------------
text1:
        db      'Hallo Welt'
        db      0                       ; 0 = Endezeichen
text2:
        db      'Text zwei'
        db      0                       ; 0 = Endezeichen
;--------------------------------------------------------------------------
;       UP: Ausgabe des Textes im Flash, auf den DPTR zeigt
;       ===================================================
;
_lcdt1:
        call    lcd_data                ; Ausgabe eines Bytes ans LCD
        inc     dptr                    ; zeige auf naechstes Byte
lcd_text:
        clr     a                       ; kein Offest
        movc    a, @a+dptr              ; lese Byte aus Flash
        jnz     _lcdt1                  ; ungleich 0 -> Anzeigen
        ret                             ;   gleich 0 -> return
;--------------------------------------------------------------------------
lcd_data:                               ; hier LCD Ausgabe einfuegen
        ret
;--------------------------------------------------------------------------

LCD_Text: statt 25 Instruktionen nur 6.

Nicht persönlich nehmen, aber ich bin doch schon sehr froh, daß ich 
keinen PIC programmieren muß.


Peter

[M. J. (manfred-64)]

Danke John,

auf die Idee, das mit einem Macro zu lösen wäre ich glaube nicht so 
schnell gekommen.
Mir ist nur nicht klar wie "movlw   high Text_Labe" funktioniert!
movlw mit 2 Operanden?????


g
Manfred

[M. J. (manfred-64)]

Peter Dannegger schrieb:
> Ein wirklich sehr beeindruckendes Beispiel, wie kompliziert doch die
> PIC-Programmierung in Assembler ist.
>
> Im Gegensatz dazu sieht die gleiche Aufgabe für den 8051 erheblich
> einfacher aus:

wayne

[John B. (johnbauer)]

Manfred John schrieb:
> Mir ist nur nicht klar wie "movlw   high Text_Labe" funktioniert!
> movlw mit 2 Operanden?????

Text_1   da   "Temperatur\x00"

Das Label 'Text_1' beinhaltet die Adresse des ersten Zeichen des Strings 
im Flash.

movlw   high Text_Label
movlw   low Text_Lebel

Das 'high' und das 'low' sind Assembler Direktiven. Beim Kompilieren 
wird das entsprechende low- bzw. high-Byte des Labels eingesetzt.

Um Daten aus dem Flash auszulesen, muss man in PMADRH das high-Byte, und 
in PMADRL das low-Byte der zu lesenden Adresse schreiben.
(Achtung: die Registernamen der Controller sind nicht gleich. In meinem 
Code vom PIC16F74: PMADR ist beim PIC16F727: PMADRL)


Peter Dannegger schrieb:
> die  PIC-Programmierung in Assembler

Immer diese Verallgemeinerungen.

[M. J. (manfred-64)]

John Bauer schrieb:
> Das 'high' und das 'low' sind Assembler Direktiven.

Die hab ich wohl etwas vernachlässigt :)
Mal schauen was ich da noch alles für interessante Möglichkeiten 
übersehen habe.


Dank und Gruß
Manfred