Ampelsteuerung

library IEEE;

use IEEE.STD_LOGIC_1164.ALL;

use IEEE.NUMERIC_STD.ALL;

entity Ampel is

    Port ( clk : in  STD_LOGIC;

           art : out  STD_LOGIC;   -- Auto rot

           age : out  STD_LOGIC;   -- Auto gelb

           agn : out  STD_LOGIC;   -- Auto grün

           frt : out  STD_LOGIC;   -- Fussgänger rot

           fgn : out  STD_LOGIC;   -- Fussgänger grün

           ft  : in  STD_LOGIC);   -- Fussgängertaster

end Ampel;

architecture Behavioral of Ampel is

--  constant onesec: integer := 50000000; -- 50MHz

  constant onesec: integer := 5000; -- Takt 5kHz

  signal ftsr    : std_logic_vector (3 downto 0);    -- ft eintakten und Flanke erkennen

  signal tic     : integer range 0 to 5*onesec := 0; -- Zähler bis max. 5 sec

  signal schritt : integer range 0 to 6 := 0; 

begin

   process begin

      wait until rising_edge(CLK);

      if (tic/=0) then

         tic <= tic - 1;

      end if;

      ftsr <= ftsr(2 downto 0) & ft;      -- Einsynchronisieren (hilft gegen amoklaufende FSM)

      if (schritt=0 and ftsr="0111") then -- Flanke erkennen (hilft gegen Dauerbetätigung und defekte Taster)

         schritt <= 1;                    -- Flanke erkannt: los gehts

         tic     <= 2*onesec;

      end if;

      if (tic=0) then  -- Zeit abgelaufen (na gut, ein Takt zu lang, aber bei 50M macht das nicht so viel aus): nächster Schritt

         art <= '0';   -- Defaultwerte (sparen Tipparbeit): Ampel aus

         age <= '0';

         agn <= '0';

         frt <= '0'; 

         fgn <= '0';

         case schritt is

           when 0 => agn <= '1';

                     frt <= '1';

           when 1 => age <= '1';

                     frt <= '1';

                     tic <= 2*onesec;

                     schritt <= 2;

           when 2 => art <= '1';

                     frt <= '1';

                     tic <= 2*onesec;

                     schritt <= 3;

           when 3 => art <= '1';

                     fgn <= '1';

                     tic <= 5*onesec;

                     schritt <= 4;

           when 4 => art <= '1';

                     frt <= '1';

                     tic <= 2*onesec;

                     schritt <= 5;

           when 5 => art <= '1';

                     age <= '1';

                     frt <= '1';

                     tic <= 2*onesec;

                     schritt <= 6;

           when 6 => agn <= '1';

                     frt <= '1';

                     tic <= 5*onesec;

                     schritt <= 0;

         end case;

      end if;

   end process;

end Behavioral;