Oled mit I2C läuft nicht

[Stefan S. (kami)]

Hallo zusammen,

ich habe nun schon das 3te Display bei folgendem Händler erworben:

http://www.ebay.de/itm/CRIUS-CO-16-OLED-Display-Module-V1-0-for-MWC-MultiWii-Flight-Control-Board-/251195490020?ssPageName=ADME:X:DERP:DE:1123

ich verbinde das Display mit einem Atmega 328 und nutze Arduino mit 
einem i2C Scanner und auch der i2cOled ino-datei. Leider wird a das 
Display nicht als I2C erkannt und b die i2cOled läuft auch nicht. Das 
Display bleibt schwarz. Habe direkt 5V, GND und SDA,SCL angeschlossen.

Was mache ich falsch?

Gruß kami

[Troll (Gast)]

Stefan S. schrieb:
> Was mache ich falsch?

So ziemlich alles?
Mehr Details! Code, Schaltplan nach deinem aktuellen! Aufbau, usw.

[Stefan S. (kami)]

Hi,

also der Controller ist ein Jeenode SMD Kit:

http://jeelabs.net/attachments/download/345/jlpcb-132.pdf

Habe das Display direkt an 5V, GND, SDA, SCL geklemmt.

für den I2C-Scanner nehme ich folgenden Code:

#include <Wire.h>


void setup()
{
  Wire.begin();

  Serial.begin(9600);
  Serial.println("\nI2C Scanner");
}


void loop()
{
  byte error, address;
  int nDevices;

  Serial.println("Scanning...");

  nDevices = 0;
  for(address = 1; address < 127; address++ )
  {
    // The i2c_scanner uses the return value of
    // the Write.endTransmisstion to see if
    // a device did acknowledge to the address.
    Wire.beginTransmission(address);
    error = Wire.endTransmission();

    if (error == 0)
    {
      Serial.print("I2C device found at address 0x");
      if (address<16)
        Serial.print("0");
      Serial.print(address,HEX);
      Serial.println("  !");

      nDevices++;
    }
    else if (error==4)
    {
      Serial.print("Unknow error at address 0x");
      if (address<16)
        Serial.print("0");
      Serial.println(address,HEX);
    }    
  }
  if (nDevices == 0)
    Serial.println("No I2C devices found\n");
  else
    Serial.println("done\n");

  delay(5000);           // wait 5 seconds for next scan
}

und für das Oled folgendes Paket:

#include <avr/pgmspace.h>
#include <Wire.h>
//---------------FONT + GRAPHIC-----------------------------//
#include "C:\data.h"
//==========================================================//

// OLED I2C bus address
#define OLED_address  0x3c


void setup()
{
  // Initialize I2C and OLED Display
  Wire.begin();
  init_OLED();
  reset_display();           // Clear logo and load saved mode
}


//==========================================================//
void loop()
{  
   
   for(int i=0;i<128*8;i++)     // show 128* 64 Logo
     SendChar(pgm_read_byte(logo+i));
    delay(4000);
    displayOn();

   while(1)
   {
    clear_display();
    sendStrXY("Hardware Design by Mike Rankin",3,0);
    delay(3000);
    reset_display();
   }      
    //displayOff();
      //clear_display();
   //delay(4000);
  
}

//==========================================================//
// Resets display depending on the actual mode.
static void reset_display(void)
{
  displayOff();
  clear_display();

  
  displayOn();
}




//==========================================================//
// Turns display on.
void displayOn(void)
{
    sendcommand(0xaf);        //display on
}

//==========================================================//
// Turns display off.
void displayOff(void)
{
  sendcommand(0xae);    //display off
}

//==========================================================//
// Clears the display by sendind 0 to all the screen map.
static void clear_display(void)
{
  unsigned char i,k;
  for(k=0;k<8;k++)
  {  
    setXY(k,0);    
    {
      for(i=0;i<128;i++)     //clear all COL
      {
        SendChar(0);         //clear all COL
        //delay(10);
      }
    }
  }
}






//==========================================================//
static void printBigTime(char *string)
{

  int Y;
  int lon = strlen(string);
  if(lon == 3) {
    Y = 0;
  } else if (lon == 2) {
    Y = 3;
  } else if (lon == 1) {
    Y = 6;
  }
  
  int X = 2;
  while(*string)
  {
    printBigNumber(*string, X, Y);
    
    Y+=3;
    X=2;
    setXY(X,Y);
    *string++;
  }
}


//==========================================================//
// Prints a display big number (96 bytes) in coordinates X Y,
// being multiples of 8. This means we have 16 COLS (0-15) 
// and 8 ROWS (0-7).
static void printBigNumber(char string, int X, int Y)
{    
  setXY(X,Y);
  int salto=0;
  for(int i=0;i<96;i++)
  {
    if(string == ' ') {
      SendChar(0);
    } else 
      SendChar(pgm_read_byte(bigNumbers[string-0x30]+i));
   
    if(salto == 23) {
      salto = 0;
      X++;
      setXY(X,Y);
    } else {
      salto++;
    }
  }
}

//==========================================================//
// Actually this sends a byte, not a char to draw in the display. 
// Display's chars uses 8 byte font the small ones and 96 bytes
// for the big number font.
static void SendChar(unsigned char data) 
{ 
  Wire.beginTransmission(OLED_address); // begin transmitting
  Wire.write(0x40);//data mode
  Wire.write(data);
  Wire.endTransmission();    // stop transmitting
}

//==========================================================//
// Prints a display char (not just a byte) in coordinates X Y,
// being multiples of 8. This means we have 16 COLS (0-15) 
// and 8 ROWS (0-7).
static void sendCharXY(unsigned char data, int X, int Y)
{
  setXY(X, Y);
  Wire.beginTransmission(OLED_address); // begin transmitting
  Wire.write(0x40);//data mode
  
  for(int i=0;i<8;i++)
    Wire.write(pgm_read_byte(myFont[data-0x20]+i));
    
  Wire.endTransmission();    // stop transmitting
}

//==========================================================//
// Used to send commands to the display.
static void sendcommand(unsigned char com)
{
  Wire.beginTransmission(OLED_address);     //begin transmitting
  Wire.write(0x80);                          //command mode
  Wire.write(com);
  Wire.endTransmission();                    // stop transmitting
 
}

//==========================================================//
// Set the cursor position in a 16 COL * 8 ROW map.
static void setXY(unsigned char row,unsigned char col)
{
  sendcommand(0xb0+row);                //set page address
  sendcommand(0x00+(8*col&0x0f));       //set low col address
  sendcommand(0x10+((8*col>>4)&0x0f));  //set high col address
}


//==========================================================//
// Prints a string regardless the cursor position.
static void sendStr(unsigned char *string)
{
  unsigned char i=0;
  while(*string)
  {
    for(i=0;i<8;i++)
    {
      SendChar(pgm_read_byte(myFont[*string-0x20]+i));
    }
    *string++;
  }
}

//==========================================================//
// Prints a string in coordinates X Y, being multiples of 8.
// This means we have 16 COLS (0-15) and 8 ROWS (0-7).
static void sendStrXY( char *string, int X, int Y)
{
  setXY(X,Y);
  unsigned char i=0;
  while(*string)
  {
    for(i=0;i<8;i++)
    {
      SendChar(pgm_read_byte(myFont[*string-0x20]+i));
    }
    *string++;
  }
}


//==========================================================//
// Inits oled and draws logo at startup
static void init_OLED(void)
{
  sendcommand(0xae);    //display off
  sendcommand(0xa6);            //Set Normal Display (default)
    // Adafruit Init sequence for 128x64 OLED module
    sendcommand(0xAE);             //DISPLAYOFF
    sendcommand(0xD5);            //SETDISPLAYCLOCKDIV
    sendcommand(0x80);            // the suggested ratio 0x80
    sendcommand(0xA8);            //SSD1306_SETMULTIPLEX
    sendcommand(0x3F);
    sendcommand(0xD3);            //SETDISPLAYOFFSET
    sendcommand(0x0);             //no offset
    sendcommand(0x40 | 0x0);      //SETSTARTLINE
    sendcommand(0x8D);            //CHARGEPUMP
    sendcommand(0x14);
    sendcommand(0x20);             //MEMORYMODE
    sendcommand(0x00);             //0x0 act like ks0108
    
    sendcommand(0xA0 | 0x1);      //SEGREMAP   //Rotate screen 180 deg
    //sendcommand(0xA0);
    
    sendcommand(0xC8);            //COMSCANDEC  Rotate screen 180 Deg
    //sendcommand(0xC0);
    
    sendcommand(0xDA);            //0xDA
    sendcommand(0x12);           //COMSCANDEC
    sendcommand(0x81);           //SETCONTRAS
    sendcommand(0xCF);           //
    sendcommand(0xd9);          //SETPRECHARGE 
    sendcommand(0xF1); 
    sendcommand(0xDB);        //SETVCOMDETECT                
    sendcommand(0x40);
    sendcommand(0xA4);        //DISPLAYALLON_RESUME        
    sendcommand(0xA6);        //NORMALDISPLAY             

  clear_display();
  sendcommand(0x2e);            // stop scroll
  //----------------------------REVERSE comments----------------------------//
  //  sendcommand(0xa0);    //seg re-map 0->127(default)
  //  sendcommand(0xa1);    //seg re-map 127->0
  //  sendcommand(0xc8);
  //  delay(1000);
  //----------------------------REVERSE comments----------------------------//
  // sendcommand(0xa7);  //Set Inverse Display  
  // sendcommand(0xae);    //display off
  sendcommand(0x20);            //Set Memory Addressing Mode
  sendcommand(0x00);            //Set Memory Addressing Mode ab Horizontal addressing mode
  //  sendcommand(0x02);         // Set Memory Addressing Mode ab Page addressing mode(RESET)  
  
   setXY(0,0);
  /*
  for(int i=0;i<128*8;i++)     // show 128* 64 Logo
  {
    SendChar(pgm_read_byte(logo+i));
  }
  */
  sendcommand(0xaf);    //display on
  
 
}

[Schleby N. (schleby)]

Stefan S. schrieb:

> Habe das Display direkt an 5V, GND, SDA, SCL geklemmt.


Du brauchst auf jeden Fall noch Pullup Widerstände für SDA und SCL 1.5 
KOhm passen immer ganz gut ,ohne die wird das mit der I2C kommunikation 
nichts.

[Frank M. (frank_m35)]

Eine kurze Recherche zeigte ziemlich schnell: Dein OLED Module ist Mist!

http://forum.arduino.cc/index.php?PHPSESSID=0p0n85bplhoiguaffotv7bojd7&topic=159851.60

Du kannst die Empfehlung von Eagle67 mal versuchen, aber wie er selbst 
schrieb, zuverlässig läuft es deswegen trotzdem nicht.

Das heißt für dich:
Wenn du ein zuverlässiges Display haben willst, wirst du es modifizieren 
müssen, da die Reset Funktion in dem eBay Modul nicht ordnungsgemäß 
verdrahtet ist und somit es sich nicht zuverlässig initialisiert, auch 
nicht mit oben genannten Code.
http://forum.arduino.cc/index.php?PHPSESSID=pjgv84n1re6a0q06o8fprthcg7&topic=159851.msg1322649#msg1322649
http://rayvenn.alnet.com.ua/2013/08/crius-oled-display-fix/

Meine Empfehlung:
Schmeiß es fort und kauf dir ein gescheites, bevor du, vor allem 
vermutlich als Anfänger, endlos kostbare Zeit damit verschwendest.

[Stefan S. (kami)]

Hi,

der Umbau mit dem Fix hat gut geklappt. Ich löte SMD schon etwas länger.
Also die Erfahrung beim Umbau ist da. Aber irgendwie klappt das immer 
noch nicht?

Noch jemand einen Tipp?

Gruß kami

[Stefan S. (kami)]

Hi,

zusammen läuft jetzt alles super. Nachdem Umbau musste ich die 
CRIUSoled.ino aus dem ersten Forumpost nehmen. Die lief super.

Vielen Dank

Gruß kami

[OLED (Gast)]

Könntest Du uns an Deinem Erfolg teilhaben lassen, indem Du die 
funktionierende Konfiguration oder Quellcode postest? Das wäre klasse.

Ich habe selber ein CRIUS CO-16 v1.2, welches mir einige Fehler 
beschehrt.