Gnuplot: Einheitskreis zeichnen

[Tobias P. (hubertus)]

Hallo zusammen,

ich möchte den Betrag einer z-Übertragungsfunktion in der komplexen 
Ebene darstellen. Dazu habe ich in Matlab meine Übertragungsfunktion 
definiert und diese dann im Bereich von x=-1..1 und y=-1..1 evaluiert, 
in dem ich für
z jeweils x+j*y eingesetzt habe. Anschliessend plotte ich den Betrag der 
Übertragungsfunktion mit pcolor. Das geht wunderbar in Matlab, nun 
möchte ich das Diagramm aber auch sinnvoll in LaTeX einbinden können. 
Für meine LaTeX-Dokumente verwende ich jeweils Gnuplot. Also habe ich 
nun die Daten aus Matlab exportiert (Datei z.txt stellt für jeden Punkt 
der komplexen Ebene den Betrag der Übertragungsfunktion dar) und zeichne 
das in LaTeX mit Gnuplot wie folgt:

set grid
set format x "$%g$"
set format y "$%g$"

set xlabel "$\\Re z$"
set ylabel "$\\Im z$"

set tics out
  

set cbtics format "$%g$"
set palette rgb 34,35,36;
  
set xrange [-1.1:1.1]
set yrange [-1.1:1.1]
set grid
set size square
  

set object 1 circle at 0,0 size 1

plot 'z.txt' u ($1*5.4863e-003-1.1):($2*5.4863e-003-1.1):3 matrix with image notitle

Das sieht schon wie gewünscht aus, allerdings möchte ich in dem Bild 
noch den Einheitskreis einzeichnen, damit man erkennt, dass die Pole 
wirklich alle innerhalb des Einheitskreises liegen. Wie ihr seht, habe 
ich versucht den Kreis zu zeichnen mit der zweitletzten Anweisung. Aber, 
man erkennt nichts! Ich denke das Problem liegt darin, dass der 
gezeichnete Kreis irgendwie "unter" dem farbigen Graphen liegt. Hat 
einer eine Idee, wie man das "Problem" beheben könnte, sodass der 
Einheitskreis als dünne schwarze Linie sichtbar wird?

Gruss Tobias

[SAlewski, Stefan (Gast)]

Tobias Plüss schrieb:
> Ich denke das Problem liegt darin, dass der
> gezeichnete Kreis irgendwie "unter" dem farbigen Graphen liegt.

Ja und warum probierst Du nicht mal nur den Kreis zu zeichnen, also ohne 
den Rest?

Wenn das Erfolg hat, vielleicht die set Object Anweisung weiter nach 
unten schieben, also nach plot?
Eventuell braucht set object circle aber auch weitere Parameter. Und 
sonst kann man Kreise natürlich auch als Kurven zeichnen, set parametric 
und dann mit sin(), cos() -- findet man mit Google.

Ich habe gnuplot derzeit nicht installiert und kann Dir momentan nicht 
helfen -- Yalu wahrscheinlich schon eher, mal sehen ob er sich meldet.

[Tobias P. (hubertus)]

Hallo,

jaaa stimmt, auf die Idee mit parametric bin ich nicht gekommen.
So geht es!

  set xlabel "$\\Re z$"
  set ylabel "$\\Im z$"
  set zlabel "$\\abs{ G(z) }$"
  
  range = 1.3
  numpnts = 401
  
  set parametric
  set trange [0:2*pi]
  fx(t) = cos(t)
  fy(t) = sin(t)
  set table 'table.tmp'
  set samples 100,100
  plot fx(t),fy(t)
  unset table
  unset parametric
  
  set palette @JET

  @FORMAT_TEX
  @SQUARE
  set xrange [-range:range]
  set yrange [-range:range]
  plot 'daten/z.txt' u ($1*range/numpnts*2-range):($2*range/numpnts*2-range):3 matrix with image notitle, \
  'table.tmp' using 1:2 with lines lw 0.5 lc rgb"black" notitle,\
  'daten/zeros.txt' using 1:2 with points pt 6 lc rgb"red" title 'Nullstellen', \
  'daten/poles.txt' using 1:2 with points pt 2 title 'Pole'

[Yalu X. (yalu) (Moderator)]

set object

geht schon, man muss aber angeben, dass das Objekt in den Vordergrund
gezeichnet werden soll:

set object 1 circle front at 0,0 size 1 fillcolor rgbcolor "black"

Die fillcolor-Option habe ich zusätzlich angegeben, da sonst der Kreis
aus mir unverständlichen Gründen weiß gefüllt wird.

[Tobias P. (hubertus)]

Hallo Yalu,
kriegst du es auch noch hin, dass das Raster sichtbar wird? set grid 
genügt offenbar nicht ;-)
danke übrigens für den input. Ist so doch etwas bequemer als meine 
Lösung!

Gruss

[Salewski, Stefan (Gast)]

Hast Du denn "set grid front" probiert?

http://gnuplot.sourceforge.net/docs_4.2/node188.html

[Yalu X. (yalu) (Moderator)]

Salewski, Stefan schrieb:
> Hast Du denn "set grid front" probiert?

Der Versuch könnte durchaus erfolgreich sein ;-)

[Tobias P. (hubertus)]

Jawoll, der Versuch war's wert ;-)
Damit und noch mit einer etwas klügeren Colormap kriege ich ein ganz 
anständiges Diagramm.

Danke & Gruss!