kann LCD Datei nicht compilieren

[Fritz B. (kleinfritzchen)]

Hallo, ich hab eine Datei zum betreiben eines LCD#s an einer 4 Bit 
leitung gefunden und wollte damit etwas experimentieren. Beim 
compilieren gab es aber folgende Fehlermeldung:
Error  1  Illegal use of undefined or forward referenced symbol 
'LCDS_DDR' in conditional  C:\Users\Fritz\Documents\Atmel 
Studio\6.1\LCDTEST4\LCDTEST4\lcd4inc.asm  72  0  LCDTEST4

was ich hier als Anfänger nicht verstehe ist wozu diese .if Anweisung 
überheupt darin vorkommt und ob sie nicht eigentlich überflüssig ist 
weil  doch LCDS_DDR und LCD_DDR immer beide das gleiche Byte zugreifen.
Mein Atmel Studio 6.1 kennt das anscheinend nicht.
Was kann ich tun um diese Meldung zu verhindern?

MfG Fritz

und hier der Code :

;*******************************************************************************
;  File:  m8_LCD_4bit.asm
;      Title:  ATmega8 driver for LCD in 4-bit mode (HD44780)
;  Assembler:  AVR assembler/AVR Studio
;    Version:  1.0
;    Created:  April 5th, 2004
;     Target:  ATmega8
; Christoph Redecker, http://www.avrbeginners.net 
; BellaD ,www.bellibot.com - some encantements
; change to include file lcd4inc.asm
;*******************************************************************************

; Some notes on the hardware:
;ATmega8 (clock frequency doesn't matter, tested with 1 MHz to 8 MHz)
; PortD.1 -> LCD RS (register select)
; PortD.2 -> LCD RW (read/write)
; PortD.3 -> LCd E (Enable)
; PortD.4 ... PortD.7 -> LCD data.4 ... data.7
; the other LCd data lines can be left open or tied to ground.
; the pin Vo can fit to GND for maximum of contrast 


;********* you want this in the main file **********
;.equ   LCD_PORT = PORTD
;.equ   LCD_DDR  = DDRD
;.equ  LCDS_PORT = PORTD
;.equ  LCDS_DDR  = DDRD

;.equ  LCD_RS  = 1
;.equ  LCD_RW  = 2
;.equ  LCD_E  = 3


;.def  temp  = r16
;.def  arg    = r17    ;argument for calling subroutines
;.def  arg2  = r18    ;argument for mathematics
;.def  return  = r19    ;return value from subroutines

;***********************************************************************************
; the following source is from AVRbeginners.net .great work- well documented
; the advantage of read the busyflag in 4-bit mode is, no delay's needed
;***********************************************************************************
LCD_command8:  ;used for init (we need some 8-bit commands to switch to 4-bit mode!)
  in  temp, LCD_DDR    ;we need to set the high nibble of DDRD while leaving
          ;the other bits untouched. Using temp for that.
  sbr  temp, 0b11110000  ;set high nibble in temp
  out  LCD_DDR, temp    ;write value to DDRD again
  in  temp, LCD_PORT    ;then get the port value
  cbr  temp, 0b11110000  ;and clear the data bits
  cbr  arg, 0b00001111  ;then clear the low nibble of the arg
          ;so that no control line bits are overwritten
  or  temp, arg    ;then set the data bits (from the arg) in the
          ;Port value
  out  LCD_PORT, temp    ;and write the port value.
  sbi  LCDS_PORT, LCD_E    ;now strobe E
  nop
  nop
  nop
  cbi  LCDS_PORT, LCD_E
  in  temp, LCD_DDR    ;get DDRD to make the data lines input again
  cbr  temp, 0b11110000  ;clear data line direction bits
  out  LCD_DDR, temp    ;and write to DDRD
  ret

LCD_putchar:
  push  arg    ;save the argmuent (it's destroyed in between)
  in  temp, LCD_DDR    ;get data direction bits
  sbr  temp, 0b11110000  ;set the data lines to output
  out  LCD_DDR, temp    ;write value to DDRD
  in  temp, LCD_PORT    ;then get the data from PortD
  
.if LCDS_DDR == LCD_DDR    ;if the same port
  cbr  temp, 0b11111110  ;clear ALL LCD lines (data and control!)
.else
  cbr  temp, 0b11110000
.endif
  
  ;cbr  temp, 0b11111110  ;clear ALL LCD lines (data and control!)
  
  cbr  arg, 0b00001111  ;we have to write the high nibble of our arg first
          ;so mask off the low nibble
  or  temp, arg    ;now set the arg bits in the Port value
  out  LCD_PORT, temp    ;and write the port value
  sbi  LCDS_PORT, LCD_RS    ;now take RS high for LCD char data register access
  sbi  LCDS_PORT, LCD_E    ;strobe Enable
  nop
  nop
  nop
  cbi  LCDS_PORT, LCD_E
  pop  arg    ;restore the arg, we need the low nibble now...
  cbr  temp, 0b11110000  ;clear the data bits of our port value
  swap  arg    ;we want to write the LOW nibble of the argument to
          ;the LCD data lines, which are the HIGH port nibble!
  cbr  arg, 0b00001111  ;clear unused bits in argument
  or  temp, arg    ;and set the required argument bits in the port value
  out  LCD_PORT, temp    ;write data to port
  sbi  LCDS_PORT, LCD_RS    ;again, set RS
  sbi  LCDS_PORT, LCD_E    ;strobe Enable
  nop
  nop
  nop
  cbi  LCDS_PORT, LCD_E
  cbi  LCDS_PORT, LCD_RS
  in  temp, LCD_DDR
  cbr  temp, 0b11110000  ;data lines are input again
  out  LCD_DDR, temp
    ret

LCD_command:  ;same as LCD_putchar, but with RS low!
  push  arg
  in  temp, LCD_DDR
  sbr  temp, 0b11110000
  out  LCD_DDR, temp
  in  temp, LCD_PORT
  ;cbr  temp, 0b11111110
.if LCDS_DDR == LCD_DDR    ;if the same port then
  cbr  temp, 0b11111110  ;clear ALL LCD lines (data and control!)
.else
  cbr  temp, 0b11110000
.endif
  cbr  arg, 0b00001111
  or  temp, arg

  out  LCD_PORT, temp
  sbi  LCDS_PORT, LCD_E
  nop
  nop
  nop
  cbi  LCDS_PORT, LCD_E
  pop  arg
  cbr  temp, 0b11110000
  swap  arg
  cbr  arg, 0b00001111
  or  temp, arg
  out  LCD_PORT, temp
  sbi  LCDS_PORT, LCD_E
  nop
  nop
  nop
  cbi  LCDS_PORT, LCD_E
  in  temp, LCD_DDR
  cbr  temp, 0b11110000
  out  LCD_DDR, temp
  ret

LCD_getchar:
  in  temp, LCD_DDR    ;make sure the data lines are inputs
  andi  temp, 0b00001111  ;so clear their DDR bits
  out  LCD_DDR, temp
  sbi  LCDS_PORT, LCD_RS    ;we want to access the char data register, so RS high
  sbi  LCDS_PORT, LCD_RW    ;we also want to read from the LCD -> RW high
  sbi  LCDS_PORT, LCD_E    ;while E is high
  nop
  in  temp, PinD    ;we need to fetch the HIGH nibble
  andi  temp, 0b11110000  ;mask off the control line data
  mov  return, temp    ;and copy the HIGH nibble to return
  cbi  LCDS_PORT, LCD_E    ;now take E low again
  nop        ;wait a bit before strobing E again
  nop  
  sbi  LCDS_PORT, LCD_E    ;same as above, now we're reading the low nibble
  nop
  in  temp, PinD    ;get the data
  andi  temp, 0b11110000  ;and again mask off the control line bits
  swap  temp      ;temp HIGH nibble contains data LOW nibble! so swap
  or  return, temp    ;and combine with previously read high nibble
  cbi  LCDS_PORT, LCD_E    ;take all control lines low again
  cbi  LCDS_PORT, LCD_RS
  cbi  LCDS_PORT, LCD_RW
  ret          ;the character read from the LCD is now in return

LCD_getaddr:  ;works just like LCD_getchar, but with RS low, return.7 is the busy flag
  in  temp, LCD_DDR
  andi  temp, 0b00001111
  out  LCD_DDR, temp
  cbi  LCDS_PORT, LCD_RS
  sbi  LCDS_PORT, LCD_RW
  sbi  LCDS_PORT, LCD_E
  nop
  in  temp, PinD
  andi  temp, 0b11110000
  mov  return, temp
  cbi  LCDS_PORT, LCD_E
  nop
  nop
  sbi  LCDS_PORT, LCD_E
  nop
  in  temp, PinD
  andi  temp, 0b11110000
  swap  temp
  or  return, temp
  cbi  LCDS_PORT, LCD_E
  cbi  LCDS_PORT, LCD_RW
  ret

LCD_wait:        ;read address and busy flag until busy flag cleared
  
  rcall  LCD_getaddr
  andi  return, 0x80
  brne  LCD_wait
  ret


LCD_delay:
  clr  r2
  LCD_delay_outer:
  clr  r3
    LCD_delay_inner:
    dec  r3
    brne  LCD_delay_inner
  dec  r2
  brne  LCD_delay_outer
  ret

LCD_init:     
;**** for the most LCD you must write 3times a dummy command before you change to 4Bit***
;this is corrected by www.bellibot.com :-)) - before !you have only one LineLCD ***
  
  ;ldi  temp, 0b00001110  ;control lines are output, rest is input
  in temp,LCD_DDR
  andi temp,0b00001111    ;LCD pins input
  out LCD_DDR,temp
  in temp,LCDS_DDR
  ori     temp, (1<<LCD_RS)|(1<<LCD_RW)|(1<<LCD_E) ;controllpins output
  out  LCDS_DDR, temp
  
  rcall  LCD_delay    ;
  ldi  arg, 0x30      ;
  rcall  LCD_command8    

  rcall  LCD_delay
  ldi  arg, 0x30    ;NOW: 2 lines, 5*7 font, 4-BIT MODE!     ** DUMMY ***
  rcall  LCD_command8    ;
  
  
  rcall  LCD_delay    
  ldi  arg, 0x30      
  rcall  LCD_command8    

  rcall  LCD_delay    ;first, we'll tell the LCD that we want to use it
  ldi  arg, 0x20      ;in 4-bit mode.
  rcall  LCD_command8    ;LCD is still in 8-BIT MODE while writing this command!!!

  
  rcall  LCD_delay
  ldi  arg, 0x28    ;NOW: 2 lines, 5*7 font, 4-BIT MODE!     ** this change to 4bit 2 lines **
  rcall  LCD_command    ;after this point you don't can change anything 'show HD44780 Datasheet'

  rcall  LCD_wait
  ldi  arg, 0x0F    ;now proceed as usual: Display on, cursor on, blinking
  rcall  LCD_command
  
  rcall  LCD_wait
  ldi  arg, 0x01    ;clear display, cursor -> home
  rcall  LCD_command
  
  rcall  LCD_wait
  ldi  arg, 0x06    ;auto-inc cursor
  rcall  LCD_command
  ret

;******************************************
; clear Displays
LCD_clear:
           push arg
       ldi   arg, 0b00000001      ; Display clear
           rcall LCD_command
           rcall  LCD_wait
           pop arg
       ret
 
 ; Cursor Home
LCD_home:
           push arg
       ldi   arg, 0b00000010      ; Cursor Home
           rcall LCD_command
           rcall  LCD_wait
           pop arg
       ret
;set cursor pos
LCD_pos:
    sbr arg,0b10000000 ; Set DD-RAM-Adress
    rcall LCD_command
    rcall  LCD_wait
    ret

;*****************************************************
; Display at the position in arg the string starting at Z (null-term.)
;
LCD4ZTxt:
  sbr arg,0b10000000 ; Set DD-RAM-Adress
  rcall LCD_command
  rcall  LCD_wait
LCD4ZTxt1:
  lpm ; Get a char
  tst R0 ; Null-Char?
  breq LCD4ZTxtR
  mov arg,R0
  rcall LCD_putchar ; display the cahr
  rcall  LCD_wait
  adiw ZL,1 ; next char
  rjmp LCD4ZTxt1 ; do it again
LCD4ZTxtR:
  ret
;**********************************************************************
;
; Eine 8 Bit Zahl ohne Vorzeichen hexadezimal ausgeben
;
; Übergabe:            Zahl im Register arg
; veränderte Register: keine
;
lcd_number_hex:
           swap  arg
           rcall lcd_number_hex_digit
           swap  arg
 
lcd_number_hex_digit:
           push  arg
 
           andi  arg, $0F
           cpi   arg, 10
           brlt  lcd_number_hex_digit_1
           subi  arg, -( 'A' - '9' - 1 ) ; es wird subi mit negativer Konstante verwendet, weil es kein addi gibt
lcd_number_hex_digit_1:
           subi  arg, -'0'               ; ditto
           rcall  lcd_putchar
           rcall  LCD_wait
           pop   arg
           ret
;*********************************************************************
;
; Eine 8 Bit Zahl dezimal ohne Vorzeichen ausgeben
;
; Übergabe:            Zahl im Register arg
; veränderte Register: keine
;
lcd_number:
           ;push  temp            ; die Funktion verändert temp2, also sichern
                                  ; wir den Inhalt, um ihn am Ende wieder
                                  ; herstellen zu können
 
           mov   arg2,arg     ; das Register temp1 frei machen
                                  ; abzählen wieviele Hunderter
                                  ; in der Zahl enthalten sind
           ldi   arg, '0'
lcd_number_1:
           subi  arg2, 100       ; 100 abziehen
           brcs  lcd_number_2     ; ist dadurch ein Unterlauf entstanden?
           inc   arg            ; Nein: 1 Hunderter mehr ...
           rjmp  lcd_number_1     ; ... und ab zur nächsten Runde
;
                                  ; die Hunderterstelle ausgeben
lcd_number_2:
           rcall LCD_putchar
           rcall LCD_wait
       subi  arg2, -100      ; 100 wieder dazuzählen, da die
                              ; vorherhgehende Schleife 100 zuviel
                  ; abgezogen hat
 
                                  ; abzählen wieviele Zehner in
                  ; der Zahl enthalten sind
           ldi   arg, '0'
lcd_number_3:
           subi  arg2, 10        ; 10 abziehen
           brcs  lcd_number_4     ; ist dadurch ein Unterlauf enstanden?
           inc   arg            ; Nein: 1 Zehner mehr ...
           rjmp  lcd_number_3     ; ... und ab zur nächsten Runde
 
                              ; die Zehnerstelle ausgeben
lcd_number_4:
           rcall LCD_putchar
           rcall LCD_wait
       subi  arg2, -10       ; 10 wieder dazuzählen, da die
                              ; vorhergehende Schleife 10 zuviel
                  ; abgezogen hat
 
                                  ; die übrig gebliebenen Einer
                  ; noch ausgeben
           ldi   arg, '0'       ; die Zahl in temp2 ist jetzt im Bereich
           add   arg, arg2     ; 0 bis 9. Einfach nur den ASCII Code für
           rcall LCD_putchar         ; '0' dazu addieren und wir erhalten dierekt
           rcall LCD_wait                       ; den ASCII Code für die Ziffer
 
           ;pop   temp            ; den gesicherten Inhalt von temp2 wieder herstellen
           ret                    ; und zurück

[Mike (Gast)]

Fritz Bie schrieb:
> Illegal use of undefined or forward referenced symbol
> 'LCDS_DDR'

Du solltest dem Compiler LCDS_DDR irgendwie bekannt machen.

p.s.
Ruft das Wort "Dateianhang" irgendwelche Assoziation bei dir wach?

[Fritz B. (kleinfritzchen)]

tut mir leid aber ich versteh überhaupt nicht was du mit "Dateianhang" 
meinst. Ich hab auch keine Ahnung wie man diese Variablen dem Compiler 
bekannt macht.
Das ganze funktioniert natürlich mit einer weiteren Datei in der eine 
main ist und dort sind die in der Datei aufgeführten sachen:
;.equ   LCD_PORT = PORTD
;.equ   LCD_DDR  = DDRD
;.equ  LCDS_PORT = PORTD
;.equ  LCDS_DDR  = DDRD

;.equ  LCD_RS  = 1
;.equ  LCD_RW  = 2
;.equ  LCD_E  = 3


;.def  temp  = r16
;.def  arg    = r17    ;argument for calling subroutines
;.def  arg2  = r18    ;argument for mathematics
;.def  return  = r19    ;return value from subroutines
natürlich definiert....
allerdings hab ich das .include vor der Definition, das probier ich heut 
Abend mal aus, vielleicht liegt es ja da dran.

[Georg G. (df2au)]

Du weißt aber schon, dass ein ; den Rest der Zeile zum Kommentar 
erklärt? Insofern sind deine "Definitionen" nur schmückendes Beiwerk.

Abgesehen davon zeigen mir diese Zeilen

; the other LCd data lines can be left open or tied to ground.
; the pin Vo can fit to GND for maximum of contrast

dass der Autor entweder das Datenblatt nicht gelesen oder nicht 
verstanden hat. Die Spannung an Vo solltest du auf jeden Fall 
einstellbar machen und die nicht benutzten Pins am LCD lass bitte offen.