pixel bewegen bei vga-ansteuerung

[Mar B. (sepp12)]

Hallo Leute,

arbeite zur Zeit als Einsteiger in Vhdl an einer vga-ansteuerung. 
Hintergrund und einzelne unterschiedlich farbige Quadrate bzw. Rechtecke 
hab ich schon ausgegeben.

Würde die jetzt einfach mal gerne von unten nach oben durch den 
Bildbereich laufen lassen, allerdings verstehe ich nicht wie ich da 
überhaupt ansetzen soll, vll. kann mir hier jemand den Tipp geben?

hier mein bisheriger Vhdl Code:

----------------------------------------------------------------------------------
-- Company: 
-- Engineer: 
-- 
-- Create Date:    21:46:37 04/08/2014 
-- Design Name: 
-- Module Name:    VGA - PROGRAMM 
-- Project Name: 
-- Target Devices: 
-- Tool versions: 
-- Description: 
--
-- Dependencies: 
--
-- Revision: 
-- Revision 0.01 - File Created
-- Additional Comments: 
--
----------------------------------------------------------------------------------
library IEEE;
use IEEE.STD_LOGIC_1164.ALL;
use IEEE.std_logic_arith.ALL;
use ieee.std_logic_unsigned.all;



-- Uncomment the following library declaration if using
-- arithmetic functions with Signed or Unsigned values
--use IEEE.NUMERIC_STD.ALL;

-- Uncomment the following library declaration if instantiating
-- any Xilinx primitives in this code.
--library UNISIM;
--use UNISIM.VComponents.all;

entity VGA is

PORT
(

clk_50 : IN   std_logic;

v_sync:  OUT  std_logic;
h_sync:   OUT  std_logic;

red:    OUT  std_logic_vector (2 DOWNTO 0);
green:  OUT  std_logic_vector (2 DOWNTO 0);
blue:    OUT  std_logic_vector (2 DOWNTO 0)

);

end VGA;





architecture PROGRAMM  of VGA is

signal clk_25          : std_logic;
signal horizontal_counter : std_logic_vector (9 downto 0);
signal vertical_counter   : std_logic_vector (9 downto 0);
signal x              : std_logic_vector (9 downto 0);
signal y              : std_logic_vector (9 downto 0);

begin

--------------------------------------------25MHz-Takt fuer VGA--------------------------------------------

process (clk_50)               
begin
  if (clk_50 'EVENT and clk_50='1') then
    if (clk_25 = '0') then
      clk_25 <= '1';
    else
      clk_25 <= '0';
    end if;
  end if;
end process;








process(clk_50)

begin

---------------------------Horizontaler Synchronisationsimpuls---------------------------
if(clk_25 'Event and clk_25 = '1')then
    
   horizontal_counter <= horizontal_counter + "0000000001";

   if(horizontal_counter > "1010010000" and horizontal_counter < "1011110000") then -- >656 and <752
      h_sync <= '0';
   else
      h_sync <= '1';
   end if;

      if(horizontal_counter = "1100100000") then                           --800
      horizontal_counter <= "0000000000";
      vertical_counter <=  vertical_counter + "0000000001";
   end if;
  
  if(horizontal_counter > "0000000000" and horizontal_counter < "1010000001") then -- > 0 and < 641
      blue <= "000";
      red <= "000";
      green <= "111";
   else
      blue <= "000";
      red <= "000";
      green <= "000";
  end if;

  
 
---------------------------Vertikaler Synchronisationsimpuls---------------------------
   
   if (vertical_counter > "111101010" and vertical_counter < "111101101") then     -- > 490 and < 493
      v_sync <= '0';
   else
      v_sync <= '1';
   end if;
   
   if(vertical_counter > "111100000" and vertical_counter < "1000001110") then     -- >480 and < 526
      blue <= "000";
      red <= "000";
      green <= "000"; 
   end if;
   
   if(vertical_counter = "1000001110") then                             --525
      vertical_counter <= "0000000000";
   end if;
  


  
  x <="0000110010";
  y <="0011110000";
  
if(horizontal_counter > "0000000000" and horizontal_counter < "1010000001") then  
if((vertical_counter > y) and (vertical_counter < (y+"100000")) 
and (horizontal_counter > x) and (horizontal_counter < (x+"100000")))then

      blue <= "000";
      red <= "111";
      green <= "000";
    

                                         
end if;
end if;
end if;



    
end process;

end PROGRAMM;

mfg sepp12

[Lothar M. (Firma: Titel) (lkmiller) (Moderator)]

Wenn du diese zwei Zähler hier

  signal horizontal_counter : std_logic_vector (9 downto 0);
  signal vertical_counter   : std_logic_vector (9 downto 0);

als integer deklarieren würdest, dann wäre dieser Vergleich ganz kurz 
und einfach zu lesen:

 if(horizontal_counter > 0 and horizontal_counter < 641) then

Als Tipp: verwende die numeric_std statt der std_logic_arith und der 
std_logic_unsigned...

Hier ist die Sensitivliste falsch:

process(clk_50)
begin
if(clk_25 'Event and clk_25 = '1')then

Der Prozess ist eigentlich nur auf clk_25 sensitiv. Aber das jetzt noch 
nicht ändern, denn so werden keine Takte erzeugt:

process (clk_50)               
begin
  if (clk_50 'EVENT and clk_50='1') then
    if (clk_25 = '0') then
      clk_25 <= '1';
    else
      clk_25 <= '0';
    end if;
  end if;
end process;

Verwende diesen clk_25 als Clock-Enable und nimm nur den 50MHz Takt als 
richtigen Takt. So etwa:

process (clk_50)               
begin
  if (clk_50 'EVENT and clk_50='1') then
    if (clk_25 = '0') then
      clk_25 <= '1';
    else
      clk_25 <= '0';
    end if;
  end if;
end process;

process(clk_50)  -- jetzt passt die Sensitivliste 
begin
if(clk_50 'Event and clk_50 = '1') then -- im ganzen Design der selbe Takt!!
  if clk_25='1' then -- das ist ein Clock-Enable
     ...dein Code

Martin Braun schrieb:
> Würde die jetzt einfach mal gerne von unten nach oben durch den
> Bildbereich laufen lassen, allerdings verstehe ich nicht wie ich da
> überhaupt ansetzen soll, vll. kann mir hier jemand den Tipp geben?
Du nimmst jetzt vier Register und definierst damit den Anfang und das 
Ende eines Farbwechsels. Diese Register vergleichst du laufend mit dem 
x- und dem y-Zähler und schaltest die Farbe passend um.
Und ab und zu änderst du die Werte dieser Register. Dadurch bewegt sich 
das andersfarbige Viereck...

[Mar B. (sepp12)]

Erstmal danke für die Hilfe.

"Du nimmst jetzt vier Register und definierst damit den Anfang und das
Ende eines Farbwechsels."

Wie ist das zu verstehen, denke an diesen Punkt liegt mein Problem. vll. 
bräcuhte ich da noch einen weiteren Denkanstoß bzw. Erklärung?

mfg sepp12

[GS (chromosoma)]

Hier, guck mal mein Tutorial an. Vllt hilft das;)


https://www.youtube.com/watch?v=WK5FT5RD1sU

[Lothar M. (Firma: Titel) (lkmiller) (Moderator)]

Mar B. schrieb:
> Wie ist das zu verstehen, denke an diesen Punkt liegt mein Problem. vll.
> bräcuhte ich da noch einen weiteren Denkanstoß bzw. Erklärung?
Mal angenommen, deine VGA Erzeugung läuft schon richtig, dann würde ich 
für ein blaues Rechteck sowas vorschlagen:

 if horizontal_counter >= links and vertikal_counter >= oben then 
       blue  <= "111";
       red   <= "000";
       green <= "000";
 end if;

 if horizontal_counter > rechts and vertikal_counter > unten then 
       blue  <= "000";
       red   <= "000";
       green <= "000";
 end if;

Und dann machst du einen zweiten Prozess auf, in dem die Werte für 
links, rechts , oben und unten z.B. jede Zehntelsekunde neu berechnet 
werden. Wenn du z.B. auf rechts und links jeweils 1 addierst, solange 
links < 640, und dann jeweils 1 subtrahierst, solange rechts > 0, dann 
wandert das Rechteck immmer hin und her (du wirst herausfinden: du musst 
dir die Richtung natürlich merken).
Selbes für oben und unten, und das Rechteck wandert ausdauernd diagonal 
über den Bildschirm...

[Mar B. (sepp12)]

Danke hat mir sehr geholfen.

Probiere das heute gleich aus!

Was ich mich gestern noch gefragt habe ich hätte eigtl vor am schluss so 
eine art videospiel daraus zu machen,in dem eine spielfigur objekten 
ausweicht.

Wie kann man eigtl. Spielfiguren z.b. so eine art "super mario"
darstellen?

Muss ich mir die aus den einzelnen pixeln zusammensetzen oder is dies in 
der art nicht möglich ?

mfg Sepp12

[Duke Scarring (Gast)]

Mar B. schrieb:
> Muss ich mir die aus den einzelnen pixeln zusammensetzen
Ja. Aber üblicherweise wird man Sprites, Buchstaben und Grafiken aus 
einem Speicher (RAM oder ROM) holen.

Hier gbt es eine Einführung in FPGAs:
http://www.youtube.com/watch?v=X51Qxdyb2Wo
Ab ca. 26:00 gibt es eine Demo und anschließend die Erklärung dazu.

Duke

[peter (Gast)]

Das DE-1Board hat Farbvectoren RGB 0-3 und nicht 0-2.

Gruss

[peter (Gast)]

Jup, das sieht ja gut aus.

Ich habe mein Viereck (Rot ) auf einen Platz gesetzt.
Es funktioniert.

Wie sieht jetzt bitte der Prozess aus um es zu verschieben nach rechts 
und nach lnks? Kommt in die Sensitiv-Liste ein clk mit 
rechts-links-oben-unten, oder ohne clk?

Danke.
Gruss

library IEEE;
use IEEE.STD_LOGIC_1164.ALL;
use ieee.numeric_std.ALL;

entity vga_timing1 is
port(
  clk50_in  : in std_logic;
  hs_out    : out std_logic;
  vs_out    : out std_logic;
  
  red_out   : OUT STD_LOGIC_VECTOR(3 downto 0);
  green_out : OUT STD_LOGIC_VECTOR(3 downto 0);
  blue_out  : OUT STD_LOGIC_VECTOR(3 downto 0)
  ); 
end vga_timing1;

architecture behavioral of vga_timing1 is

signal clk25    : std_logic:='0';
signal hcounter : integer := 0;
signal vcounter : integer := 0;
signal links : integer := 200;
signal rechts : integer := 220;
signal oben : integer := 200;
signal unten : integer := 220;

begin

-- generate a 25Mhz clock
process (clk50_in)
begin
  if clk50_in'event and clk50_in='1' then
    clk25 <= not clk25;
  end if;
end process;

process (clk25)
begin
  if clk25'event and clk25 = '1' then
    if (hcounter >= links) and (hcounter < rechts) and (vcounter >= oben) and (vcounter < unten) then 
       red_out<="1000";
     else
       red_out<="0000";
   end if;
  end if;
end process;

process (clk25)
begin
  if clk25'event and clk25 = '1' then
    if hcounter >= (639+16) and hcounter <= (639+16+96) then
      hs_out <= '0';
    else
      hs_out <= '1';
    end if;
  
    if vcounter >= (479+10) and vcounter <= (479+10+2) then
      vs_out <= '0';
     else
      vs_out <= '1';
    end if;
  
--- horizontal counts from 0 to 799
    hcounter <= hcounter+1;
  
    if hcounter = 799 then
      vcounter <= vcounter+1;
      hcounter <= 0;
    end if;
  
--- vertical counts from 0 to 524
    if vcounter = 524 then 
      vcounter <= 0;
    end if;
  end if;
end process;

end behavioral;

[peter (Gast)]

Ich möchte das Viereck bitte mit 2 Tasten bewegen.

Danke.

[peter (Gast)]

Wenn sw gedrückt dann hat er '0' ansonsten '1'.

Ich habe jetzt diesen Process mit reingesetzt:

process(sw(0),rechts,links)
begin   
  if (sw(0) ='0') then
    rechts <= rechts+1;
    links <= links+1;
    if rechts >= 640 then
      rechts <=120;
      links <=100;
    end if;  
  end if;    
end process;

Es ist nur ab zu ein roter Streifen zu sehen.

Gruss

[Lothar M. (Firma: Titel) (lkmiller) (Moderator)]

peter schrieb:
> Ich möchte das Viereck bitte mit 2 Tasten bewegen.
Du solltest also zuallererst diese Tasten einsynchronisieren.
Und dann eine Flankenerkennung drauf ansetzen.
Und dann bei erkannter Flanke die Grenzen ändern...

Hier mein Vorschlag zum Anpassen:

port(
   ...
   x_taster, y_taster  : in std_logic;
   ...
  ); 
:
:
signal xsr : std_logic_vector(3 downto 0) :=  (others=>'0');
signal ysr : std_logic_vector(3 downto 0) :=  (others=>'0');
:
:
begin
:
:
-- generate a 25Mhz clock !!! Wie gesagt: so macht man das nicht!
    clk25 <= not clk25;
:
:

process begin
  wait untilk rising_edge(clk25);
  xsr <= xsr(2 downto 0) & x_taster; -- Taster eintakten
  ysr <= ysr(2 downto 0) & y_taster;
  if xsr = "0111" then -- steigende Flanke
     if links = 619 then
        links  <= 0;
        rechts <= 20;
     else
        links  <= links+1;
        rechts <= rechts+1;
     end if;
  end if;
  if ysr = "0111" then
     if oben = 459 then
        oben  <= 0;
        unten <= 20;
     else
        oben  <= oben+1;
        unten <= unten+1;
     end if;
  end if;
end process;
  
:
:

Gib doch besser beim Integer den range mit an:

signal clk25    : std_logic:='0';
signal hcounter : integer range 0 to 751 := 0;
signal vcounter : integer range 0 to 491 := 0;
signal links    : integer range 0 to 619 := 200;
signal rechts   : integer range 20 to 639 := 220;
signal oben     : integer range 0  to 459 := 200;
signal unten    : integer range 20 to 479 := 220;

Dann kann der simulator gleich meckern, wenn was schiefläuft...

peter schrieb:
> Ich habe jetzt diesen Process mit reingesetzt:...
Ein Zähler, der ohne Takt gezählt wird: das ist eine kombinatorische 
Schleife.
http://www.lothar-miller.de/s9y/archives/42-Kombinatorische-Schleifen.html

[Lattice User (Gast)]

peter schrieb:
> Wenn sw gedrückt dann hat er '0' ansonsten '1'.
>
> Ich habe jetzt diesen Process mit reingesetzt:
>

> process(sw(0),rechts,links)
> begin
>   if (sw(0) ='0') then
>     rechts <= rechts+1;
>     links <= links+1;
>     if rechts >= 640 then
>       rechts <=120;
>       links <=100;
>     end if;
>   end if;
> end process;
>

>
> Es ist nur ab zu ein roter Streifen zu sehen.
>
> Gruss

Da das ein combinatorischer Prozess ist, ist er viel zu schnell. 
Ausserdem enthält er Latches, eine sehr schlechte Idee.

Pack das in den existierened Prozess (einmal pro Bild abfragen)

--- vertical counts from 0 to 524
    if vcounter = 524 then 
      vcounter <= 0;

      if (sw(0) ='0') then
        rechts <= rechts+1;
        links <= links+1;
        if rechts >= 640 then
          rechts <=120;
          links <=100;
        end if;  
      end if;    
    end if;

Davon abgesehen muss sw(0) noch entprellt und einsynchrinsiert werden, 
damit es zuverlässig funktioniert.

[Duke Scarring (Gast)]

peter schrieb:
> mit 2 Tasten
Hast Du die entprellt?
http://www.lothar-miller.de/s9y/categories/5-Entprellung

peter schrieb:
> process(sw(0),rechts,links)
> begin
>   if (sw(0) ='0') then
Das ist kombinatorische Logik und dürfte ein bischen zu schnell gehen, 
als das Du es mit dem Auge sehen kannst.

peter schrieb:
> um es zu verschieben nach rechts
> und nach lnks?
Du mußt Deine "links" und "rechts" Signale verändern. Aber nur so 
schnell, das Du noch was sehen kannst.

Duke

[Peter B. (funkheld)]

Jup, danke. Jetzt funktioniert es.
Die Tasten sind von Haus aus schon Entprellt beim DE-1.

Habe clk-50 reingenommen.
Jetzt kann ich mit den beiden Druck-Tastern das Quadrat hin und her 
schieben. Wenn es rechts anstösst(640) bleibt es stehen und wenn es 
links anstösst bleibt es stehen(0).

process(clk50_in,sw,rechts,links)
begin  
  if clk50_in'event and clk50_in='1' then
    if (c<499999) then       
      c <= c+1;                
    else    
      if (sw(0) ='0') then
        rechts <= rechts+1;
        links <= links+1;
        if rechts >= 640 then
          rechts <=640;
          links <=620;
        end if;  
      end if;
      if (sw(1) ='0') then
        rechts <= rechts-1;
        links <= links-1;
        if links = 0 then
          rechts <=20;
          links <=0;
        end if;  
      end if;
      c <= 0;  
    end if;  
  end if;
end process;

Gruss

[Lattice User (Gast)]

Peter Bierbach schrieb:
> Jup, danke. Jetzt funktioniert es.
> Die Tasten sind von Haus aus schon Entprellt beim DE-1.
>

Auch einsynchronisert auf deine clk50?
Wenn nicht wird manchmal beim Drücken der Tasten das Viereck wild 
springen und sich u.U. auch in der Breite ändern. Da du nur alle 10 
Milliseknden abfrägst wird das sehr sehr selten sein, ist aber genau die 
Art von Fehlern die sich nachträglich nur extrem schwer auffinden 
lassen.

process(clk50_in,sw,rechts,links)

Ein synchroner getakter Prozess darf nur die Clock, (und eventuell ein 
asynchrones Reset) in der Sensitivitylist haben.

[Lothar M. (Firma: Titel) (lkmiller) (Moderator)]

Peter Bierbach schrieb:
> if (sw(0) ='0') then
Peter, das mit dem Einsynchronisieren hast du gelesen? Willst du 
wissen, WARUM man das macht? Dann klick da drauf:
http://www.lothar-miller.de/s9y/archives/64-State-Machine-mit-asynchronem-Eingang.html
Genau sowas hast du dir da gerade gebaut.

[Peter B. (funkheld)]

Jup danke für den Hinweis.

Hier habe ich jetzt alle 4 Drucktasten reingebracht.
Das Viereck bleibt an den Kanten stehen  wenn es anstösst und dann muss 
man mit den Tasten die Richtung ändern. Mit meiner Zählschleife vom 
clk-50 (200000) läuft das Viereck flink und schlierenfrei über den 
Screen(640x480.

library IEEE;
use IEEE.STD_LOGIC_1164.ALL;
use ieee.numeric_std.ALL;

entity vga_timing1 is
port(
  clk50_in  : in std_logic;
  hs_out    : out std_logic;
  vs_out    : out std_logic;
  sw        : in STD_LOGIC_VECTOR(3 downto 0);
  
  red_out   : OUT STD_LOGIC_VECTOR(3 downto 0);
  green_out : OUT STD_LOGIC_VECTOR(3 downto 0);
  blue_out  : OUT STD_LOGIC_VECTOR(3 downto 0)
  ); 
end vga_timing1;

architecture behavioral of vga_timing1 is

signal clk25    : std_logic:='0';
signal hcounter : integer := 0;
signal vcounter : integer := 0;
signal links : integer := 100;
signal rechts : integer := 120;
signal oben : integer := 100;
signal unten : integer := 120;
signal c : integer range 0 to 500000 := 0; 

begin

process(clk50_in,sw,rechts,links,oben, unten)
begin  
  if clk50_in'event and clk50_in='1' then
    if (c<200000) then       
      c <= c+1;                
    else    
      if (sw(0) ='0') then
        rechts <= rechts+1;
        links <= links+1;
        if rechts = 640 then
          rechts <=640;
          links <=620;
              end if;  
      end if;
      if (sw(1) ='0') then
        rechts <= rechts-1;
        links <= links-1;
        if links = 0 then
          rechts <=20;
          links <=0;
        end if;  
      end if;
      if (sw(2) ='0') then
        unten <= unten+1;
        oben <= oben+1;
        if unten = 480 then
          unten <=480;
          oben <=460;
        end if;  
      end if;
      if (sw(3) ='0') then
        unten <= unten-1;
        oben <= oben-1;
        if oben = 0 then
          unten <=20;
          oben <=0;
        end if;  
      end if;
      c <= 0;  
    end if;  
  end if;
end process;  

process (clk50_in)
begin
  if clk50_in'event and clk50_in='1' then
    clk25 <= not clk25;
  end if;
end process;

process (clk25)
begin
  if clk25'event and clk25 = '1' then
    if (hcounter >= links) and (hcounter < rechts) and (vcounter >= oben) and (vcounter < unten) then 
       red_out<="1000";
     else
       red_out<="0000";
   end if;
  end if;
end process;

process (clk25)
begin
  if clk25'event and clk25 = '1' then
    if hcounter >= (639+16) and hcounter <= (639+16+96) then
      hs_out <= '0';
    else
      hs_out <= '1';
    end if;
  
    if vcounter >= (479+10) and vcounter <= (479+10+2) then
      vs_out <= '0';
     else
      vs_out <= '1';
    end if;
  
--- horizontal counts from 0 to 799
    hcounter <= hcounter+1;
  
    if hcounter = 799 then
      vcounter <= vcounter+1;
      hcounter <= 0;
    end if;
  
--- vertical counts from 0 to 524
    if vcounter = 524 then 
      vcounter <= 0;
    end if;
  end if;
end process;

end behavioral;

[Lattice User (Gast)]

Peter Bierbach schrieb:
> Jup danke für den Hinweis.
>
> Hier habe ich jetzt alle 4 Drucktasten reingebracht.
> Das Viereck bleibt an den Kanten stehen  wenn es anstösst und dann muss
> man mit den Tasten die Richtung ändern. Mit meiner Zählschleife vom
> clk-50 (200000) läuft das Viereck flink und schlierenfrei über den
> Screen(640x480.
>

Ab und zu wird Tearing zu sehen sein, immer dann wenn sich die Position 
ändert während das Viereck gerade ausgegeben wird.
Abhilfe: Position nur wärend des Vsyncs ändern.
Da das eventuell etwas langsam ist, Doublebuffering verwenden.
Im Tastenprozess: z.b links_neu statt links ändern,
Im Displayprozess bei vcounter = 524, links <= links_neu.

[Peter B. (funkheld)]

Jup danke.
Das wird wohl erst gehen wenn der Screen aus dem RAM bedient wird 
(Doublebuffering)?

-----------------------
Ausserdem enthält er Latches, eine sehr schlechte Idee
-----------------------
Warum sind die Latches nicht gut im zusätzlichen Process(sensitivity)?


Danke.

Gruss

[Lattice User (Gast)]

Peter Bierbach schrieb:
> Jup danke.
> Das wird wohl erst gehen wenn der Screen aus dem RAM bedient wird?
>
Wieso, dein Bild ist im Prinzip durch die 4 Register 
links,rechts,oben,unten bestimmt. Und diese 4 Register kannst du 
Doublebuffern. Lies nochmal die 2 letzen Zeilen meines vorigen Postings.

Nochmal zur Erinnerung: *Einsynchronisieren*:
Beitrag "Re: pixel bewegen bei vga-ansteuerung"

[max (Gast)]

Weil Latches nicht getaktet sind:
http://electronics.stackexchange.com/questions/38645/why-are-inferred-latches-bad

Du hast auch 2 Takte in deinem System. Das kann bei falschen 
Taktübergängen zu Problemen führen. Deshalb Clock-enable verwenden:

process (clk_50)               
begin
  if (clk_50 'EVENT and clk_50='1') then
    clk_25 <= not clk_25;
    if (clk_25 = '1') then -- das ist ein Clock-Enable
        if hcounter >= (639+16) and hcounter <= (639+16+96) then
          hs_out <= '0';
        else
          hs_out <= '1';
        end if;
        ...Rest von deinem Code

Das Einsynchronisieren der Tastensignale hat nichts mit dem Prellen zu 
tun, sondern damit, dass die Tastensignale asynchron zu deinem Takt 
sind. Dies führt zu Timingverletzungen... deswegen wie Hr. Miller es auf 
seiner Homepage hat machen.

[Lothar M. (Firma: Titel) (lkmiller) (Moderator)]

max schrieb:
> Deshalb Clock-enable verwenden
Ein Dejavu: Beitrag "Re: pixel bewegen bei vga-ansteuerung"

Leider zeigt sich Peter hier recht lernresistent...

[Peter B. (funkheld)]

So habe ich es geändert mit rechts_neu usw.
Mit sw kann ich jetzt auch die Farbe vom Viereck ändern.

Die Geschwindigkeit hat hier keine Einbußen.
Warum muss das bei vcounter=524 rein?

Danke.
Gruss

library IEEE;
use IEEE.STD_LOGIC_1164.ALL;
use ieee.numeric_std.ALL;

entity vga_timing1 is
port(
  clk50_in  : in std_logic;
  hs_out    : out std_logic;
  vs_out    : out std_logic;
  key       : in STD_LOGIC_VECTOR(3 downto 0);
  sw        : in STD_LOGIC_VECTOR(2 downto 0);
  
  red_out   : OUT STD_LOGIC_VECTOR(3 downto 0);
  green_out : OUT STD_LOGIC_VECTOR(3 downto 0);
  blue_out  : OUT STD_LOGIC_VECTOR(3 downto 0)
  ); 
end vga_timing1;

architecture behavioral of vga_timing1 is

signal clk25    : std_logic:='0';
signal hcounter : integer := 0;
signal vcounter : integer := 0;
signal links_neu : integer := 100;
signal rechts_neu : integer := 120;
signal oben_neu : integer := 100;
signal unten_neu : integer := 120;
signal links : integer := 0;
signal rechts : integer := 0;
signal oben : integer := 0;
signal unten : integer := 0;
signal c : integer range 0 to 500000 := 0; 
signal red   : STD_LOGIC_VECTOR(3 downto 0);
signal green : STD_LOGIC_VECTOR(3 downto 0);
signal blue  : STD_LOGIC_VECTOR(3 downto 0);

begin

process(sw)
begin  
  if (sw(0) ='1') then 
    red<="1111";
    green<="0000";
    blue<="0000";
  end if;
  if (sw(1) ='1') then 
    red<="0000";
    green<="1111";
    blue<="0000";
  end if;
  if (sw(2) ='1') then 
    red<="0000";
    green<="0000";
    blue<="1111";
  end if;
end process;  

process(clk50_in,key,rechts_neu,links_neu,oben_neu, unten_neu)
begin  
  if clk50_in'event and clk50_in='1' then
    if (c<200000) then       
      c <= c+1;                
    else    
      if (key(0) ='0') then
        rechts_neu <= rechts_neu+1;
        links_neu <= links_neu+1;
        if rechts_neu = 640 then
          rechts_neu <=640;
          links_neu <=620;
        end if;  
      end if;
      if (key(1) ='0') then
        rechts_neu <= rechts_neu-1;
        links_neu <= links_neu-1;
        if links_neu = 0 then
          rechts_neu <=20;
          links_neu <=0;
        end if;  
      end if;
      if (key(2) ='0') then
        unten_neu <= unten_neu+1;
        oben_neu <= oben_neu+1;
        if unten_neu = 480 then
          unten_neu <=480;
          oben_neu <=460;
        end if;  
      end if;
      if (key(3) ='0') then
        unten_neu <= unten_neu-1;
        oben_neu <= oben_neu-1;
        if oben_neu = 0 then
          unten_neu <=20;
          oben_neu <=0;
        end if;  
      end if;
      c <= 0;  
    end if;  
  end if;
end process;  

process (clk50_in)
begin
  if clk50_in'event and clk50_in='1' then
    clk25 <= not clk25;
  end if;
end process;

process (clk25)
begin
  if clk25'event and clk25 = '1' then
    if (hcounter >= links) and (hcounter < rechts) and (vcounter >= oben) and (vcounter < unten) then 
       red_out<= red;
       green_out<=green;
       blue_out<=blue;
     else
       red_out<="0000";
       green_out<="0000";
       blue_out<="0000";
   end if;
  end if;
end process;

process (clk25,unten_neu,oben_neu,rechts_neu,links_neu)
begin
  if clk25'event and clk25 = '1' then
    if hcounter >= (639+16) and hcounter <= (639+16+96) then
      hs_out <= '0';
    else
      hs_out <= '1';
    end if;
  
    if vcounter >= (479+10) and vcounter <= (479+10+2) then
      vs_out <= '0';
     else
      vs_out <= '1';
    end if;
  
--- horizontal counts from 0 to 799
    hcounter <= hcounter+1;
  
    if hcounter = 799 then
      vcounter <= vcounter+1;
      hcounter <= 0;
    end if;
  
--- vertical counts from 0 to 524
    if vcounter = 524 then 
      rechts <= rechts_neu;
      links <= links_neu;
      oben <= oben_neu;
      unten <= unten_neu;
      vcounter <= 0;
    end if;
  end if;
end process;

end behavioral;

[Peter B. (funkheld)]

Hmmm. unter Doublebuffern verstehe ich das fertige Bild aus dem RAM auf 
den SCreen abbilden.

Muss das jetzt so in jedem Process, wo die clk_25 als sensitive 
gebraucht wird?
-------------------------
if(clk_50 'Event and clk_50 = '1') then -- im ganzen Design der selbe 
Takt!!
  if clk_25='1' then -- das ist ein Clock-Enable
--------------------------

process (clk50_in)
begin
if (clk50_in 'EVENT and clk50_in='1') then
  if clk25 = '1' then
    if (hcounter >= links) and (hcounter < rechts) and (vcounter >= oben) and (vcounter < unten) then 
       red_out<= red;
       green_out<=green;
       blue_out<=blue;
     else
       red_out<="0000";
       green_out<="0000";
       blue_out<="0000";
   end if;
  end if;
end if;  
end process;

process (clk50_in,unten_neu,oben_neu,rechts_neu,links_neu)
begin
if(clk50_in 'Event and clk50_in = '1') then 
  if clk25 = '1' then
    if hcounter >= (639+16) and hcounter <= (639+16+96) then
      hs_out <= '0';
    else
      hs_out <= '1';
    end if;
  
    if vcounter >= (479+10) and vcounter <= (479+10+2) then
      vs_out <= '0';
     else
      vs_out <= '1';
    end if;
  
--- horizontal counts from 0 to 799
    hcounter <= hcounter+1;
  
    if hcounter = 799 then
      vcounter <= vcounter+1;
      hcounter <= 0;
    end if;
  
--- vertical counts from 0 to 524
    if vcounter = 524 then 
      rechts <= rechts_neu;
      links <= links_neu;
      oben <= oben_neu;
      unten <= unten_neu;
      vcounter <= 0;
    end if;
  end if;
end if;  
end process;

Danke.
Gruss

[Lothar M. (Firma: Titel) (lkmiller) (Moderator)]

Peter Bierbach schrieb:
> Hmmm. unter Doublebuffern verstehe ich das fertige Bild aus dem RAM auf
> den SCreen abbilden.
Man kann auch nur die Koordinaten des Teils des bildes, das sich 
ändert puffern. Denn nur dieser Teil kann Probleme machen. Auch das 
ist Double Buffering...

[Peter B. (funkheld)]

Warum gibt es bei "c" keine Fehlermeldung, obwohl "c" nicht in der 
Empfindlichkeitsliste steht?

Danke.

process(clk50_in,key,rechts_neu,links_neu,oben_neu, unten_neu)
begin  
  if clk50_in'event and clk50_in='1' then
    if (c<200000) then       
      c <= c+1;                
    else    
      if (key(0) ='0') then
        rechts_neu <= rechts_neu+1;
        links_neu <= links_neu+1;
        if rechts_neu = 640 then
          rechts_neu <=640;
          links_neu <=620;
        end if;  
      end if;
      if (key(1) ='0') then
        rechts_neu <= rechts_neu-1;
        links_neu <= links_neu-1;
        if links_neu = 0 then
          rechts_neu <=20;
          links_neu <=0;
        end if;  
      end if;
      if (key(2) ='0') then
        unten_neu <= unten_neu+1;
        oben_neu <= oben_neu+1;
        if unten_neu = 480 then
          unten_neu <=480;
          oben_neu <=460;
        end if;  
      end if;
      if (key(3) ='0') then
        unten_neu <= unten_neu-1;
        oben_neu <= oben_neu-1;
        if oben_neu = 0 then
          unten_neu <=20;
          oben_neu <=0;
        end if;  
      end if;
      c <= 0;  
    end if;  
  end if;
end process;

[Lattice User (Gast)]

Peter Bierbach schrieb:
> Warum gibt es bei "c" keine Fehlermeldung, obwohl "c" nicht in der
> Empfindlichkeitsliste steht?
>
> Danke.
>

Weil für einen getakten Prozess (wie chon mal angemerkt) ohne Reset nur 
die
Clock da rein muss

process(clk50_in)

[Mar B. (sepp12)]

Hallo nochmal,

hätte da noch ne frage, wenn ich jetzt zuällig ein objekt am monitor 
ausgeben möchte ohne vorher festzulegen bei welcher x und y position es 
sich befindet, könnte man das mit einem pseudo random noise generator 
machen oder nicht?

falls es möglich ist, wie begrenzt man zum beispiel das objekt auf den 
rechten oder linken bildschirmteil, wenn ich in mittig teilen würde.


mfg

sepp12

[Lothar M. (Firma: Titel) (lkmiller) (Moderator)]

Mar B. schrieb:
> hätte da noch ne frage, wenn ich jetzt zuällig ein objekt am monitor
> ausgeben möchte ohne vorher festzulegen bei welcher x und y position es
> sich befindet, könnte man das mit einem pseudo random noise generator
> machen oder nicht?
Ja. Stichwort LFSR.
Ein LFSR mit 64Bit Breite wäre toll für die nachfolgende Strategie.

> falls es möglich ist, wie begrenzt man zum beispiel das objekt auf den
> rechten oder linken bildschirmteil, wenn ich in mittig teilen würde.
Man begrenzt für die linke Bildschirmhälfte den Wertebereich auf 0..299 
(bei einer Objektbreite von 20 Pixeln) und addiert für die rechte Hälfte 
auf diesen Wert noch 320 drauf.
Weil aber eine  modulo-300 Rechnung auf einem FPGA umständlich ist, 
würde ich eine Zufallszahl mit 64 Bit Breite ermitteln, daraus dann 
einzelne Bitmuster "ausschneiden": 1x 0..255 (8 Bit), 1x 0..31 (5 Bit), 
1x 0..7 (3 Bit), 2x 0..3 (je 2 Bit) und dann alle zusammenaddieren: 
fertig ist die Zufallszahl von 0..255+31+7+3+3 = 0..299

Hier sieht man schon, dass eine geschickte Auswahl der Obergrenze (bzw. 
"Quadratbreite") die Anzahl der nötigen Berechnungen signifikant 
reduzieren kann. Mit einer Breite von 18 wäre eine Zufallszahl von 
0..301 nötig, die sich aus drei kleineren Werten zusammenaddieren lässt: 
255+31+15