Programm soll statt Atmega8 auf Atmega48 laufen

[Markus A. (tubeland)]

Hallo,

Anbei habe ich hier ein Programm einer Flip Flop Schaltung diese Läuft 
auf dem AT Mega8 einwandfrei

Nun habe ich Probleme dieses Programm auf einen ATmega48 am laufen zu 
bekommen.

Anbei das Programm und die Fehlermeldung

.include "m48def.inc"

.def iwr0      = r1
.def iwr1      = r2

.def key_old   = r3
.def key_state = r4
.def key_press = r5

.def temp1     = r17
.def sreg_save = r18


.equ key_pin   = PINB
.equ key_port  = PORTB
.equ key_ddr   = DDRB

.def leds      = r19
.equ led_port  = PORTD
.equ led_ddr   = DDRD

.org 0x0000
;rcall   EEPROM_read
    rjmp    init

.org OVF0addr
    rjmp    timer_overflow0

;
; *****************************************************************************
;
; Initialisierung
; Alle Komponenten auf die Startbedingungen einstellen
;
init:
;
;  Stackpointer
;
    ldi      temp1, HIGH(RAMEND)
    out      SPH, temp1
    ldi      temp1, LOW(RAMEND)     ; Stackpointer initialisieren
    out      SPL, temp1
;
; Ausgänge
;
    ldi      temp1, 0xFF
    out      led_ddr, temp1
;
; Eingänge
;
    ldi      temp1, 0xFF            ; Tasten sind auf Eingang
    out      key_port, temp1        ; Pullup Widerstände ein
;
; Timer für die Tastenabfrage
;
    ldi      temp1, 1<<CS02 | 1<<CS00   ; Timer mit Vorteiler 1024
    out      TCCR0, temp1
    ldi      temp1, 1<<TOIE0            ; Timer Overflow Interrupt einrichten
    out      TIMSK, temp1

    clr      key_old                ; die Register für die Tastenauswertung im
    clr      key_state              ; Timer Interrupt initialisieren
    clr      key_press

    sei                             ; und los gehts: Timer frei

;
; aus dem EEPROM den letzten Zustand wiederherstellen

    ldi      ZL,low(daten)
    ldi      ZH,high(daten)
    rcall    EEPROM_read            ; Byte ist in r16
  
    mov      leds, r16
  out      led_port, leds    

;
; Alles ist eingerichtet. Jetzt gehts mit der eigentlichen Arbeit los
;
main:
    cli                             ;
    mov      temp1, key_press       ; Einen ev. Tastendruck merken und ...
    clr      key_press              ; Tastendruck zurücksetzen
    sei

    cpi      temp1, 0               ; Tastendruck auswerten. Wenn eine von 8 Tasten
    breq     main                   ; gedrückt worden wäre, wäre ein entsprechendes
                                    ; Bit in key_press gesetzt gewesen

    eor      leds, temp1            ; Die zur Taste gehörende Led umschalten
    out      led_port, leds

                                    ; und den neuen Zustand im EEPROM ablegen
                                    ; das Z-Register ist noch vom Lesen an
                                    ; der richtigen Stelle
    mov      r16, leds
    rcall    EEPROM_write

    rjmp     main

;
; *****************************************************************************
;
; Timer Overflow
; wird regelmässig aufgerufen und hat die Aufgabe die Tasten auszuwerten
;
; Eine vollständig gedrückte Taste wird im Register key_press mit einem
; 1 Bit vermerkt. Der Benutzer ist selbst dafür zuständig, dieses Bit
; wieder zu löschen
;
timer_overflow0:               ; Timer Overflow Interrupt

    push    r0                 ; temporäre Register sichern
    in      r0, SREG
    push    r0
    push    iwr0
    push    iwr1

get8key:                       ;/old      state     iwr1      iwr0
    mov     iwr0, key_old      ;00110011  10101010            00110011
    in      key_old, key_pin   ;11110000
    eor     iwr0, key_old      ;                              11000011
    com     key_old            ;00001111
    mov     iwr1, key_state    ;                    10101010
    or      key_state, iwr0    ;          11101011
    and     iwr0, key_old      ;                              00000011
    eor     key_state, iwr0    ;          11101000
    and     iwr1, iwr0         ;                    00000010
    or      key_press, iwr1    ; gedrückte Taste merken
;
;
    pop     iwr1               ; Register wiederherstellen
    pop     iwr0
    pop     r0
    out     SREG, r0
    pop     r0
    reti

;
; *****************************************************************************
;
; Lesefunktion aus dem EEPROM
;
; Die Adresse von der gelesen werden soll, wird im Z-Register übergeben (r30/r31)
;
; Das gelesene Byte bekommt man im Register r16 zurückgeliefert
;
EEPROM_read:
    sbic    EECR,EEWE                   ; prüfe ob der vorherige Schreibzugriff
                                        ; beendet ist
    rjmp    EEPROM_read                 ; nein, nochmal prüfen

    out     EEARH, ZH                   ; Adresse laden
    out     EEARL, ZL
    sbi     EECR, EERE                  ; Lesevorgang aktivieren
    in      r16, EEDR                   ; Daten in CPU Register kopieren
  ;out      led_port, leds
    ret

;
; *****************************************************************************
;
; Schreibfunktion ins EEPROM
;
; Die Adresse an die geschrieben werden soll, wird im Z-Register übergeben (r30/r31)
; Das zu schreibende Byte wird im Register r16 übergeben
;
EEPROM_write:
    sbic    EECR, EEWE                  ; prüfe ob der letzte Schreibvorgang beendet ist
    rjmp    EEPROM_write                ; wenn nein, nochmal prüfen
 
    out     EEARH, ZH                   ; Adresse schreiben
    out     EEARL, ZL                   ; 
    out     EEDR, r16                   ; Daten  schreiben
    in      sreg_save,sreg              ; SREG sichern
    cli                                 ; Interrupts sperren, die nächsten
                                        ; zwei Befehle dürfen NICHT
                                        ; unterbrochen werden
    sbi     EECR,EEMWE                  ; Schreiben vorbereiten
    sbi     EECR,EEWE                   ; Und los !
    out     sreg, sreg_save             ; SREG wieder herstellen
    ret


; Daten im EEPROM definieren
;
.eseg
;
daten:
    .db     0b00000000

Das sind die Meldungen

C:\flipflop at mega48\flipflopneu3.asm(1): Including file 'C:\Programme\Atmel\AVR Tools\AvrAssembler2\Appnotes\m48def.inc'
C:\flipflop at mega48\flipflopneu3.asm(57): error: Undefined symbol: TCCR0
C:\flipflop at mega48\flipflopneu3.asm(59): error: Undefined symbol: TIMSK
C:\flipflop at mega48\flipflopneu3.asm(153): error: Undefined symbol: EEARH
C:\flipflop at mega48\flipflopneu3.asm(172): error: Undefined symbol: EEARH

Was muss dort anders sein damit es dann läuft?
Beste Grüße markus

[Fritz G. (fritzg)]

Schau ins Datenblatt vom Mega48, wie dort die Register heissen.Es gibt 
da z.B. TIMSK1 und TIMSK2.

[S. Landolt (Gast)]

Auch liegen die Register z.T. in einem anderen Adressbereich, also std 
statt out.
Und der ATmega48 hat nur 256 Bytes EEPROM, also kein EEARH.

[NobbyH (Gast)]

Wie Fritz schon schrieb sind die Register vom ATMEGA8 und ATMEGA48 
teilweise unterschiedlich. D.h. Du musst diese entsprechend anpassen 
damit das Programm auf dem ATMEGA48 läuft.
In der Liste der Fehlermeldungen siehst Du genau, welche Register nicht 
identisch sind bzw. andere Namen haben:

D:\Software\Flipflop.asm(1): Including file 'C:\Program Files\Atmel\AVR 
Tools\AvrAssembler2\Appnotes\m48def.inc'
D:\Software\Flipflop.asm(57): error: Undefined symbol: TCCR0
D:\Software\Flipflop.asm(59): error: Undefined symbol: TIMSK
D:\Software\Flipflop.asm(154): error: Undefined symbol: EEARH
D:\Software\Flipflop.asm(173): error: Undefined symbol: EEARH

Es können aber auch die Inhalte der Register abweichend sein.
Details findest Du im Datenblatt

[Markus A. (tubeland)]

ist es dann EERE ?

[S. Landolt (Gast)]

(Pardon, Sie sollten wirklich das Datenblatt zur Hand nehmen)

EERE ist ein Bit im EECR.
Vermutlich gibt es nur EEARL, müsste ich aber auch erst ausprobieren.

[Hannes J. (Firma: _⌨_) (pnuebergang)]

Als groben Anhaltspunkt kannst du mal in den Migration Guide vom atmega8 
zum atmega88 (ja, 88 nicht 48) reinsehen.

[Dieter F. (Gast)]

Lustig:

Beitrag "atmega8 Flip flop"

[Markus A. (tubeland)]

Mich macht es neugierig was gemacht werden muss damit es funktioniert 
wenn ich es wüste würde ich nicht fragen

[S. Landolt (Gast)]

Ob Ihnen das auf Dauer wirklich weiterhilft?

;    out      TCCR0, temp1
    out      TCCR0B, temp1

;    out      TIMSK, temp1
    sts      TIMSK0, temp1

;    out     EEARH, ZH                   ; Adresse laden

;    out     EEARH, ZH                   ; Adresse schreiben

[Markus A. (tubeland)]

Nach der Änderung sind die Fehlermeldungen weg nur funktioniert es so 
nicht. Oder muss
;    out     EEARH, ZH                   ; Adresse laden

;    out     EEARH, ZH                   ; Adresse schreiben
auch ersetzt werden?

[S. Landolt (Gast)]

> nur funktioniert es so nicht.
Zur Funktion kann ich nichts sagen, ich habe nur rein formal umgesetzt; 
wollte eigentlich auch nur meinen Schreibfehler von ganz oben 
wiedergutmachen.

Die beiden Zeilen mit EEARH werden ersatzlos gestrichen.

[S. Landolt (Gast)]

Ich habe das jetzt mal eben zusammengesteckt: bei mir läuft es.
Einen schönen Sonntag wünsche ich.

[Hannes J. (Firma: _⌨_) (pnuebergang)]

Markus Andrzejewski schrieb:
> Mich macht es neugierig was gemacht werden muss damit es funktioniert
> wenn ich es wüste würde ich nicht fragen

Der Punkt ist, dass du offensichtlich in fünf Jahren nichts dazugelernt 
hast. Du kommst hier mit dem selben Mist an, der vor fünf Jahren schon 
falsch war. Du bestehst immer noch darauf es genau so falsch zu machen, 
obwohl man dir schon vor fünf Jahren gesagt hat, dass es so nicht 
funktioniert und dir gezeigt hat wie es geht.

Dann ignorierst du heute, wie vor fünf Jahren, alle Hinweise die dir zu 
unbequem sind. Anders ausgedrückt, wie vor fünf Jahren behandelst du uns 
als ob wir für dich nur ein Stück Scheiße sind.

[Markus A. (tubeland)]

Sorry, den hinweisen bin ich nach gegangen habe dann wohl an der 
falschen Stelle nach geschaut.

Muss sagen funktioniert jetzt doch. hatte den Taster zu kurz betätigt.

Habe dann

 ldi      temp1, 1<<CS02 | 1<<CS00   ; Timer mit Vorteiler 1024

geändert in

 ldi      temp1, 1<<CS01 | 1<<CS00   ; Timer mit Vorteiler 1024

so ist die Reaktion schneller.

Auf welche Seiten Hätte ich denn die Lösung gefunden?

[spess53 (Gast)]

HI

> ldi      temp1, 1<<CS01 | 1<<CS00   ; Timer mit Vorteiler 1024

Ohne nachzusehen: ist garantiert falsch

>so ist die Reaktion schneller.

>Auf welche Seiten Hätte ich denn die Lösung gefunden?

Ich tippe auf die CKDIV8-Fuse. Die gibt es beim ATMega8 nicht.

MfG Spess

[Dieter F. (Gast)]

spess53 schrieb:
>> ldi      temp1, 1<<CS01 | 1<<CS00   ; Timer mit Vorteiler 1024
>
> Ohne nachzusehen: ist garantiert falsch

Erstmal nur in Bezug auf den Kommentar ... die Fuse-Einstellung wird 
aber sicher auch eine Rolle spielen ... :-)

[Dieter F. (Gast)]

Markus Andrzejewski schrieb:
> Auf welche Seiten Hätte ich denn die Lösung gefunden

Ich schätze mal, im Datenblatt - bei Timer ...

[spess53 (Gast)]

Hi

>Erstmal nur in Bezug auf den Kommentar ...

Das war nicht auf den Kommentar gemünzt.

MfG Spess

[Dieter F. (Gast)]

spess53 schrieb:
> Das war nicht auf den Kommentar gemünzt

Worauf denn? Eine "gültige" Timer-Einstellung ist es - oder?

[S. Landolt (Gast)]

Der Sprung von /1024 auf /64 ist zu groß, soo langsam waren die Taster 
dann doch nicht.

[Dieter F. (Gast)]

S. Landolt schrieb:
> Der Sprung von /1024 auf /64 ist zu groß, soo langsam waren die Taster
> dann doch nicht.

Mit CKDIV8 passt das ungefähr - aber was ist sonst noch falsch ?

[S. Landolt (Gast)]

Einen eigentlichen Fehler kann ich nicht erkennen, auch fand ich die 
ursprüngliche Ansprechzeit nicht ungewöhnlich (bin eine Logamatic 2107 
gewohnt).
Aber ich hätte den Mittelweg gewählt, also /256.

[spess53 (Gast)]

Hi

>Worauf denn? Eine "gültige" Timer-Einstellung ist es - oder?

Klar. Aber wenn im ursprünglichen Programm der Vorteiler von von 1024 
für eine angemessene 'Langsamkeit' notwendig war, und jetzt dafür ein 
Vorteiler von 128 notwendig ist, zeugt das von einer langsameren 
Taktfrequenz als angenommen.

MfG Spess