Arduino tone() bzw. delayMicroseconds() zu lang

[YannikW (Gast)]

Hi,

ich habe ein kleines Problem, dass ich jetzt mit meinem neuen kleinen 
Oszi entlich entlarven konnte. (DSO138 von BG - nettes kleines Spielzeug 
und für viele sicher ausreichend :P )

Aber zum eigentlichen Problem.
Für ein Infrarot Sender & Empfänger möchte ich mein eigenes IR Signal 
"bauen".

Damit der Empfänger das Signal wahrnimmt ist es 38kHz codiert. Die Daten 
werden dann einfach duch die Puls-/Pausenlängen übertragen. Dazu brauche 
ich Pulslängen im Bereich ~300-500µS.

Testweise habe ich es mal mit 1mS Pulslänge probiert.

hier der Code :

void loop() {
  tone(3, 38000);
  delayMicroseconds(1000);
  noTone(3);
  delayMicroseconds(1000);
}

Da kommt nun leider das raus was ihr auf dem Bild "38kHz Puls 500Hz 
delaymicroseconds" seht. Die Pause passt, der Puls ist aber etwa 2,3ms 
lang..

Selber Code mit

delay(1);

 liefert ein besseres Ergebnis, aber so richtig passt es immernoch 
nicht, siehe "38kHz Puls 500Hz delay"

Ein mit digitalWrite und delayMicroseconds erzeugtes 500Hz 
Rechtecksignal passt perfekt.

Es scheint also, als würde tone() nicht mit delayMicroseconds() zusammen 
funktionieren. Kann das sein??

Hätte da einer ne Idee, wie man das beheben könnte? :)

[Basti B. (basti195)]

Die Funktionen müssen irgend woher wissen was du für ein Taktsignal 
einspeist.
bei _delay_ms(xy); übergibt man dem Programm durch
#define F_CPU 16000000
das es sich um ein 16mhz takt handelt.

[YannikW (Gast)]

Bei Arduino sollte das nicht extra nötig sein, oder?

[ooOoo (Gast)]

Sebastian B. schrieb:
> das es sich um ein 16mhz takt handelt.

Millihertz - wie süß :-)

[YannikW (Gast)]

Habe eine Lösung gefunden.. Bzw einen anderen Weg ;)

Habe jetzt für das 38kHz PWM einfach einen CTC Timer genommen.

Damit klappt es einwandfrei :)

void setup() 
{
  pinMode(3, OUTPUT);
  
  //clear Timer2
  TCCR2A = 0;
  TCCR2B = 0;
  
  //set timer2 on 76kHz (2*38) toggle Pin D3
  TCCR2A |= (1 << COM2B0);    //Toggle OC2B on compare match
  TCCR2A |= (1 << WGM21);     //CTC Mode
  
  TCCR2B |= (1 << CS20);      //No Prescaler
  
  OCR2A = 209;                //(16000000 / 76000) - 1
}

void loop()
{
  enableSignal();
  delayMicroseconds(1000);
  disableSignal();
  delayMicroseconds(1000);
}

void enableSignal()
{
  TCCR2B |= (1 << CS20);    //Enable Timer
  TCCR2A |= (1 << COM2B0);  //Eable toggle OC2B on compare match
}

void disableSignal()
{
  TCCR2B &= ~(1 << CS20);    //Disable Timer
  TCCR2A &= ~(1 << COM2B0);  //Get access for manualy set OC2B to low
  PORTD &= ~(1 << 3);        //Set D3 to low
}