LED Ladestandsanzeige

[Edgar (Gast)]

Hallo,

ich hänge bei der Planung einer Schaltung fest.

Ich möchte für einen 6S LiPo Akku eine Ladestandsanzeige bauen. Im 
Grunde soll diese Schaltung die selbe Funktion wie der LM3914 haben, 
jedoch sollen die LEDs nicht in linearen Schritten angesteuert werden, 
sondern der Entladekurve einer LiPo angepasst.

Wie kann ich das realisieren?

[Wolfgang (Gast)]

Edgar schrieb:
> Wie kann ich das realisieren?

Mit einem passenden ausgelegten Spannungsteiler für die Vergleichswerte 
der Komparatorstufen, jedenfalls wenn du es analog aufbauen möchtest.

Falls du lieber einen µC verwenden möchtest - und das vermute ich mal 
auf Grund des Unterforums, in dem du deine Frage stellst - nimmst du 
einen µC mit ADC und kannst mit dem Messwert dann eine Tabelle mit den 
Schwellwerten abklappern, die du vorher hinterlegt hast.

[ek13 (Gast)]

Suche mal nach lipowächter bei eBay. Vielleicht ist da schon was 
passendes dabei.

[akku (Gast)]

Ich hab sowas mal für nen Tiny13 gemacht:

Der Spannungsteiler für den Analogeingang war so dimensioniert das bei 
Randvollem Akku 5V (AREF=5V) am Eingang erreicht werden. Aber das kann 
ja jeder für sich anders machen.

;
; Li-Ion Akku Ladestandanzeige für ATTiny13.
; 5 LED Anzeige inkl. Unterspannungswarnung.
; 07/2016 Björn Wieck
;

.include "tn13def.inc"

.def temp  = r16
.def temp1 = r17
.def temp2 = r18
.def AIn = r19


; FUSE CLK/8 setzen!!

;LED1=PB0, LED2=PB1, LED3=PB2, LED4=PB3, LED5=PB4; Analog-In=PB5

.org 0x0000

    rjmp    init      ;Reset


init:
    ldi  temp, LOW(RAMEND)  ;Stackpointer initialisieren
    out   SPL, temp
     ldi  temp, 0b00011111  ;PortB 0-4 auf Ausgang
    out  DDRB, temp
    ldi  temp, 0b00011111  ;Alle LEDs Ausschalten
    out  PORTB, temp

    ;ADC einrichten
    ldi  temp, (1<<ADLAR) | (0<<REFS0) | (0<<MUX1) | (0<<MUX0)  ;Auflösung 8-Bit, REF=Vcc, Kanal 0
    out  ADMUX, temp
    ldi   temp, (1<<ADEN) | (1<<ADSC) | (1<<ADATE) | (1<<ADPS2) | (1<<ADPS1)  ;AD-Wandler einschalten, Freilaufend
    out  ADCSRA, temp
    ldi  temp, 0
    out  ADCSRB, temp

Start:
    rcall  GetADC      ;Spannung messen
    cpi  AIn, 215    ;Wenn Unterspannung dann LED 1 Blinken lassen
    brlo  Blink
    cpi  AIn, 247    ;Akku 80-100%
    brsh  LED5
    cpi  AIN, 239    ;Akku 60-80%
    brsh  LED4
    cpi  AIn, 229    ;Akku 40-60%
    brsh  LED3
    cpi  AIn, 223    ;Akku 20-40%
    brsh  LED2
    cpi  AIn, 215    ;Akku 0-20%
    brsh  LED1
    rjmp  Start


LED5:  ldi  temp, 0b00000000    ;LED 1-5 einschalten
    out  PORTB, temp
    rjmp  Start

LED4:  ldi  temp, 0b00010000    ;LED 1-4 einschalten
    out  PORTB, temp
    rjmp  Start

LED3:  ldi  temp, 0b00011000    ;LED 1-3 einschalten
    out  PORTB, temp
    rjmp  Start

LED2:  ldi  temp, 0b00011100    ;LED 1-2 einschalten
    out  PORTB, temp
    rjmp  Start

LED1:  ldi  temp, 0b00011110    ;LED1 einschalten
    out  PORTB, temp
    rjmp  Start

Blink:  ldi  temp, 0b00011110    ;LED 1 blinkt
    out  PORTB, temp
    rcall  Wait
    ldi  temp, 0b00011111
    out  PORTB, temp
    rcall  Wait
    rjmp  Start

Wait:          ; Warteschleife für ca. 200 Millisekunden --> wenns flackert dann CLK/8 vergessen ;)
    ldi  temp1, 255
    ldi  temp2, 128
wl1:  dec  temp1
    brne  wl1
    dec  temp2
    brne  wl1
    ret

GetADC:    sbi  ADCSRA, ADIF      ;logisch "1" löscht ADIF flag !
adwait1:                     ;Erster Wert ignorieren, da meist Ungenau
    sbis  ADCSRA, ADIF
    rjmp  adwait1
    sbi  ADCSRA, ADIF    ;logisch "1" löscht ADIF flag !, nochmal
adwait2:              ;neuen ADC-Wert lesen
    sbis  ADCSRA, ADIF 
    rjmp  adwait2

; Noch genauere Werte würden sich ergeben wenn der ADC mehrfach eingelesen wird, dessen Werte summiert und durch die Schleifendurchläufe geteilt wird.
; In dieser Anwendung ist das aber Unrelevant.

; ADC-Wert übernehmen
    in   AIn, ADCH
    ret

[Edgar (Gast)]

Wolfgang schrieb:
> und das vermute ich mal
> auf Grund des Unterforums

ups, falsches Unterforum :)

möchte das ganze analog aufbauen.

[Edgar (Gast)]

Aber das ganze mit einem uC zu realisieren ist auch interessant.
Danke für die Idee.

[akku (Gast)]

Analog geht natürlich auch. Hier ist ein Plan aus einer Anzeige eines 
Fahrradakku den ich mal aufgenommen habe.

Musst du halt für deine Gegebenheiten anpassen, hier R7 und R9

[Wolfgang (Gast)]

Edgar schrieb:
> möchte das ganze analog aufbauen.

Dann bietet dir das Blockschaltbild vom LM3914 (S.8 im Datenblatt) doch 
schon mal einen Überblick über die zu realisierenden Funktionen. Mit 
4-fach Komparatoren hält sich der Aufwand noch in Grenzen.