include headerfiles in Assembler

[Dominik (Gast)]

Hallo,
ich bin neu in Assembler und komme nicht ganz mit der $include Funktion 
bzw. den headerfiles in Assembler zurecht. Als IDE benutzte ich Keil.

Ich habe ein Programm geschrieben, mit dem ich auf ein LCD Display 
zugreifen kann. Um alles etwas zu vereinfachern möchte ich das ganze 
jetzt als externe Datei haben und eben die einzelnen 
Methoden/Unterprogramme so aufrufen.
Allerdings funktioniert es nicht ganz so wie ich es mir vorstelle, trotz 
Tutorials und Erklärungen.

Zudem habe ich niergends gefunden, ob die Variablendeklaration, so wie 
ich es gemacht habe überhaupt funktionieren kann. Oder ob ich die 
Register für meine externe Datei verwenden darf.

Wie gesagt bin ich blutiger Anfänger, ich hoffe trotzdem, dass mir 
jemand helfen kann.

Einzubinden habe ich es auf diesem Weg versucht:

$include(lcd_display.h)

ORG 00h
  SJMP INIT_PROGRAMM
  
INIT_PROGRAMM:
  MOV P1,#00110011b

  ACALL LCD_INIT // Unterprogramm aus lcd_display
    
  MOV A, #41h // A
  ACALL LCD_DATA // Unterprogramm aus lcd_display
  
  MOV P1,#11001100b
END

Das ist das Programm, welches ich gerne als Headerfile benutzten würde:

U  EQU  31    ;Variable um Upper Nibble zu speichern
L  EQU  32    ;Variable um Lower Nibble zu speichern
  
PORT   EQU  P2   ; Port direkt
D4     EQU  p2.0 ; Datenbus
D5     EQU  p2.1 ; Datenbus
D6     EQU  p2.2 ; Datenbus
D7    EQU  p2.3 ; Datenbus
HG     EQU  p2.7 ; ?
RS    EQU  p2.6 ; Register Select ( 0 = Befehl / 1 = Daten )
RW    EQU  p2.5 ; Read / Write ( 0 = Schreiben / 1 = Lesen )
EN    EQU  p2.4 ; Enable

  
LCD_INIT:
  CLR RS
  SETB RW
  
  // 4-Bit Datenlänge einschalten
  MOV PORT, #0
  SETB D5
  ACALL DELAY

  // 4-Bit Datenlänge, 2-zeiliges Display, 5x7 Front
  MOV PORT, #0
  SETB D5
  ACALL DELAY
  
  MOV PORT, #0
  SETB D7
  ACALL DELAY
  
  // Display ein, Cursor ein, Cursor blinken
  MOV PORT, #0
  ACALL DELAY
  
  MOV PORT, #0
  SETB D4
  SETB D5
  SETB D6
  SETB D7
  ACALL DELAY
  
  // Display löschen, Cursor auf Position 1 setzen
  MOV PORT, #0
  ACALL DELAY
  
  MOV PORT, #0
  SETB D4
  ACALL DELAY
  
  // Cursor Auto-Increment
  MOV PORT, #0
  ACALL DELAY  
  
  MOV PORT, #0
  SETB D5
  SETB D6
  ACALL DELAY  
  ACALL WAIT_L
RET

SEPARATOR: // Seperator teilt das Byte in Upper und Lower Nibble, um den 4bit Datentransport zu ermöglichen
  // Beispielsbuchstabe: 0101 0011
    mov  L ,A     ; schreibe 0101 0011 in Lower Nibble
    
    ANL  L, #00001111b ; AND prüfen mit 0101 0011 mit 0000 1111, ergibt 0000 0011
    
    SWAP A       ;  Tausche Akkuinhalt 0101 0011 ergibt 0011  0101
    
    MOV  U, A     ; schreibe 0011 0101 in Upper Nibble
    ANL  U, #00001111b ; AND prüfen mit 0011 0101 mit 0000 1111, ergibt 0000 0101
RET 


LCD_DATA: // Daten an LCD senden
  SETB RS
  //RS (Register Select) ist die Auswahl zwischen 0: "Instruction-Register" und 1: "Data-Register"
  // Instruction-Register (0) ist für Befehle, Data-Register (1) ist für Daten (z.B. Texte schreiben)

  ACALL  SEPARATOR
  ORL L, #11000000b ; OR prüfen mit 0000 0011 mit 1100 0000, ergibt 1100 0011
  ORL U, #11000000b ; OR prüfen mit 0000 0101 mit 1100 0000, ergibt 1100 0101
            ; laut Beschreibung sollte #10000000b statt #11000000b verwendet werden, 
            ; da RW auf 0 für Schreiben ist,
            ; allerdings funktioniert der Datentransport dann nicht
  ACALL  MOVE_TO_PORT
RET 
  

LCD_CMD: // Befehle an LCD senden
  CLR RS ; 
  SETB RW
  //RS (Register Select) ist die Auswahl zwischen 0: "Instruction-Register" und 1: "Data-Register"
  // Instruction-Register (0) ist für Befehle, Data-Register (1) ist für Daten (z.B. Texte schreiben)

  ACALL  SEPARATOR 
  ACALL  MOVE_TO_PORT
RET 


LCD_CLEAR: // Display löschen, Cursor auf Position 1 setzen
  MOV PORT, #0
  ACALL DELAY
  
  MOV PORT, #0
  SETB D4
  ACALL DELAY
RET
 

MOVE_TO_PORT: // Sende die Daten (Lower-& Upper-Nibble) an den Port  
  CLR RW // setze RW auf 0, bedeutet: Schreiben
  MOV PORT, U // Zuerst Upper Nibble
  ACALL DELAY
  
  CLR RW
  MOV PORT, L // Danach Lower Nibble

  ACALL DELAY  
RET


MOVE_CURSOR_RIGHT: // Cursor nach rechts bewegen
  CLR RS
  CLR RW
  // BEFEHL:
  
  // D7 D6 D5 D4 D3 D2 D1 D0
  //  0  0  0  1 SC RL  *  * 
  
  // RL: 0=Links 1=Rechts    SC: 0=Cursor 1=Display(Shift)  
  
  MOV A, #00010100b
  ACALL LCD_CMD
RET


MOVE_CURSOR_LEFT: // Cursor nach links bewegen
  CLR RS
  CLR RW
  MOV A, #00010000b
  ACALL LCD_CMD
RET


SHIFT_DISPLAY_RIGHT: // Display nach rechts verschieben
  CLR RS
  CLR RW
  MOV A, #00011100b
  ACALL LCD_CMD
RET


SHIFT_DISPLAY_LEFT: // Display nach links verschieben
  CLR RS
  CLR RW
  MOV A, #00011000b
  ACALL LCD_CMD
RET


DELAY: // Das Enable-Bit wird gesetzt, danach kurz gewartet und wieder gelöscht. 
       // So wird ein Befehl an das Display gesendet
  SETB  EN   
  ACALL WAIT
  CLR  EN    
RET


// Kürzeste WAIT-Schleife für LCD Display
WAIT:
  MOV R7 , #7
  l1: MOV R6 , #7
  l2: DJNZ R6, l2
    DJNZ R7, l1
RET

// Längere WAIT-Schleife für sichtbare Veränderungen
WAIT_L:
  MOV R5 , #60
  c1: MOV R4 , #60
  c2: MOV R3 , #60
  c3: DJNZ R3, c3
    DJNZ R4, c2
    DJNZ R5, c1
RET

[Matthias S. (Firma: matzetronics) (mschoeldgen)]

Dominik schrieb:
> $include(lcd_display.h)

Das solltest du erst an der Stelle im Code schreiben, an der es passt. 
Im Moment steht es vor dem Reset Vektor und damit wird vermutlich etwas 
überschrieben, spätestens, wenn das .ORG Statement kommt. Also erst an 
einer Stelle einfügen, wo es passt.

[Heinz V. (heinz_v)]

Was zeigt die IDE denn im Meldungsfenster?

[Dominik (Gast)]

Habe den $include Befehl jetzt nach INIT_PROGRAMM eingefügt, allerdings 
funktioniert es noch immer nicht.

Die IDE zeigt keine Warnings oder Fehler.

[Heinz V. (heinz_v)]

BTW. liegt die Include Datei (wieso eigentlich xxx.h und nicht xxx.inc?) 
denn im selben Verzeichniss wie dein Quellcode? Oder erwartet Keil vll 
sowieso eine absolute Pfad Angabe?

[Volker S. (vloki)]

Das macht man doch heutzutage nicht mehr so, oder?
(ORG und Programmcode über include einfügen. Dafür hat man doch den 
Linker)

Keil kabe schon seit Ewigkeiten nicht mehr benutzt, aber ich kann mir 
irgendwie nicht so recht vorstellen, dass das der Weg ist.
Frage an erfahrene Keil Assembler Nutzer: "Irre ich mich da total?"

[Heinz V. (heinz_v)]

Volker S. schrieb:
> Das macht man doch heutzutage nicht mehr so, oder?
> (ORG und Programmcode über include einfügen. Dafür hat man doch den
> Linker)

Include bindet einfach weiteren Quelltext ein, zur Zeit des 
Assemblierens, das ist aber kein einfaches 'merging' bei MASM32 oder A86 
werden nur die Prozeduren übersetzt die das Hauptprogramm auch 
verwendet.

Der org Pseudoopcode legt den Programmstart fest, doch manchmal ist das 
wohl nötig (x.bin Dateien starten normalerweise bei 0 und wei DOS/WIN 
Executables steht ein jmp Startaddresse am Anfang des Programmheaders.)

[Volker S. (vloki)]

Hmmm, auf den ersten Blick sah das für mich so nach 8051 Assembler aus.
Ist wohl einfach zu lange her ;-)