Signalwertzuweisung zu spät

[Johannes H. (Gast)]

Hallo liebe Forenbesucher,

ich hätte da ein Problem wo ich leider nicht weiter komme. Wie im 
Betreff schon angegeben, habe ich ein Signal, dem ich alle 100Hz, ein 
Wert zuweisen will, jedoch ist es leider so, dass die Zuweisung um 100Hz 
hinterherhinkt. Es ist auch so, dass alle 100Hz das Zeilensignal der 
Wert ändert. Ich habe auch ein Bild von der Simulation angehängt.

architecture rtl of col_row_buttons is 
  
    constant C_CNTR : natural := 1000000; -- um 100Hz zu generieren
    
    signal s_presc_cntr    : natural;
    signal s_column     : natural range 0 to 3;
    signal s_presc_en     : std_logic;
    signal s_column_buttons  : std_logic_vector (COL_ROW_BUTTONS - 1 downto 0);
    signal s_pressed_button  : std_logic_vector (KEYPAD_BUTTONS - 1 downto 0);
begin 
    
  -- generieren des 100 Hz signals
    
  p_presc : process (clk_i, reset_i) 
  begin 
    if reset_i = '1' then 
      s_presc_cntr <= 0;
      s_presc_en <= '0';
    elsif clk_i = '1' and clk_i'event then 
      if s_presc_cntr >= C_CNTR then 
        s_presc_en <= '1';
        s_presc_cntr <= 0;
      else
        s_presc_en <= '0';
        s_presc_cntr <= s_presc_cntr + 1;
      end if; 
    end if; 
  end process p_presc;
      
  -- Zeilenwert alle 100Hz ändern
  
  p_column : process (clk_i, reset_i)
  begin 
    if reset_i = '1' then 
      s_column_buttons <= x"F"; 
      s_column <= 0;
    elsif clk_i = '1' and clk_i'event then 
      if s_presc_en = '1' then 
        if s_column = 0 then 
          s_column_buttons <= "1110";
          s_column <= s_column + 1; 
        elsif s_column = 1 then 
          s_column_buttons <= "1101";
          s_column <= s_column + 1; 
        elsif s_column = 2 then 
          s_column_buttons <= "1011"; 
          s_column <= s_column + 1; 
        elsif s_column = 3 then 
          s_column_buttons <= "0111";
          s_column <= 0; 
        end if;         
      end if; 
    end if; 
  end process p_column;
        
  col_buttons_o <= s_column_buttons;

  -- anhand Zeilensignal gedrückte Taste ermitteln
  
  p_press_buttons : process (clk_i, reset_i)
  begin 
    if reset_i = '1' then 
      s_pressed_button <= (others => '1');
    elsif clk_i = '1' and clk_i'event then 
        if s_presc_en = '1' then             -- alle 100Hz
          case s_column_buttons (3 downto 0) is 
            when "1110" => 
              if row_buttons_i(0) = '0' then 
                s_pressed_button <= s_pressed_button or  X"0002";   
              elsif row_buttons_i (1) = '0' then 
                s_pressed_button <= s_pressed_button or X"0010";  
              elsif row_buttons_i (2) = '0' then 
                s_pressed_button <= s_pressed_button or X"0080";  
              elsif row_buttons_i (3) = '0' then 
                s_pressed_button <= s_pressed_button or X"0001";   
              elsif row_buttons_i <= "1111" then 
                s_pressed_button <= (others => '0');
              end if; 
            when "1101" =>
              if row_buttons_i(0) = '0' then 
                s_pressed_button <= s_pressed_button or  X"0004";   
              elsif row_buttons_i (1) = '0' then 
                s_pressed_button <= s_pressed_button or X"0020";  
              elsif row_buttons_i (2) = '0' then 
                s_pressed_button <= s_pressed_button or X"0100";  
              elsif row_buttons_i (3) = '0' then 
                s_pressed_button <= s_pressed_button or X"8000";   
              elsif row_buttons_i <= "1111" then 
                s_pressed_button <= (others => '0');
              end if;
            when "1011" => 
              if row_buttons_i(0) = '0' then 
                s_pressed_button <= s_pressed_button or X"0008";   
              elsif row_buttons_i (1) = '0' then 
                s_pressed_button <=  s_pressed_button or X"0040";  
              elsif row_buttons_i (2) = '0' then 
                s_pressed_button <=  s_pressed_button or X"0200";  
              elsif row_buttons_i (3) = '0' then 
                s_pressed_button <=  s_pressed_button or X"4000";   
              elsif row_buttons_i <= "1111" then 
                s_pressed_button <= (others => '0');
              end if;
            when "0111" => 
              if row_buttons_i(0) = '0' then 
                s_pressed_button <= s_pressed_button or X"0400";   
              elsif row_buttons_i (1) = '0' then 
                s_pressed_button <= s_pressed_button or X"0800";  
              elsif row_buttons_i (2) = '0' then 
                s_pressed_button <= s_pressed_button or X"1000";  
              elsif row_buttons_i (3) = '0' then 
                s_pressed_button <= s_pressed_button or X"2000";   
              elsif row_buttons_i <= "1111" then 
                s_pressed_button <= (others => '0');
              end if;
            when others =>
              s_pressed_button <= (others => '0');
          end case;
        end if;
    end if; 
  end process; 
  pressed_button_o <= s_pressed_button;
end architecture rtl;

Wie man in der Simulation sehen kann, ist pressed button_o bei 
10000000ns (10ms) noch immer auf null obwohl er laut den row_button_i 
und col_button_o auf X"0002" sein sollte. Bei 20ms ist er dann auf 
X"0002" wobei hier das Signal schon X"0006" sein sollte (es ist erst bei 
30 ms). Es hinkt eben um 10ms hinterher.

Ich hoffe ihr könnt mir da weiterhelfen.

Lg Johannes

[Theor (Gast)]

Naja. Leider reagieren reale Vorrichtungen nicht instantan, d.h. in 
Null-Zeit und in zusätzlich in einem Maß, dass von anderen Vorrichtungen 
als Veränderung erkannt wird.

D.h. im konkreten Fall, dass zwischen dem Ereignis der steigenden Flanke 
und der Änderung irgendeines, abhängigen Ausgangssignales Zeit vergeht. 
Dass muss man berücksichtigen.
Was einem da im Wege stehen kann, ist die unhinterfragte Annahme, alles 
müsse "sofort" geschehen. Das ist nicht der Fall.
Die Frage ist nur, ob und welche Verzögerungen akzeptabel sind.

[Johannes H. (Gast)]

Vielen Dank für die schnelle Antwort :)

Ok also ist es nicht möglich, weil ich denke, dass mein VHDL-Code falsch 
ist.

Lg

[Lothar M. (Firma: Titel) (lkmiller) (Moderator)]

Johannes H. schrieb:
> Vielen Dank für die schnelle Antwort :)
Die war zwar völlig korrekt, aber leider am Thema vorbei. Das Problem 
hier ist "vor" und "hinter" dem Flipflop...   ;-)

Johannes H. schrieb:
> Es hinkt eben um 10ms hinterher.
Glückwunsch, du hast Latency entdeckt.

Dein Problem liegt darin, dass du gleichzeitig nach je 10ms den 
nächsten Zustand der Marix setzt und (Achtung jetzt kommt es:) den 
bisherigen alten auswertest.

Ein Tipp: lass mal zum Ausprobieren diese 10ms Abfrage bei der 
Auswertung weg...

Johannes H. schrieb:
> ich denke, dass mein VHDL-Code falsch ist.
Der tut doch. Nur erwartest du das Falsche. Wie gesagt: jede 
Signalzuweisung in einem getakteten Prozess ergibt ein Flipflop. Und das 
übernimmt mit dem Takt die Information, die hör dem Takt am Eingang 
anlag. Einfach mal einen Abend drüber nachgrübeln.

[Johannes H. (Gast)]

Aha ok also das Problem ist dass ich s_column_button ein Wert zuweise 
aber im selben Zug abfrage?

Lothar M. schrieb:
> Ein Tipp: lass mal zum Ausprobieren diese 10ms Abfrage bei der
> Auswertung weg...

wenn ich die abfrage weglassen würde, müsste er dann (wenn ich es 
richtig verstanden habe) zumindest ein Taktzyklus hinterherhinken oder?

[Lothar M. (Firma: Titel) (lkmiller) (Moderator)]

Johannes H. schrieb:
> Aha ok also das Problem ist dass ich s_column_button ein Wert zuweise
> aber im selben Zug abfrage?
Richtig: du speicherst da mit der selben Taktflanke die Auswertung des 
alten Werts und setzt gleichzeitig den neuen Wert der dann zu einem 
neuen Auswertungsergebnis führt...

> zumindest ein Taktzyklus hinterherhinken oder?
Ja.
Sonst müsste das Ergebnis kombinatorisch weitergegeben werden, dann 
kommt das mit der Latency eben irgendwo später.

Aber bei einer Tastenabfrage kann das eigentlich kein Problem sein...