TIMER0 Normal Mode bei 2560

[Uwe H. (uhomm)]

Hallo liebe Leute,

ich hätte da mal eine Frage an die ATmega Cracks... :)

Ich programmiere gerade mit einem Arduino mit dem ATmega2560 per Atmel 
Studio in Assembler, um mich da ein wenig einzuarbeiten.

Konkret geht es um die Timer.

Ich habe (nachfolgend) ein Programm, das den TIMER0 nutzt. Per ISR wird 
ein Ausgangspin (Digital Pin 11) getoggelt UND per CompareMatch-Einheit 
soll der zugehörige Ausgang OC0A (Digital Pin 13) im Toggle Modus 
betrieben werden.

Der ISR-Teil läuft auch, aber am Digital Pin 13 (OC0A) erscheint NICHT 
das Rechtecksignal...

Sieht jemand einen Grund dafür?

Eine weitere Frage hätte ich noch...bei der Initialisierung von TIMSK0 
funktioniert der Befehl "out" nicht...ich muss hier statt dessen "sts" 
verwenden...das ist mir völlig unklar...

Nachtrag: Ich verwende das Atmel Studio in der Version 7.0.1931 mit den 
installierten Packages in der Version 7.0.122
Der Assembler meldet mir bei Verwendung von out bei dem Beschreiben von 
TIMSK0 den Fehler "Operand 1 out of range: 0x6e"


LG Uwe

;==============================================================================
; Normal-Mode.asm
; Verwendet Digital Pin 13 für OC0A und Digital Pin 11 per Overflow Interrupt
;
; Using the Output Compare to generate waveforms in Normal mode is not
; recommended, since this will occupy too much of the CPU time.
; (Datasheet Seite 120)
;
; Created: 12.07.2018 18:40:14
; Author : Uwe
;==============================================================================

.ORG 0x0000            ; Nachfolgenden Programmcode
                ; ab der Speicherstelle
                ; 0x0000 ablegen

;==============================================================================
; Interrupt-Handler
;==============================================================================
  jmp    INIT        ; Interruptvektoren überspringen
                ; und zum Hauptprogramm
.org OVF0addr
  jmp    TIM0_OVR_ISR

;==============================================================================
; Initialisierung nach Neustart
;==============================================================================
INIT:
  cli              ; Alle Interrupts sperren

  ldi    r16, HIGH(RAMEND)   ; Stackpointer initialisieren
  out    SPH, r16
  ldi    r16, LOW(RAMEND)
  out    SPL, r16

  sbi    DDRB, PORTB5        ; Pin 5 ist Ausgang
  sbi    DDRB, PORTB7        ; Pin 7 ist Ausgang
  
  call  INIT_TMR0      ; Unterprogramm zur Initialisierung
                ; von TIMER0 aufrufen

  sei              ; Alle Interupts freigeben
  
  jmp    MAIN_LOOP      ; Sprung zur Endlosschleife

;==============================================================================
; Initialisierung von TIMER0, bedient per ISR PORTB5 (Digitalpin 11)
; Modus: Normal (WGM02:0 = 0)
; Prescaler: 1024 (CS02:0 = 5)
; Compare Output Mode: Toggle (COM0A1:0 = 1) --> OC0A (Digitalpin 13)
; Timer0 Overflow Interrupt nutzen
;==============================================================================
INIT_TMR0:
  ldi    r16, 100      ; Zählregister vorladen --> höhere Frequenz
  out    TCNT0, r16      ; ansonsten Zählregister = 0

  ldi    r16, 0
  out    TCCR0A, r16      ; Beide Steuerregister = 0
  out    TCCR0B, r16

  ldi    r16, (1<<COM0A0)      ; Modus einstellen
  out    TCCR0A, r16

  ldi    r16, (1<<CS02)|(1<<CS00)  ; Prescaler einstellen
  out    TCCR0B, r16

  ldi    r16, (1<<TOV0)    ; eventuellen TOV0 Interrupt löschen
  out    TIFR0, r16

  ldi    r16, (1<<TOIE0)    ; TOV0 Interrupt aktivieren
  sts    TIMSK0, r16
  
  ret              ; Rücksprung

;==============================================================================
; Interrupt-Service-Routine
; TIMER0: OVERFLOW
; bedient PORTB5 (Digitalpin 11)
;==============================================================================
TIM0_OVR_ISR:
  push  r16          ; verwendete Register sichern
  push  r17

  in    r16, SREG
  push  r16          ; Statusregister sichern

  ldi    r16, 100
  out    TCNT0, r16      ; Zählregister vorladen --> höhere Frequenz

  in    r16, PORTB      ; PORTB einlesen
  ldi    r17, (1<<PORTB5)  ; PORTB Bit5 setzen
  eor    r16, r17      ; PortB Bit5 toggeln
  out    PORTB, r16      ; auf PORTB ausgeben

  pop    r16
  out    SREG, r16      ; Statusregister zurückladen

  pop    r17          ; verwendete Register zurückladen
  pop    r16

  reti

;==============================================================================
; Programm-Endlosschleife
;==============================================================================
MAIN_LOOP:
  nop
  jmp  MAIN_LOOP      ; the reset vector: jump to "main"

[Einer K. (Gast)]

Uwe H. schrieb:
> Der Assembler meldet mir bei Verwendung von out bei dem Beschreiben von
> TIMSK0 den Fehler "Operand 1 out of range: 0x6e"
Glaube der Meldung!
Glaube der Meldung!

(verwende stattdessen STS)

[Thomas F. (igel)]

Uwe H. schrieb:
> bei der Initialisierung von TIMSK0
> funktioniert der Befehl "out" nicht...ich muss hier statt dessen "sts"
> verwenden...das ist mir völlig unklar...

in und out können nur die Adressen 0-63 ansprechen. Darüber muss man 
ld(s) und st(s) verwenden. Steht aber so im Datenblatt Kapitel "AVR 
Memories". siehe dazu auch die "Register Summary".

[spess53 (Gast)]

Hi

>Der ISR-Teil läuft auch, aber am Digital Pin 13 (OC0A) erscheint NICHT
>das Rechtecksignal...

Setze mal das OCR0A-Register auf einen Wert zwischen 100 und 255.

>Eine weitere Frage hätte ich noch...bei der Initialisierung von TIMSK0
>funktioniert der Befehl "out" nicht...ich muss hier statt dessen "sts"
>verwenden...das ist mir völlig unklar...

in/out können nur die Register im IO-Breich ($00..$3F) adressieren. Das 
sind die Register die im Datenblatt in 'Register Summary' mit zwei 
Adressen gekennzeichnet sind. TIMSK0 (Adresse $6E) liegt aber im 
erweiterten IO-Bereich der nur mit sts ansprechbar ist.

MfG Spess

[Thomas F. (igel)]

Uwe H. schrieb:
> aber am Digital Pin 13 (OC0A) erscheint NICHT
> das Rechtecksignal... Sieht jemand einen Grund dafür?

TCCR0A ist falsch intitialisiert.
OCR0A nicht auf Wert gesetzt.

(Hab grad nur das Datenblatt zum At90CAN da, daher mal selber nachsehen)

[Uwe H. (uhomm)]

Herzlichen Dank für die fachkundige Antwort hinsichtlich IN/OUT bzw. 
LDS/STS!

Habe es gerade nachgeschlagen...Unterschied ist, das IN/OUT nur einen 
Maschinenzyklus benötigen, LDS/STS jedoch zwei Maschinenzyklen.

Hinsichtlich des fehlenden Signals an OC0A haben Eure Hinweise leider 
nicht geholfen. Ich habe die Timer0 Initialisierung nun wie folgt 
geändert. Es erscheint trotzdem kein Signal.

Any further hints?

;==============================================================================
; Initialisierung von TIMER0, bedient per ISR PORTB5 (Digitalpin 11)
; Modus: Normal (WGM02:0 = 0)
; Prescaler: 1024 (CS02:0 = 5)
; Compare Output Mode: Toggle (COM0A1:0 = 1) --> OC0A (Digitalpin 13)
; Timer0 Overflow Interrupt nutzen
;==============================================================================
INIT_TMR0:
  ldi    r16, 100      ; Zählregister vorladen --> höhere Frequenz
  out    TCNT0, r16      ; ansonsten Zählregister = 0

  ldi    r16, 0
  out    TCCR0A, r16      ; Beide Steuerregister = 0
  out    TCCR0B, r16

  ldi    r16, (1<<COM0A0)      ; Compare Output einstellen
  out    TCCR0A, r16

  ldi    r16, (1<<CS02)|(1<<CS00)  ; Prescaler einstellen
  out    TCCR0B, r16

  ldi    r16, 100      ; OCR0A auf 100 vorladen
  out    OCR0A, r16      ; 

  ldi    r16, (1<<TOV0)    ; eventuellen TOV0 Interrupt löschen
  out    TIFR0, r16

  ldi    r16, (1<<TOIE0)    ; TOV0 Interrupt aktivieren
  sts    TIMSK0, r16
  
  ret              ; Rücksprung

[Chaos (Gast)]

Uwe H. schrieb:
> soll der zugehörige Ausgang OC0A (Digital Pin 13)

Bist du sicher, dass der OC0A an Digital Pin 13 liegt? Ich meine mich 
dunkel zu erinnern, dass die OCs alle in den analog Bereich geroutet 
sind?! Zumindest schließe ich aus dem Digital Pin, dass du mit nem 
Arduino Mega2560 rummachst. Evtl einfach mal die anderen Pins nach ner 
Reaktion belauschen.

MfG Chaos

[Einer K. (Gast)]

Chaos schrieb:
> Bist du sicher, dass der OC0A an Digital Pin 13 liegt?
Ja.

Siehe:
https://arduino-info.wikispaces.com/file/view/Mega2-900.jpg/421499040/Mega2-900.jpg

[Karl M. (Gast)]

Hallo Uwe H.,

wir verwenden Diese Macros zum einfacheren Lesen und Setzen von IO 
Ports.

.macro xIn
.if @1<64
in    @0,@1
.else
lds    @0,@1
.endif
.endmacro

.macro xOut
.if @0<64
out    @0,@1
.else
sts    @0,@1
.endif
.endmacro

Dies ist auch noch erweiterbar auf Bit IO Zugriffe:

.macro gCbi
.if @0<32
cbi    @0,@1
.else
xIn    WL,@0
cbr    WL,(1<<@1)
xOut  @0,WL
.endif
.endmacro

.macro gSbi
.if @0<32
sbi    @0,@1
.else
xIn    WL,@0
sbr    WL,(1<<@1)
xOut  @0,WL
.endif
.endmacro

Für spezielle Zugriffe sind diese auch sinnvoll:

.macro gSbic
.if @0<32
sbic  @0,@1
.else
xIn  WL,@0
sbrc  WL,@1
.endif
.endmacro

.macro gSbis
.if @0<32
sbis  @0,@1
.else
xIn  WL,@0
sbrs  WL,@1
.endif
.endmacro

Wir nutzen darüber hinaus noch folgende Aliase der Registernamen.
Eine Expansion von W nach WH_WL bis Z nach ZH:ZL erfolgt automatisch.

;low block A
.def  _LA0    = R0
.def  _LA1    = R1
.def  _LA2    = R2
.def  _LA3    = R3
;low block B
.def  _LB0    = R4
.def  _LB1    = R5
.def  _LB2    = R6
.def  _LB3    = R7
;temp block A
.def  _TMP0    = R8
.def  _TMP1    = R9
.def  _TMP2    = R10
.def  _TMP3    = R11
;temp block B
.def  _TMPA    = R12
.def  _TMPB    = R13
.def  _TMPC    = R14
.def  _TMPD    = R15
;high block A
.def  _HA0    = R16
.def  _HA1    = R17
.def  _HA2    = R18
.def  _HA3    = R19
;high block B
.def  _HB0    = R20
.def  _HB1    = R21
.def  _HB2    = R22
.def  _HB3    = R23
;pointers
.def  WL    = R24
.def  WH    = R25
.def  XL    = R26
.def  XH    = R27
.def  YL    = R28
.def  YH    = R29
.def  ZL    = R30
.def  ZH    = R31

[Uwe H. (uhomm)]

Liebe Helfer,

danke für die Hinweise mit dem Makros ;) auch wenn das nichts mit der 
Frage nach dem fehlenden Signal zu tun hat, aber wohl mit dem IN/OUT 
bzw. LDS/STS wie ich vermute...

Mittlerweile habe ich mir für alle sechs Modi (CTC, Fast PWM etc.) 
Testprogramme geschrieben und die arbeiten auch alle wie erwartet.

Nur im Normal-Mode bekomme ich am Pin OC0A (Ja, beim Arduino mit dem 
2560 ist das der DigitalPin 13) einfach kein Signal erzeugt.

Im Datenblatt des ATmega 2560 findet sich auf Seite 120 folgender 
Hinweis:
"Using the Output Compare to generate waveforms in Normal mode is not 
recommended, since this will occupy too much of the CPU time."

Ob im Rahmen eines Re-Designs vom 2560 diese Betriebsart einfach deshalb 
entfernt wurde und deshalb nichts am Pin liefert?

Reine Spekulation!

LG Uwe Homm

Kurzer Nachtrag: Ich kontrolliere die Signale mit einem Oszilloskop.

[S. Landolt (Gast)]

> alle sechs Modi ... die arbeiten auch alle wie erwartet.

Da zögere ich jetzt mit meiner Vermutung, trotzdem: OC0A liegt beim 
ATmega2560 auf B7, wurde dieser Pin als Ausgang definiert? In INIT_TMR0 
sehe ich davon nichts, dort hätte ich es erwartet.

[Uwe Homm (Gast)]

Danke, dass Du Dich nochmal mit meinem Problem beschäftigst!

Ja, POPRTB7 ist als Ausgang definiert...siehe mein erstes Posting. Ich 
habe das ganz am Anfang in dem Bereich "Initialisierung nach Neustart" 
gemacht.

LG
Uwe Homm

[S. Landolt (Gast)]

Tja, ich habe keinen ATmega2560 (geschweige denn einen Arduino), aber 
auf dem verwandten ATmega1284 läuft es, und in dessen Datenblatt steht 
derselbe zitierte Hinweis; der sich übrigens wohl nur auf die 
Interruptverwendung bezieht, denn davor steht: "The Output Compare Unit 
can be used to generate interrupts at some given time."

[S. Landolt (Gast)]

Vorschlag: es hat sich doch einiges geändert, stellen Sie einfach das 
komplette Programm im derzeitigen Zustand vor.

[Uwe H. (uhomm)]

Das Testprogramm hat sich NUR dahingehend geändert, dass ich auf den 
Vorschlag von Thomas F. (igel) (13.07. um 11:31) und dessen Vorgänger 
das Register OCR0A bei der Timerinitialisierung mit einem Wert vorbelegt 
habe (siehe meinen Post vom 13.07. um 12:48 Uhr). Inwiefern ich TCCR0A 
falsch eingestellt hätte, ist mir unklar.

DAS war die einzige Änderung gegenüber meinem ersten Posting.

LG
Uwe Homm

;==============================================================================
; TIMER0-Normal-Mode0
; Verwendet Digital Pin 13 für OC0A und Digital Pin 11 per Overflow Interrupt
; DigitalPin 11: T ~ 19ms, Tastgrad = 0,5
; DigitalPin 13: kein Signal
;
; Using the Output Compare to generate waveforms in Normal mode is not
; recommended, since this will occupy too much of the CPU time.
; (Datasheet Seite 120)
;
; Created: 12.07.2018 18:40:14
; Author : Uwe
;==============================================================================

.ORG 0x0000            ; Nachfolgenden Programmcode
                ; ab der Speicherstelle
                ; 0x0000 ablegen

;==============================================================================
; Interrupt-Handler
;==============================================================================
  jmp    INIT        ; Interruptvektoren überspringen
                ; und zum Hauptprogramm
.org OVF0addr
  jmp    TIM0_OVR_ISR

;==============================================================================
; Initialisierung nach Neustart
;==============================================================================
INIT:
  cli              ; Alle Interrupts sperren

  ldi    r16, HIGH(RAMEND)   ; Stackpointer initialisieren
  out    SPH, r16
  ldi    r16, LOW(RAMEND)
  out    SPL, r16

  sbi    DDRB, PORTB5    ; Pin 5 ist Ausgang
  sbi    DDRB, PORTB7    ; Pin 7 ist Ausgang
  
  call  INIT_TMR0      ; Unterprogramm zur Initialisierung
                ; von TIMER0 aufrufen

  sei              ; Alle Interupts freigeben
  
  jmp    MAIN_LOOP      ; Sprung zur Endlosschleife

;==============================================================================
; Initialisierung von TIMER0, bedient per ISR PORTB5 (Digitalpin 11)
; Modus: Normal (WGM02:0 = 0)
; Prescaler: 1024 (CS02:0 = 5)
; Compare Output Mode: Toggle (COM0A1:0 = 1) --> OC0A (Digitalpin 13)
; Timer0 Overflow Interrupt nutzen
;==============================================================================
INIT_TMR0:
  ldi    r16, 100      ; Zählregister vorladen --> höhere Frequenz
  out    TCNT0, r16      ; ansonsten Zählregister = 0

  ldi    r16, 0
  out    TCCR0A, r16      ; Beide Steuerregister = 0
  out    TCCR0B, r16

  ldi    r16, (1<<COM0A0)    ; Compare Output einstellen
  out    TCCR0A, r16

  ldi    r16, (1<<CS02)|(1<<CS00); Prescaler einstellen
  out    TCCR0B, r16

  ldi    r16, 100      ; OCR0A auf 100 vorladen
  out    OCR0A, r16      ; 

  ldi    r16, (1<<TOV0)    ; eventuellen TOV0 Interrupt löschen
  out    TIFR0, r16

  ldi    r16, (1<<TOIE0)    ; TOV0 Interrupt aktivieren
  sts    TIMSK0, r16
  
  ret              ; Rücksprung

;==============================================================================
; Interrupt-Service-Routine
; TIMER0: OVERFLOW
; bedient PORTB5 (Digitalpin 11)
;==============================================================================
TIM0_OVR_ISR:
  push  r16          ; verwendete Register sichern
  push  r17

  in    r16, SREG
  push  r16          ; Statusregister sichern

  ldi    r16, 100
  out    TCNT0, r16      ; Zählregister vorladen --> höhere Frequenz

  in    r16, PORTB      ; PORTB einlesen
  ldi    r17, (1<<PORTB5)  ; PORTB Bit5 setzen
  eor    r16, r17      ; PortB Bit5 toggeln
  out    PORTB, r16      ; auf PORTB ausgeben

  pop    r16
  out    SREG, r16      ; Statusregister zurückladen

  pop    r17          ; verwendete Register zurückladen
  pop    r16

  reti

;==============================================================================
; Programm-Endlosschleife
;==============================================================================
MAIN_LOOP:
  nop
  jmp  MAIN_LOOP      ; the reset vector: jump to "main"

[Einer K. (Gast)]

Uwe Homm schrieb:
> habe das ganz am Anfang in dem Bereich "Initialisierung nach Neustart"
> gemacht.

Habe das mal in der Arduino IDE getestet.....
PB7 und PB5 flackern friedlich vor sich hin

int main() 
{
  DDRB  |= _BV(PB5)|_BV(PB7);
  TCNT0  = 100;
  OCR0A  = 101; // setze OCR0A < 101, und die LED bleibt aus)
  TCCR0A = (1<<COM0A0);
  TCCR0B = (1<<CS02)|(1<<CS00);
  TIFR0  = (1<<TOV0);
  TIMSK0 = (1<<TOIE0);
  sei();
  for(;;);
}

ISR(TIMER0_OVF_vect) 
{
   TCNT0 = 100;
   PINB  = (1<<PB5);
}

Dein Fehler ist offensichtlich!
Du setzt bei jeder Gelegenheit TCNT0 = 100.
Aber  OCR0A steht auf Auslieferungszustand == 0
Selbst 100 reicht nicht.
Der Schwellwert wird nie durchlaufen.
Damit bleibt PB7 dauerhaft aus.

OCR0A MUSS größer 100 eingestellt werden.

[Uwe H. (uhomm)]

Danke...Du bist mein Held :)

DAS habe ich total aus den Augen verloren.
Nun geht das Testprogramm auch; gleiches Signal wie am Pin 11 durch den 
OVERFLOW Interrupt.

LG
Uwe Homm

[S. Landolt (Gast)]

Und da es zuletzt nur um OC0A ging (und ursprünglich um Assembler), hier 
in Ergänzung zu ufufs äußerst prompt bereitgestellten Programm:

/*
SLdt 180714

toggle OC0A == B7   (B3 auf ATmega1284)
*/

;.include "m1284Pdef.inc"
.include "m2560def.inc"

.def    tmp0                = r16

.org 0
    rjmp    main

main:
;   sbi     DDRB,3
    sbi     DDRB,7
    ldi     tmp0,(1<<COM0A0)
    out     TCCR0A,tmp0
    ldi     tmp0,(1<<CS02)+(1<<CS00)
    out     TCCR0B,tmp0
main_loop:
  rjmp      main_loop

Ohne diesen OVF-Interrupt wird es recht kompakt.

[Einer K. (Gast)]

S. Landolt schrieb:
> (und ursprünglich um Assembler)
Ja, ich machs mir lieber mit einem Compiler...(wenn es irgendwie geht)
Für ASM habe ich noch nicht mal eine eingerichtete Testumgebung.
(ok, *.S Dateien in Arduino Libs bekomme ich gerade noch hin)

[S. Landolt (Gast)]

Ihre Hilfe war perfekt und kam an!
(Meine mag vielleicht beitragen, den Stil zu verbessern)

[Einer K. (Gast)]

S. Landolt schrieb:
> Ihre Hilfe
? ?
Deine!
Ansonsten, danke für die Blumen.


Irgendwie bin ich überrascht, dass meins geholfen hat.
Denn, dass, und auch mit welchem Wert OCR0A vorbesetzt werden muss, 
wurde ja schon im Thread genannt.

Als da keine (positive) Reaktion drauf erfolgte, musste es getestet 
werden.

[S. Landolt (Gast)]

Dass ich geduzt werde, daran habe ich mich gewöhnt (werd's ja sogar auf 
Wahlplakaten von Laternenpfählen herunter). Selbst jedoch mir sonst 
völlig unbekannte Menschen zu duzen, daran werde ich wohl nie gewöhnen. 
Lassen wir es dabei bewenden, und nichts für ungut.