AVR External Interrupt Hilfe

[Crafter C. (crafter_c)]

Ich will mit Assember afangen und habe ein simples Interruptprogram 
geschrieben, aber mein Problem ist, dass der Interrupt nicht ausgelöst 
wird. Ich habe PB5 als Output und PD2 als input mit PULLUP eingestellt. 
Der Interrupt INT0 ist eingeschaltet und sollte bei einem Pinchange 
getriggert werden, aber nichts funktioniert, wenn ich den PD2 auf GND 
stecke.

ATMega328P

.include "m328pdef.inc"

begin:

rjmp  init      ;RESET 
rjmp  LED_ON      ;INT0      
reti          ;INT1
reti          ;PCINT0
reti          ;PCINT1
reti          ;PCINT2
reti          ;WDT
reti          ;TIMER2_COMPA
reti          ;TIMER2_COMPB
reti          ;TIMER2_OVF
reti          ;TIMER1_CAPT
reti          ;TIMER1_COMPA
reti          ;TIMER1_COMPB
reti          ;TIMER1_OVF
reti          ;TIMER0_COMPA
reti          ;TIMER0_COMPB
reti          ;TIMER0_OVF
reti          ;SPI STC
reti          ;USART_RX
reti          ;USART_UDRE
reti          ;USART_TX
reti          ;ADC
reti          ;EE READY
reti          ;ANALOG COMP

init:
  ldi r16, high(RAMEND)  ;setup stack
  out SPH, r16      ;
  ldi r16,low(RAMEND)    ;
  out SPL, r16      ;

  ldi r16, 0b00100000    ;set PB5 as OUTPUT
  out DDRB, r16      ;load to DDRB

  ldi r16, 0b00000100    ;set PD2 as PULLUP
  out PortD, r16      ;load to PortD

  ldi r16, 0b00000001    ;enable INT0 interrupt
  out EIMSK,r16

  ldi r16, 0b00000001    ;set when the Interrupt inerrupt 
  sts EICRA,r16

  sei            ;enable interrupts
loop:
  rjmp loop

LED_ON:
  cli            ;disable Interrupt
  sbi PORTB,5        ;set bit 5 
  sei            ;enable interrupts
  reti          ;return to Interrupt

[Karl M. (Gast)]

Hallo,

arbeite doch mit .org 0x0
für den Start der "Interrupt-Sprung-Tabelle" und mit einem weiteren .org 
0x???? mit dem korrekten Start des Programms.

Dann dies hier, was soll das?

LED_ON:
  cli            ;disable Interrupt
  sbi PORTB,5        ;set bit 5 
  sei            ;enable interrupts
  reti          ;return to Interrupt

Weisst Du wie ein Interrupt Request bei einem Atmel µC finktioniert?
Es ist nicht notwendig und unnötig das "Global Interrupt Enable" Bit zu 
verändern.
Register musst Du hier noch nicht sichern.

Ich verwende in Macro xIn und xOut, dass automatisch die Konvertierung 
zu IN/ LDS und OUT/ STS durchführt.

Dann ist es problematisch bei großen Programmen so vorzugehen, da man 
nie den aktuellen Zustand eines Registers mit einbezieht:

ldi r16, 0b00100000    ;set PB5 as OUTPUT
out DDRB, r16      ;load to DDRB

Also read modify write, kann man natürlich auch über ein weiteres Macros 
lösen.

xIn r16,DDRB
ori r16,(1<<PB5)
xOut DDRB,r16

Gleiches für diese Zeile:

ldi r16, 0b00000100;set PD2 as PULLUP
out PortD, r16 ;load to PortD

Neu:

xIn r16,DDRD
andi r16,~(1<<PD2) ; clear bit, set to input
xOut DDRD,r16

xIn r16,PortD
ori r16,(1<<PD2) ; set bit, set pullup on
xOut PortD,r16[/c]

;INT0: ISC0[1:0] = 10 - falling edge!
xIn r16, EICRA
andi r16,~((1<<ISC01)|(1<<ISC00)) ; clear bits
ori r16,((1<<ISC01)|(0<<ISC00)) ; set bits, for the programmer
xOut EICRA,r16

; Nicht vergessen sollte man auch das INTF0 Flag zu löschen
ldi r16,(1<<INTF0)
xOut EIFR,r16 ; ja das macht man so!

; enable INT0 interrupt request
xIn r16, EIMSK
ori r16,(1<<INT0)
xOut EIMSK,r16

[Dirk B. (Gast)]

rjmp  init      ;RESET
rjmp  LED_ON      ;INT0
geht schief, da der ATMega328P long jmp als Interruptvektoren hat
rjmp  init nop     ;RESET
rjmp  LED_ON nop     ;INT0
oder
jmp  init      ;RESET
jmp  LED_ON      ;INT0
reti nop
...
'erwischt'  int0 besser.
oder
.org 0
rjmp  init      ;RESET .org 1 unprogrammed
.org 2
rjmp  LED_ON      ;INT0

[Peter D. (peda)]

Dirk B. schrieb:
> .org 0
> rjmp  init      ;RESET .org 1 unprogrammed
> .org 2
> rjmp  LED_ON      ;INT0

Man sollte es besser gleich richtig machen:

        .org    INT0addr
        rjmp    LED_ON

[Crafter C. (crafter_c)]

Danke für die Antworten, das Programm läuft jetzt. Ich habe aber noch 
einige Fragen zu den Befehlen

andi r16,~((1<<ISC01)|(1<<ISC00)) ; clear bits

Was bedeutet dieses "~"?

.org 0
rjmp  init      ;RESET
.org 2
rjmp  LED_ON      ;INT0      
reti          ;INT1
reti          ;PCINT0
reti          ;PCINT1
reti          ;PCINT2
reti          ;WDT
.
.
.

Was hat es mit dem ".org" auf sich?

[Karl M. (Gast)]

Hallo,

da hilft Dir dann die Dokumentation zum AVR Assembler weiter.

Damit kannst Du dir selbst, auch zusätzlich mit dem Datenblatt des AVR 
µC, einige Frage beantworten:

https://www.microchip.com/webdoc/avrassembler/avrassembler.wb_expressions.html

[Karl M. (Gast)]

Jetzt kannst Du durchstarten!

Es ist über die Suchfunktion sehr einfach auch die ORG Anweisung zu 
finden:

https://www.microchip.com/webdoc/avrassembler/avrassembler.wb_directives.html

[Marc V. (Firma: Vescomp) (logarithmus)]

Crafter C. schrieb:
> Was hat es mit dem ".org" auf sich?

 Damit wird die Adresse im flash festgelegt.

 Übrigens funktioniert dein Programm nur weil du .org 2
 stehen hast.

 Alle AVRs über 8KB Flash sehen jmp vor (2 Words), alle AVRs mit
 weniger als 8KB benutzen rjmp (1 Word).

 Deswegen sollte beim ATMEGA328P jmp und nicht rjmp in der
 INT-Vector Table stehen oder ein .org mit richtiger Adresse vor
 dem entsprechenden INT-Vector.

[Dirk B. (Gast)]

.org definiert die Programmspeicheradresse an die der nächste Befehl 
geschrieben wird. In deinem Fall stehen die Interupvektoren
reset: addr 0
int0: addr 2
... bei einem avr mit weniger Speicher der nur rjmp benötigt
reset:addr 0
int0: addr 1
mit dem tw. üblichen
rjmp reset
rjmp int0
....
stehen die Befehle gemäß der Länge der vorigen Befehle im 
Programmspeicher. rjmp: 1 Word jmp:2 Word. Die Festlegung mit .org 
[addr]ist also praktisch eine Versicherung, dass der Befehl richtig zum 
Aufruf steht, der µC springt beim Imterupt int0 immer zur Adresse 2 
(etwas schwer in Worten zu beschreiben)

.org 0
(r)jmp init ;  mit der Sicherheit fester Adressen ist jmp/rjmp egal
.org INT0addr ;INT0addr bzw. XXXXaddr sind Bezeichner für die passenden 
Adresse.
(r)jmp init0
wäre noch besser/verständlicher, aber ich war mir über die Schreibweise 
nicht ganz sicher.

"~" ist invertiert  d.h. ~00000001 ---> 11111110
wenn du bit0 (byte: 0000.0001) löschen möchtest, dann gibt aktuelles 
byte (xxxx.xxxx) UND nicht (0000.0001) --> xxxx.xxx0; bit0 cleared