ATtiny414 führt Programm nicht aus?

[Daniel K. (daniel_k80)]

Hallo zusammen,

ich habe einen ATtiny414, welchen ich über UPDI programmiert habe. Das 
Programm funktioniert auch, wenn ich über einen Debugger das Programm 
starte (es wird ein I/O auf High gezogen und nach 10 Sekunden fällt er 
auf Low zurück).
Wenn ich den Debugger nun abstecke und Spannung auf den Tiny gebe wird 
das Programm aber nicht ausgeführt. Der Pin bleibt die ganze Zeit auf 
Low.

Wie kommt das? Was macht der Debugger anders?

Vielen Dank für die Hilfe!

.def  temp1    = r16                   
.def  temp2    = r17                    
.def  temp3    = r18                    
.def  temp4    = r19                    
.def  temp5    = r20                    
.def  temp6    = r21
.def  Timeout_M  = r22                    ; Timeout für die RTC (Minuten)
.def  Timeout_S  = r23                    ; Timeout für die RTC (Sekunden)

.cseg                  
.org $0000                            ; RESET
  rjmp    Reset_Handler                      
.org CRCSCAN_NMI_vect                      ; CRCSCAN_NMI    
  reti
.org BOD_VLM_vect                        ; BOD_VLM
  reti
.org PORTA_PORT_vect                      ; PORTA_PORT
  reti
.org PORTB_PORT_vect                      ; PORTB_PORT
  reti
.org RTC_CNT_vect                        ; RTC_CNT
  rjmp    RTC_InterruptHandler
.org RTC_PIT_vect                        ; RTC_PIT
  reti
.org TCA0_OVF_vect                        ; TCA0_OVF
  reti
.org TCA0_HUNF_vect                        ; TCA0_HUNF
  reti
.org TCA0_CMP0_vect                        ; TCA0_CMP0
  reti
.org TCA0_CMP1_vect                        ; TCA0_CMP1
  reti
.org TCA0_CMP2_vect                        ; TCA0_LCMP2
  reti
.org TCB0_INT_vect                        ; TCB0_INT
  reti
.org TCD0_OVF_vect                        ; TCD0_OVF
  reti
.org TCD0_TRIG_vect                        ; TCD0_TRIG
  reti
.org AC0_AC_vect                        ; AC0_AC
  reti
.org ADC0_RESRDY_vect                      ; ADC0_RESRDY
  reti
.org ADC0_WCOMP_vect                      ; ADC0_WCOMP
  reti
.org TWI0_TWIS_vect                        ; TWI0_TWIS
  reti
.org TWI0_TWIM_vect                        ; TWI0_TWIM
  reti
.org SPI0_INT_vect                        ; SPI0_INT
  reti
.org USART0_RXC_vect                      ; USART0_RXC
  reti
.org USART0_DRE_vect                      ; USART0_DRE
  reti
.org USART0_TXC_vect                      ; USART0_TXC
  reti
.org NVMCTRL_EE_vect                      ; NVMCTRL_EE
  reti

Reset_Handler:
  ldi    temp1, low(RAMEND)
  out    CPU_SPL, temp1
  ldi    temp1, high(RAMEND)
  out    CPU_SPH, temp1

Main:
  ; B.0 als Ausgang und auf Low setzen
  ldi temp1, 0x01
  sts PORTB_DIR, temp1
  ldi temp1, 0x00
  sts PORTB_OUT, temp1

  rcall RTC_Init

  ; Globale Interrupts aktivieren
  lds temp1, CPU_SREG
  ldi temp2, (0x01 << 0x07)
  or temp1, temp2
  sts CPU_SREG, temp1

  LOOP:
    rjmp LOOP

; --------------------------------------------------------------------------------------------------------------
; RTC Initialisierung
;  - Verwende den internen 32 kHz ULP Oszillator mit einem Prescaler von 32
;  - Prescaler 1024
;  - Overflow Register laden
;  - Overflow Interrupt aktivieren
;  - RTC aktivieren
; --------------------------------------------------------------------------------------------------------------
RTC_Init:
  ; Prescaler setzen
  ldi temp1, (RTC_PRESCALER1_bm | RTC_PRESCALER3_bm)
  sts RTC_CTRLA, temp1
  rcall RTC_WaitBusy

  ; Interne 1 kHz Taktquelle einstellen 
  ldi  temp1, RTC_CLKSEL_INT1K_gc
  sts RTC_CLKSEL, temp1

  ; Interruptflags löschen
  ldi temp1, 0x00
  sts RTC_INTFLAGS, temp1

  ; Overflow interrupt aktivieren
  ldi temp1, RTC_OVF_bm
  sts RTC_INTCTRL, temp1

  ; Aktiviere die RTC
  ldi Timeout_M, 0
  ldi Timeout_S, 10
  rcall RTC_SetAlarm
  rcall RTC_Enable

  ; Setze B.0 auf High
  ldi temp1, 0x01
  sts PORTB_OUTTGL, temp1

  ret

; --------------------------------------------------------------------------------------------------------------
; RTC aktivieren
; --------------------------------------------------------------------------------------------------------------
RTC_Enable:
  lds temp1, RTC_CTRLA
  ldi temp2, RTC_RTCEN_bm
  or temp1, temp2
  sts RTC_CTRLA, temp1

  ; Auf Sync warten
  rcall RTC_WaitBusy
  ret

; --------------------------------------------------------------------------------------------------------------
; Auf RTC Sync warten
; --------------------------------------------------------------------------------------------------------------
RTC_WaitBusy:
  BusyLoop:
  lds temp1, RTC_STATUS
  cpi temp1, 0
  brne BusyLoop
  ret

; --------------------------------------------------------------------------------------------------------------
; RTC Alarm aktivieren
;  - Verwendet R22 für den Timeout in Minuten
;  - Verwendet R23 für den Timeout in Sekunden
; --------------------------------------------------------------------------------------------------------------
RTC_SetAlarm:
  ; Berechnen der Sekunden für den Timeout
  ldi temp1, 60
  mul Timeout_M, temp1
  movw r24, r0
  add r24, Timeout_S
  ldi temp1, 0
  adc r25, temp1
  subi r24, 1

  ; Kopiere das unterste Byte des Overflow-Wertes in das TEMP-Register und 
  ; starte den Schreibvorgang durch das Schreiben des obersten Bytes 
  ; des Overflow-Wertes
  sts RTC_TEMP, r24
  sts RTC_PERH, r25
  rcall RTC_WaitBusy
  ret

; --------------------------------------------------------------------------------------------------------------
; RTC Interrupt handler
; - Verwendet r16 für die Interruptbehandlung
; --------------------------------------------------------------------------------------------------------------
RTC_InterruptHandler:
  ; Setze B.0 auf Low
  ldi temp1, 0x01
  sts PORTB_OUTCLR, temp1

  ; Interruptflags kopieren
  lds temp1, RTC_INTFLAGS
  andi temp1, RTC_CMP_bm
  
  ; Interruptflags löschen
  ldi temp2, 0x03
  sts RTC_INTFLAGS, temp2

  ;cpi temp1, 0x01
  ;breq Overflow
  ;rjmp Overflow_End
  ;Overflow:
  ;  ; Lösche das Overflow-Flag
  ;  lds temp1, RTC_INTFLAGS
  ;  ldi temp2, 0x03
  ;  and temp1, temp2
  ;  sts RTC_INTFLAGS, temp1

  ;  ldi r16, 7
  ;Overflow_End:
  reti

[Karl M. (Gast)]

Hallo,

da bleibt nur die Reset Beschaltung des Attiny übrig.
Lege doch bitte man diesen Pin über einen Widerstand 1k-10k Ohm auf Vcc.

[Karl M. (Gast)]

Hallo,

ich habe da noch einen kleinen Tipp:
In RTC_Enable, kann man auch direkt

RTC_Enable:
lds temp1, RTC_CTRLA
ori temp1,RTC_RTCEN_bm
; gleichwertig, pseudonym:
;SBR temp1,RTC_RTCEN_bm
sts RTC_CTRLA, temp1
:

schreiben.

Daniel K. schrieb:
> RTC_Enable:
>   lds temp1, RTC_CTRLA
>   ldi temp2, RTC_RTCEN_bm
>   or temp1, temp2
>   sts RTC_CTRLA, temp1
>
>   ; Auf Sync warten
>   rcall RTC_WaitBusy
>   ret

[Karl M. (Gast)]

Auch hierfür gibt es einen Einfachen Befehl:

sei

siehe http://ww1.microchip.com/downloads/en/DeviceDoc/40001912A.pdf
8.7.3 Status Register

Und komplett:
37. Instruction Set Summary

Für alle 8 Bits im Status Register gibt es 1 Takt lange Befehle:
Carry:  SEC / CLC
Negative Flag: SEN / CLN
Zero Flag: SEZ / CLZ
Global Interrupt: SEI / CLI
Signed Test: SES / CLS
Two’s Complement Overflow: SEV / CLV
T in SREG: SET / CLT
Half Carry Flag: SEH / CLH

Daniel K. schrieb:
> ; Globale Interrupts aktivieren
>   lds temp1, CPU_SREG
>   ldi temp2, (0x01 << 0x07)
>   or temp1, temp2
>   sts CPU_SREG, temp1

[Daniel K. (daniel_k80)]

Hallo Karl,

danke für die Anmerkungen :)
Kenne das sei() Makro bisher nur aus C. Wusste nicht, dass es auch in 
Assembler verfügbar ist.

Der Pull-Up hat leider nichts gebracht. Der Tiny macht immer noch nichts 
:(

[Daniel K. (daniel_k80)]

Ok, der Fehler scheint wohl nicht am Mikrocontroller zu liegen, sondern 
vielmehr macht die RTC ohne Debugger nicht das was sie soll (nämlich 10 
Sekunden warten).
Statt 10 Sekunden sind es 10 ms. Da scheint noch was nicht richtig 
gesetzt zu werden...

Edit:
Problem gelöst. Ohne Debugger wurde der Prescaler nicht richtig gesetzt.
Ich habe das Problem nun gelöst, indem ich vor dem Setzen noch auf einen 
Sync warte, dann den Wert setze und dann noch einmal synchronisiere.
Nun funktioniert es.

RTC_Init:
  rcall RTC_WaitBusy
  ldi temp1, (RTC_PRESCALER1_bm | RTC_PRESCALER3_bm)
  sts RTC_CTRLA, temp1
  rcall RTC_WaitBusy

[Karl M. (Gast)]

Daniel K. schrieb:
> Hallo Karl,
>
> danke für die Anmerkungen :)
> Kenne das sei() Makro bisher nur aus C. Wusste nicht, dass es auch in
> Assembler verfügbar ist.

Ist aber im Assembler kein Macro.

Kennst Du schon die vielen Info(-seiten) zum Atmel AVR 
Assemblerbefehlssatz?

1) https://www.microchip.com/webdoc/avrassembler/index.html
2) http://ww1.microchip.com/downloads/en/devicedoc/40001917a.pdf

Mehr?

google: "https://www.microchip.com/ avr assembler"