MSP23S17 Adresspins Verhalten

[Maxim B. (max182)]

Hallo,

ich wollte Adresspins von MSP23S17 benutzen und Verhalten von Chip ist 
komisch: nur A2 wirkt, A1 und A0 scheinen egal zu sein. Ich habe zwei IC 
ausprobiert, alles gleich.
Sind die beide defekt oder weiß ich etwas nicht?

Bei Init setze ich HAEN in IOCON auf 1. Seitdem sollte IC Adresse auf 
A0-A2 unterscheiden. Aber: wenn ich A2 auf 0 halte, antwortet IC auf 
Adressen 0 bis 3, wenn A2 = 1, dann von 4 bis 7. Dabei völlig egal, ob 
A1 und A0 auf 0 sind oder auf 1.

Wo liegt Fehler? Hier ist gekürztes Testprogramm.

; spi.asm
.macro  SPI_INIT    
  sbi SPI_PORT,SPI_SS
  in @0, SPI_DDR
  ori @0, (1<<SPI_SS)|(1<<SPI_MOSI)|(1<<SPI_SCK)
  andi @0, ~(1<<SPI_MISO)
  out SPI_DDR, @0
  ldi @0, (1<<SPE)|(1<<MSTR)  
  out SPCR, @0
  ldi @0, (1<<SPI2X)  ; F_CPU/2
  out SPSR, @0
  out SPDR, @0
  sbis SPSR,SPIF
  rjmp PC-1
.endm

.macro  SPI_SEND
  out SPDR, @0
  sbis SPSR,SPIF
  rjmp PC-1
.endm

; mcp23s17.asm
mcp23s17_wr:  ; temp=Daten, temph=slave address, temp3=IC-Reg
  cbi MCP23S17_SS_PORT, MCP23S17_SS
  lsl temph
  ori temph, (1<<6)  ;0b0100xxx0
  SPI_SEND temph
  SPI_SEND temp3
  SPI_SEND temp
  sbi MCP23S17_SS_PORT, MCP23S17_SS
  ret

mcp23s17_rd:  ; temp= geles.Daten, temph=slave address, temp3=IC-Reg
  cbi MCP23S17_SS_PORT, MCP23S17_SS
  lsl temph
  ori temph, (1<<MCP23S17_RW)|(1<<6)  ;0b0100xxx1
  SPI_SEND temph
  SPI_SEND temp3
  SPI_SEND temp
  sbi MCP23S17_SS_PORT, MCP23S17_SS
  in temp,SPDR
  ret

mcp23s17_init:
  ldi temp, (1<<MCP23S17_IOCON_HAEN)
  ldi temph, 0
  ldi temp3, MCP23S17_IOCON
  rjmp mcp23s17_wr

; ledreihe.asm
.equ  LEDREIHE_ADR  = 7
.equ  LED1  = 0
.equ  LED2  = 7

led1_ein:
    ldi temp, ~(1<<LED1)
    ldi temph, LEDREIHE_ADR
    ldi temp3, MCP23S17_GPIOB
    rjmp mcp23s17_wr

led1_aus:
    ldi temp, (1<<LED1)
    ldi temph, LEDREIHE_ADR
    ldi temp3, MCP23S17_GPIOB
    rjmp mcp23s17_wr

led2_ein:
    ldi temp, (1<<LED2)
    ldi temph, LEDREIHE_ADR
    ldi temp3, MCP23S17_GPIOA
    rjmp mcp23s17_wr


led2_aus:
    ldi temp, ~(1<<LED2)
    ldi temph, LEDREIHE_ADR
    ldi temp3, MCP23S17_GPIOA
    rjmp mcp23s17_wr

; main.asm
;...
    SPI_INIT temp
    rcall mcp23s17_init
    rcall led1_ein
    rcall led2_aus

    ldi temp, ~(1<<LED2)
    ldi temph, LEDREIHE_ADR
    ldi temp3,MCP23S17_IODIRA
    rcall mcp23s17_wr       ; GPA7 = Ausgang
    ldi temp, ~(1<<LED1)
    ldi temph, LEDREIHE_ADR
    ldi temp3,MCP23S17_IODIRB
    rcall mcp23s17_wr       ; GPB0 = Ausgang

loop:  rcall led1_aus
  rcall led2_ein
  MEIN_DELAY_3BYTE 799996
  rcall led1_ein
  rcall led2_aus
  MEIN_DELAY_3BYTE 799996
  rjmp loop

Vielen Dank für hilfreiche Tipps

[Maxim B. (max182)]

Schade!
Ich wollte mehrere mcp23S17 mit einem ~SS betreiben, mit verschiedenen 
Adressen A0-A2. Aber solange nur A2 wirkt, kann ich höchstens zwei IC 
auf einem ~SS hängen lassen. Dabei ist Fehler recht komisch, so bleibt 
gewisse Risiko, daß irgendwann auch A2 nicht mehr wirkt... IC stammen 
von Reichelt.

Ich weiß nicht, was hier besser zu machen ist: ein paar mcp23S17 bei 
Conrad bestellen und genauso testen? Oder einfach für alle IC separate 
~SS verwenden? Dann allerdings scheint in manchen Fällen 74HC595 besser 
zu sein: nur 1 byte zu übertragen statt 3.

Ich habe mit verschiedenen Geschwindigkeiten ausprobiert. IOCON lässt 
sich lesen lassen. HAEN steht auf 1. Für Sicherheit habe ich auch andere 
Register abgelesen: alles stimmt.

;==== Test
mcp23s17_regzeigen:  ; temp3: IC-reg-adr, temph: IC-adr, temp: zeile(7-5)/platz(4-0)
  push temph
  push temp
  mov temph, temp
  andi temph, 0x1f
  pop temp
  swap temp
  lsr temp
  andi temp, 3
  rcall lcd_setcursor
  pop temph
  rcall mcp23s17_rd

  mov temph, temp
  ldi temp3, 8

mcp23s17_regzeigen_loop1:
  sbrs temph,7
  rjmp mcp23s17_regzeigen_L01
  ldi temp, '1'
  rjmp mcp23s17_regzeigen_H01

    mcp23s17_regzeigen_L01:  
  ldi temp, '0'
    mcp23s17_regzeigen_H01:  
  rcall lcd_data
  lsl temph
  dec temp3
  brne mcp23s17_regzeigen_loop1
  ret

.macro  MCP23S17_REGLCD    ; @0 = zeile  @1 platz
  ldi temp, (@0<<5)|@1  ; @2 = IC-adr @3 =temp3: IC-reg-adr
  ldi temph, @2
  ldi temp3, @3
  rcall mcp23s17_regzeigen
.endm

  MCP23S17_REGLCD 1,8, 0, MCP23S17_IOCON
  MCP23S17_REGLCD 1,0, 0, MCP23S17_OLATA
  MCP23S17_REGLCD 0,8, 0, MCP23S17_OLATB

 Auch A2 wirkt. Nur A0 und A1 ohne Wirkung... Hat A2 GND, dann antwortet 
IC auf Adressen 0 bis 3. Wenn A2=Vcc, dann sind das die Adressen 4 bis 
7.

[Christian S. (roehrenvorheizer)]

Hallo,

hast Du die obligatorischen 100nF-Abblockkondensatoren am IC angebracht?
Sind A0...A2 direkt oder über Widerstände immer an GND oder + 
angeschlossen?
Was machst Du mit dem Reset-Anschluß?
Kannst Du mal Exemplare eines anderen Herstellers testen? Vielleicht 
sind die bisherigen Ausschuß?

Bei mir haben sie vor Jahren korrekt funktioniert, als ich die Adressen 
eingestellt habe...

MfG

[Maxim B. (max182)]

Christian S. schrieb:
> hast Du die obligatorischen 100nF-Abblockkondensatoren am IC angebracht?

Ja.

> Sind A0...A2 direkt oder über Widerstände immer an GND oder +
> angeschlossen?

Entweder an GND oder an Vcc.

> Was machst Du mit dem Reset-Anschluß?

Vcc.
Da IC ansonsten alles macht, die Ports arbeiten für IN und OUT, glaube 
ich nicht, daß Reset an Power-on nicht funktioniert.

> Kannst Du mal Exemplare eines anderen Herstellers testen? Vielleicht
> sind die bisherigen Ausschuß?

Ich dachte, die sind alle von Microchip. Macht sie noch jemand?
Ich dachte, bei Reichelt trifft man keine defekten IC wie bei Chinesen 
per Amazon? Sollte ich ein paar von Conrad kaufen?

[S. Landolt (Gast)]

> Bei Init setze ich HAEN in IOCON auf 1.

Vermutlich geschieht eben dies nicht - lässt sich aber nicht überprüfen, 
da die Definitionen fehlen.

[Maxim B. (max182)]

S. Landolt schrieb:
> Vermutlich geschieht eben dies nicht - lässt sich aber nicht überprüfen,
> da die Definitionen fehlen.

Ich habe auch IOCON gelesen und auf LCD angezeigt. Dafür dienen Funktion 
mcp23s17_regzeigen und Macros MCP23S17_REGLCD. Ich habe auch alle andere 
Register abgelesen, um sicher zu bleiben, daß IOCON gelesen wird und 
nicht etwas anderes. Ergebnis bei IOCON ist nach Init immer "00001000"

Definitionen:

.equ   MCP23S17_IOCON      = 0x05  
.equ   MCP23S17_IOCON_1    = 0x0a  
.equ  MCP23S17_IOCON_BANK    = 7
.equ  MCP23S17_IOCON_MIRROR  = 6  
.equ  MCP23S17_IOCON_DISSLW  = 4  
.equ  MCP23S17_IOCON_HAEN    = 3  
.equ  MCP23S17_IOCON_ODR    = 2  
.equ  MCP23S17_IOCON_INTPOL  = 1  



.equ   MCP23S17_IODIRA    = 0x00; IOCON.BANK = 0  
.equ   MCP23S17_IODIRA_1  = 0x00; IOCON.BANK = 1  

.equ   MCP23S17_IODIRB    = 0x01; IOCON.BANK = 0
.equ   MCP23S17_IODIRB_1  = 0x10; IOCON.BANK = 1

.equ   MCP23S17_IPOLA    = 0x02; IOCON.BANK = 0  
.equ   MCP23S17_IPOLA_1  = 0x01; IOCON.BANK = 1  

.equ   MCP23S17_IPOLB    = 0x03; IOCON.BANK = 0  
.equ   MCP23S17_IPOLB_1  = 0x11; IOCON.BANK = 1  

.equ   MCP23S17_GPINTENA  = 0x04; IOCON.BANK = 0  
.equ   MCP23S17_GPINTENA_1  = 0x02; IOCON.BANK = 1  

.equ   MCP23S17_GPINTENB  = 0x05; IOCON.BANK = 0  
.equ   MCP23S17_GPINTENB_1  = 0x12; IOCON.BANK = 1  

.equ   MCP23S17_DEFVALA  = 0x06; IOCON.BANK = 0  
.equ   MCP23S17_DEFVALA_1  = 0x03; IOCON.BANK = 1  

.equ   MCP23S17_DEFVALB  = 0x07; IOCON.BANK = 0  
.equ   MCP23S17_DEFVALB_1  = 0x13; IOCON.BANK = 1  

.equ   MCP23S17_INTCONA  = 0x08; IOCON.BANK = 0  
.equ   MCP23S17_INTCONA_1  = 0x04; IOCON.BANK = 1  

.equ   MCP23S17_INTCONB  = 0x09; IOCON.BANK = 0  
.equ   MCP23S17_INTCONB_1  = 0x14; IOCON.BANK = 1  

.equ   MCP23S17_GPPUA    = 0x0c; IOCON.BANK = 0  
.equ   MCP23S17_GPPUA_1  = 0x06; IOCON.BANK = 1  

.equ   MCP23S17_GPPUB    = 0x0d; IOCON.BANK = 0  
.equ   MCP23S17_GPPUB_1  = 0x16; IOCON.BANK = 1  

.equ   MCP23S17_INTFA    = 0x0e; IOCON.BANK = 0  
.equ   MCP23S17_INTFA_1  = 0x07; IOCON.BANK = 1  

.equ   MCP23S17_INTFB    = 0x0f; IOCON.BANK = 0  
.equ   MCP23S17_INTFB_1  = 0x17; IOCON.BANK = 1  

.equ   MCP23S17_INTCAPA  = 0x10; IOCON.BANK = 0  
.equ   MCP23S17_INTCAPA_1  = 0x08; IOCON.BANK = 1  

.equ   MCP23S17_INTCAPB  = 0x11; IOCON.BANK = 0  
.equ   MCP23S17_INTCAPB_1  = 0x18; IOCON.BANK = 1  

.equ   MCP23S17_GPIOA    = 0x12; IOCON.BANK = 0  
.equ   MCP23S17_GPIOA_1  = 0x09; IOCON.BANK = 1  

.equ   MCP23S17_GPIOB    = 0x13; IOCON.BANK = 0  
.equ   MCP23S17_GPIOB_1  = 0x19; IOCON.BANK = 1  

.equ   MCP23S17_OLATA    = 0x14; IOCON.BANK = 0  
.equ   MCP23S17_OLATA_1  = 0x0a; IOCON.BANK = 1  

.equ   MCP23S17_OLATB    = 0x15; IOCON.BANK = 0  
.equ   MCP23S17_OLATB_1  = 0x1a; IOCON.BANK = 1  


.equ  MCP23S17_SS_PORT  = PORTB
.equ  MCP23S17_SS_DDR    = DDRB
.equ  MCP23S17_SS      = PB4

.equ  MCP23S17_RW      = 0

[S. Landolt (Gast)]

Was passiert, wenn Sie in mcp23s17_init

  ldi temp3, MCP23S17_IOCON_1

schreiben statt

  ldi temp3, MCP23S17_IOCON

?

[Michael U. (amiga)]

Hallo,

es gab mal ein Errata dazu:
ww1.microchip.com/downloads/en/DeviceDoc/80311a.pdf
Keine Ahnung, ob das auf Deine Chip-Revision zutrifft.
Ich habe nur 2 Stück am SPI-Bus auf Adresse 0 und 1, da ist A2 auf Low 
und es läuft.
ICON hat 2 Adressen für das gleiche Register, 0x0A und 0x0B, es ist 
egal, womit man es adressiert.

Gruß aus Berlin
Michael

[Christian S. (roehrenvorheizer)]

"Ich dachte, die sind alle von Microchip. Macht sie noch jemand?"

Hast Recht.

MfG

[S. Landolt (Gast)]

Derzeit wird mit
.equ   MCP23S17_IOCON      = 0x05
adressiert, mir scheint, es wurde bei IOCON Bank 0 und 1 verwechselt.

[Maxim B. (max182)]

S. Landolt schrieb:
> Was passiert, wenn Sie in mcp23s17_init  ldi temp3, MCP23S17_IOCON_1
> schreiben statt  ldi temp3, MCP23S17_IOCON
> ?

Genial!!!!
Nun arbeiten alle Adressenpins!!!!

Ich habe falsche Definition gemacht, Bank verwechselt...

Nun aber spinnt etwas mit anderen Register. Obwohl ich IOCON_BANK auf 0 
lasse, antworten die Register nur auf OLATA_1 und OLATB_1 und nicht auf 
OLATA und OLATB. Ich muß noch irgendwo Fehler haben...

Aber vielen Dank! Wenigstens A0-A2 Pins arbeiten.

[Michael U. (amiga)]

Hallo,

S. Landolt schrieb:
> Derzeit wird mit
> .equ   MCP23S17_IOCON      = 0x05
> adressiert, mir scheint, es wurde bei IOCON Bank 0 und 1 verwechselt.

IOCON ist nach PowerOn/Reset auf 0x0a/0x0b weil Bank 0 aktiv ist, 
richtig.

Gruß aus Berlin
Michael

[S. Landolt (Gast)]

Gruß aus dem Schwarzwald:

Hoorig isch die Katz!
Oh jerum, oh jerum, d' Fasnet het e Loch.

[Maxim B. (max182)]

Guten Abend!

Ich bin immer noch an Basteln mit MCP23S17.

Verhalten von IC ist trotzdem komisch...

Testprogramm:
1. HAEN = 1. MCP23S17 wird für diese Operation mit 0b01000000 
angesprochen.
danach alle Operationen mit Rücksicht auf Einstellung von Pins A0-A2.
2. IODIR wo notwendig auf 0 (Ausgang).
3. unendliche Schleife: IODIR, IOCON, GPIO und OLATA werden gelesen und 
auf dem LCD gezeigt. Dazwischen blinken zwei LEDs.

Wenn A2=0, alles einwandfrei.

Wenn A2=1:
Trotz Einsetzen wird HAEN als 0 gelesen. Auch IC antwortet auf alle 
Adressen mit A2=1 (aber mit A2=0 antwortet IC nicht! ).
Wenn ich beim Starten A2=0 eine Weile halte und schalte A2=1 erst 
während der Schleife, dann wird HAEN=1 gezeigt und Verhalten von IC wird 
wie erwartet, d.h. nur eine Adresse wird erkannt. Dann natürlich blinken 
LEDs nicht, da IODIR nicht eingestellt wird. Aber auf LCD wird alles 
korrekt angezeigt...

Hantieren mit SPI-Geschwindigkeit hat nichts gebracht.

Korrektes Verhalten wurde erreicht, indem ich einfaches Schreiben in 
Register durch Lesen - Modifizieren - Schreiben ersetzt hatte. D.h. 
statt

led2_ausgang:
    ldi temp, ~(1<<LED2)
    ldi temph, LEDREIHE_ADR
    ldi temp3,MCP23S17_IODIRB
    rjmp mcp23s17_wr       ; GPB0 = Ausgang

led2_ausgang:
    ldi temph, LEDREIHE_ADR
    ldi temp3, MCP23S17_IODIRA
    rcall mcp23s17_rd
    andi temp,~(1<<LED2)
    ldi temph, LEDREIHE_ADR
    rjmp mcp23s17_wr      ; GPA7 = Ausgang

gemacht.

mcp23s17_wr:  ; temp=Daten, temph=slave address, temp3=reg
  cbi MCP23S17_SS_PORT, MCP23S17_SS
  lsl temph
  ori temph, (1<<6)  ;0b0100xxx0
  SPI_SEND temph
  SPI_SEND temp3
  SPI_SEND temp
  sbi MCP23S17_SS_PORT, MCP23S17_SS
  ret

mcp23s17_rd:  ; temp= geles.Daten, temph=slave address, temp3=reg
  cbi MCP23S17_SS_PORT, MCP23S17_SS
  lsl temph
  ori temph, (1<<MCP23S17_RW)|(1<<6)  ;0b0100xxx1
  SPI_SEND temph
  SPI_SEND temp3
  ldi temp, 0xff
  SPI_SEND temp
  sbi MCP23S17_SS_PORT, MCP23S17_SS
  in temp,SPDR
  ret

Nun überlege ich, was war das eigentlich? :)
Warum so?

Kann das daran liegen, daß IC auf einem Kontaktfeld ohne Löten aufgebaut 
wurde (aber mit Kondensator 100 n )?
Ich glaube, das innere Leben von MCP23S17 sollte kompliziert sein, da 
Zustand von Pin A2, zum Unterschied von A1 und A0, irgendwo getriggert 
sein sollte.

[S. Landolt (Gast)]

Also das sieht aber doch nach dem von Michael U. (aus Berlin) verlinkten 
Erratum aus; haben Sie das gelesen?