Datenlogger 10Kanal

#include <Adafruit_GFX.h>

#include <Adafruit_SSD1306.h>

#include <SPI.h>

#include <SD.h>

#define OLED_RESET 4

#define DEBUG 0

#ifdef DEBUG

 #define DEBUG_PRINT(x)     Serial.print (x)

 #define DEBUG_PRINTDEC(x)  Serial.print (x, DEC)

 #define DEBUG_PRINTLN(x)   Serial.println (x)

#else

 #define DEBUG_PRINT(x)

 #define DEBUG_PRINTDEC(x)

 #define DEBUG_PRINTLN(x)

#endif

Adafruit_SSD1306 display(OLED_RESET);

File myFile;

const char vers[] = "v1.0";

const unsigned long period = 5000;    // microsec.

const unsigned long runtime = 60000;  // millisec.

unsigned long count = 0;

int sensor = 0;

int buttonPushCounter = 0;   // counter for the number of button presses

int buttonState = 0;         // current state of the button

int lastButtonState = 0;     // previous state of the button

byte i = 0;

byte runcount = 0;

char fileString[11] = "RUN000.txt";

char buf[4] = "000";

String dataString = "ch1, ch2, ch3, ch4, ch5, ch6, ch7";

void setup() {

  pinMode(3, OUTPUT);           // tone output (not used yet)

  pinMode(4, INPUT);            // set pin to input

  digitalWrite(4, HIGH);        // turn on pullup resistors

  pinMode(5, INPUT);            // set pin to input

  digitalWrite(5, HIGH);        // turn on pullup resistors

  Serial.begin(38400);

  // Display

  display.begin(SSD1306_SWITCHCAPVCC, 0x3C);  // Adressierung beachten, hier 0x3C !

  startup();

  // SD Card

  // Serial.print("Initializing SD card...");

  // see if the card is present and can be initialized

  if (!SD.begin()) { // const int chipSelect = 4 - with this display not neccessary !

    DEBUG_PRINTLN("card failed, or not present !");

    SDerror();

  }

  DEBUG_PRINTLN("card initialized !");

  myFile = SD.open("runs.txt");

  // if the file opened okay, write to it

  if (myFile) {

    DEBUG_PRINT("Reading from SD file...");

    runcount = myFile.read();

    DEBUG_PRINT(runcount);

    DEBUG_PRINT("   ");

    runcount += 1;

    myFile.close();

    SD.remove("runs.txt");

  }

  myFile = SD.open("runs.txt", FILE_WRITE);

  // if the file opened okay, write to it

  if (myFile) {

    DEBUG_PRINT("writing to SD file...");

    myFile.write(runcount);

    DEBUG_PRINT(runcount);

    myFile.close();

  } else {

    myFile.close();

    DEBUG_PRINTLN("error opening runs.txt");

    SDerror();

  }

  sprintf(buf, "%03d", runcount);

  fileString[3] = buf[0];

  fileString[4] = buf[1];

  fileString[5] = buf[2];

}

void loop() {

  // read the pushbutton input pin:

  buttonState = digitalRead(4);

  // compare the buttonState to its previous state

  if (buttonState != lastButtonState) {

    // if the state has changed, increment the counter

    if (buttonState == LOW) {

      // if the current state is HIGH then the button went from off to on:

      buttonPushCounter++;

      DEBUG_PRINTLN("on");

      DEBUG_PRINT("number of button pushes: ");

      DEBUG_PRINTLN(buttonPushCounter);

      i = countdown(1);

    } else {

      // if the current state is LOW then the button went from on to off:

      DEBUG_PRINTLN("off");

    }

    // Delay a little bit to avoid bouncing

    delay(50);

  }

  // save the current state as the last state, for next time through the loop

  lastButtonState = buttonState;

  if (Serial.available()) {

    int inByte = Serial.read();

    switch (inByte) {

      case 's':

        Serial.println("measuring...");

        // tone(3, 500, 500);

        i = start();

        break;

      default:

        // statements

        break;

    }

  }

  if (i == 1) {

    recordData();

  } else {

    Messwertausgabe();

  }

}

void Messwertausgabe(void) {

  display.clearDisplay();

  display.setTextColor(WHITE);

  display.setTextSize(2);

  display.setCursor(0,0);

  display.print("run: ");

  display.println(runcount);

  display.setTextSize(1);

  display.setCursor(0,18);

  display.print("count: ");

  display.println(count);

  sensor = analogRead(0);

  uint16_t sensorgraph = sensor / 8; // 1.023 -> 127

  display.drawFastHLine(0, 29, sensorgraph, WHITE);

  display.drawFastHLine(0, 30, sensorgraph, WHITE);

  display.drawFastHLine(0, 31, sensorgraph, WHITE);

  display.display();

}

int start(void) {

  display.clearDisplay();

  display.setCursor(0,0);

  display.println("measuring... ");

  display.display();

  count = 0;

  return 1;

}

void recordData(void) {

  unsigned long timeMillis = millis() + runtime;

  unsigned long timeMicros = 0;

  myFile = SD.open(fileString, FILE_WRITE);

  if (myFile) {

    myFile.println(dataString);

  }

  do {

    if (micros() >= timeMicros) {

      timeMicros = micros() + period - 100; // 100us = program runtime   

      dataString = "";

      int analogPin;

      // read seven sensors and append to the string:

      for (analogPin = 0; analogPin < 6; analogPin++) {

        dataString += String(analogRead(analogPin)) + ",";

      }

      dataString += String(analogRead(analogPin)); // the last data without komma

      if (myFile) {

        myFile.println(dataString);

      } else {

        DEBUG_PRINTLN("error opening filestring");

        SDerror();

      }

    count++;

    }

  } while (millis() < timeMillis);

  i = 0;

  myFile.close();

}

void startup(void) {

  display.clearDisplay();

  display.setTextColor(WHITE);

  display.setTextSize(1);

  display.setCursor(3,1);

  display.println("c  A.STOECKL");

  display.drawCircle(5,5,5, WHITE);

  display.println();

  display.print("Version: ");

  display.print(vers);

  display.display();

  delay(3000);

}

void SDerror (void) {

  display.clearDisplay();

  display.setTextColor(WHITE);

  display.setTextSize(1);

  display.setCursor(0,0);

  display.println("SD card or file");

  display.setTextSize(2);

  display.setCursor(0,10);

  display.print("error");

  display.display();

  while(1);  

}

int countdown (byte j) {

  display.clearDisplay();

  display.setTextColor(WHITE);

  display.setTextSize(1);

  do {

    for (byte k = 10; k > 0; k--) {

      display.setCursor(0,0);

      display.clearDisplay();

      display.setTextSize(1);

      display.println("Count down  ");

      display.setTextSize(2);

      display.print(k);

      display.display();

      delay(1000);

    }

    j = 0;

  } while (j == 1);

  display.setTextSize(1);

  byte i  = start();

  return i;

}