PWM auf PB3 Atmega 328 P

[Herrmann (Gast)]

Hallo,

ich verstehe nicht warum mein Code nicht funktioniert.
Ich bekomme einfach keinen Output auf PB3 was ist mein Fehler?
Für Hilfe wäre ich sehr Dankbar.

Viele Grüße Herrmann

[Herrmann (Gast)]

Hier der Code nochmal in Text Form

 //Achte immer darauf welche Pwm Pins welche Timer benötigen!

void setup(){ 
  // WGM22/WGM21/WGM20 all set -> Mode 7, fast PWM
  // Set OC2B at bottom, clear OC2B at compare match
  TCCR2A = 0;
  TCCR2B = 0;
  //Fast PWM Mode
  TCCR2B |= (1<<WGM22);
  TCCR2A |=(1<<WGM21);
  TCCR2A |=(1<<WGM20); 
  TCCR2A |= (1<<COM2A1);
    
  // prescaler = 8
  TCCR2B &= ~(1<<CS22);
  TCCR2B |= (1<<CS21);
  TCCR2B &= ~(1<<CS20);
  
  
  
  //Hier Frequenz einstellen wir lassen aber auf 10 kHz  
  OCR2A = 100;
  //Hier von 0-200 Dutycycle einstellen
  OCR2B = 0;
  //So schalten wir die Pwm ein bzw. aus
 
  DDRB |= (1<<PB3);

 
} 
void loop() {
 
 //Loop wird hier stark verlangsamt
 OCR2B = map(analogRead(A0),0,1023,0,200);
  
  }

[S. Landolt (Gast)]

> Ich bekomme einfach keinen Output auf PB3 was ist mein Fehler?

PB3 ist OC2A, offenbar soll die Pulsbreitenmodulation aber auf OC2B 
erfolgen,.

[Herrmann (Gast)]

S. Landolt schrieb:
> PB3 ist OC2A, offenbar soll die Pulsbreitenmodulation aber auf OC2B
> erfolgen,.

Je genau deswegen schreibe ich ja auch :

TCCR2A |= (1<<COM2A1);

[S. Landolt (Gast)]

Aber für OC2A ist das SFR OCR2A zuständig, und dieses ist im Modus 7 der 
TOP-Wert.

[Arno (Gast)]

OC2A (der Pin) wird abhängig von OCR2A (dem Register) gesetzt/gelöscht. 
Nicht abhängig von OCR2B.

Ich hab das im Datenblatt nicht geprüft, vermute aber anhand der 
Kommentare "Frequenz einstellen", du hast einen CTC-Modus ausgewählt, 
d.h. der Timer läuft hoch bis OCR2A. Dann kannst du OC2A nicht als 
PWM-Ausgang verwenden, weil der Timer nie größer wird als OCR2A.

Das ist mit etwas anderen Worten das gleiche, was S. Landolt auch schon 
gesagt hat.

Es ergibt ferner im CTC-Modus keinen Sinn, wenn OCR2A 100 ist, in OCR2B 
Werte bis 200 zuzulassen. Der Timer läuft eh nur bis 100.

MfG, Arno

[Herrmann (Gast)]

okay entschuldige ich bin etwas neu im programmieren mit Registern. Was 
muss ich jetzt schreiben um eine PWM an PB3 zu bekommen? :)

[Herrmann (Gast)]

Arno schrieb:
> Es ergibt ferner im CTC-Modus keinen Sinn, wenn OCR2A 100 ist, in OCR2B
> Werte bis 200 zuzulassen. Der Timer läuft eh nur bis 100.

das ist richtig hier habe ich einen fehler gemacht ich wollte

OCR2A = 100;

 schreiben

[Herrmann (Gast)]

korrigiere OCR2A = 200;

[S. Landolt (Gast)]

Also entweder PWM im Modus 7 auf OC2B, das liegt auf PD3, oder PWM im 
Modus 3 auf OC2A (PB3), dann allerdings lässt sich die Frequenz nur sehr 
grob per Vorteiler einstellen.

[Georg M. (g_m)]

S. Landolt schrieb:
> PB3 ist OC2A

Richtig.

OC2A ---> PB3
OC2B ---> PD3

[S. Landolt (Gast)]

> Was muss ich jetzt schreiben um eine PWM an PB3 zu bekommen?

Als erster Versuch: Modus 3 verwenden, d.h. 'TCCR2B |= (1<<WGM22)' 
weglassen und 'OCR2A = map(analogRead...' schreiben.

[Herrmann (Gast)]

S. Landolt schrieb:
> Also entweder PWM im Modus 7 auf OC2B, das liegt auf PD3, oder PWM im
> Modus 3 auf OC2A (PB3), dann allerdings lässt sich die Frequenz nur sehr
> grob per Vorteiler einstellen.

Okay Danke also vielleicht erkläre ich mal mein Vorhaben. Ich möchte auf 
PB1,PB2 und PB3 eine PWM ausgeben im Mode 3 kann ich keinen Dutycycle 
einstellen. Ich benötige allerdings eine Frequenz von 10 kHz und einen 
variablen Dutycycle.

[S. Landolt (Gast)]

Für diese Anforderungen sehe ich bei den Gegebenheiten keine Lösung.

Timer2 im Modus 3, mit Vorteiler 1024 bei (vermutlich) 16 MHz, ergäbe 
15.6 kHz, doch weit weg von 10 kHz.

[Herrmann (Gast)]

Okay Entschuldigung die genaue Frequenz ist nicht so wichtig PB1, PB2, 
PB3 sollten nur alle die gleiche Frequenz haben so um die 10kHz es muss 
nicht genau 10 KHz sein +-3kHz sind egal.

[S. Landolt (Gast)]

Dann würde ich, als ersten Ansatz, für Timer1 & Timer2 den Vorteiler 
1024 versuchen.

[Herrmann (Gast)]

Habs hin bekommen danke :)

[Arno (Gast)]

Herrmann schrieb:
> im Mode 3 kann ich keinen Dutycycle
> einstellen.

Das stimmt so nicht.

MfG, Arno

[Herrmann (Gast)]

Jup hab ich auch gemerkt den dutycycle kann man sehr wohl einstellen, 
hier noch mein fertiger code:

//Dutycycle
uint8_t dtc = 0;

void setup(){ 
 
  setPwmPin9_10();
  setPwmPin11();
 
  }
  
  void loop() {
 
  //Loop wird hier stark verlangsamt
  dtc = map(analogRead(A0),0,1023,0,255);
  OCR1A = dtc;
  OCR1B = dtc;
  OCR2A = dtc;
  
   
  }



  void setPwmPin9_10(){
  // Reset Timer Register
  TCCR1A = 0;
  TCCR1B = 0;
  //Fast PWM Mode 
  TCCR1A |= (1<<WGM10);
  TCCR1B |= (1<<WGM12);
  //Setze Compare Modi non inverting Mode!
  TCCR1A |= (1<<COM1B1);
  TCCR1A |= (1<<COM1A1);

  //Setze Prescaler 8
  TCCR1B &= ~(1<<CS10);
  TCCR1B |=  (1<<CS11);
  TCCR1B &= ~(1<<CS12);
  //Setze Compare Values
  OCR1B = 0;
  OCR1A = 0;
  //Setze Pin 9 und 10 für aktiven PWM ausgang
  DDRB |= (1<<PB1);
  DDRB |= (1<<PB2); 
 }

  void setPwmPin11(){
  // Reset Timer Register
  TCCR2A = 0;
  TCCR2B = 0;
  //Fast PWM Mode TOP 0xFF
  TCCR2A |=(1<<WGM21);
  TCCR2A |=(1<<WGM20); 
  //Setze Compare Modi non inverting Mode!
  TCCR2A |= (1<<COM2A1);
  // prescaler = 8
  TCCR2B &= ~(1<<CS22);
  TCCR2B |= (1<<CS21);
  TCCR2B &= ~(1<<CS20);
  //Setze Compare Value
  OCR2A = 0;
  //Setze Pin11 afür aktiven PWM ausgang
  DDRB |= (1<<PB3);
    
    
  }

[S. Landolt (Gast)]

> Habs hin bekommen danke :)

Prima!
Ich hatte nämlich übersehen, dass beim Timer2 ja auch noch durch 2^8 = 
256 geteilt wird, damit sieht es dann deutlich besser aus, z.B. 16 MHz 
/256 /8 = 7.8 kHz.

[Veit D. (devil-elec)]

Hallo,

auch wenn der Timer scheinbar das macht was er soll, sollte man in der 
Arduino IDE alle Timerregister (TCCRnx und TIMSKn) vorher löschen. Die 
werden mittels setup() im Hintergrund für analogWrite voreingestellt. 
Das schützt vor unliebsamen Überraschungen wenn der Timer plötzlich 
nicht das macht was er eigentlich sollte. Ich selbst beginne mit TCCRnB, 
damit der Timer erstmal gestoppt ist.

Für die Prescalereinstellerei noch 2 Funktionen die einem das Leben 
leichter machen. Kannste auf jeden Timer anpassen.

void runTimer1 (const unsigned int prescaler)
{
  switch (prescaler) {  
    case    1 : TCCR1B |= _BV(CS10);              break;
    case    8 : TCCR1B |= _BV(CS11);              break;
    case   64 : TCCR1B |= _BV(CS11) | _BV(CS10);  break;
    case  256 : TCCR1B |= _BV(CS12);              break;
    case 1024 : TCCR1B |= _BV(CS12) | _BV(CS10);  break;
    default :   break;
  }  
}


void stopTimer1 (void)
{
  TCCR1B &= ~( _BV(CS12) | _BV(CS11) | _BV(CS10) );
}