VHDL Komponente, mehrfach instanziieren aber unterschiedlich bedaten.

[berndl (Gast)]

Hallo allerseits,
ich bin bzgl. VHDL und Ausnutzung der Features eher konservativ 
unterwegs, haette da aber jetzt gerne mal ein Problem :o)

Ich habe verschiedene SPI-Interfaces mit identischen Chips oder 
zumindest Protokoll-kompatiblen Chips, aber jeweils unterschiedlicher 
Topologie:
* 2x ChipSelect mit 4-Kanal+AUX ADC
* 2x ChipSelect mit 3-Kanal ADC
* 4x ChipSelect mit 8-Kanal ADC

Also, die SPI-Master-FSM ist eigentlich immer die gleiche, aber die 
Kommandosequenzen sind in den 3 Faellen halt unterschiedlich.

Dazu habe ich mir (anstatt eines Logikgrabes) eine LUT-basierte 
FSM-Steuerung gebaut, sieht z.B. fuer einen der Faelle so aus (so im 
Package definiert):

type t_lut_cmd is array (0 to 39) of std_logic_vector (4+8+4-1 downto 0);
constant c_lut_cmd1 : t_lut_cmd := (
  0 => x"0_C0_F",
  1 => x"0_C4_0",
  2 => x"0_C8_1",
  3 => x"0_C8_2",
  4 => x"1_C0_F",
  5 => x"1_C4_0",
  6 => x"1_C8_1",
  7 => x"1_C8_2",
  others => x"0_00_E"
);
constant c_lut_cmd2 ....

Es gibt also verschiedene Varianten dieser "lut_cmd" die im Package 
definiert sind, halt noch mehrere 'constant' Eintraege. In meiner FSM 
bzw. der zugehoerigen VHDL-Beschreibung muesste ich jetzt einfach nur 
noch zwischen den 2/3/4/5/... "constant"-Zuweisungen umschalten koennen 
und ich haette eine Logikbeschreibung, die aber durch die selektive 
Initialisierung personifiziert.
In der VHDL-Beschreibung wuerde ich jetzt abhaengig von einem Parameter 
oder sonstwas gerne einen der beiden folgenden Faelle deklarieren 
koennen:

signal lut_cmd : t_lut_cmd := c_lut_cmd1  -- erste Variante, oder
signal lut_cmd : t_lut_cmd := c_lut_cmd2  -- 2. Variante, usw...

Preisfrage: Wie kann ich das machen? Mit 'generics' denke ich nicht. 
Aber den Code einfach zu duplizieren und nur die Initialisierung aendern 
(1 Character!) kanns ja nicht sein... Jede Aenderung in Zukunft muesste 
ich dann in allen Varianten nachziehen...

[Gustl B. (-gb-)]

generate_LUTs:
if $signal = True generate
signal lut_cmd : t_lut_cmd := c_lut_cmd1;
else generate
signal lut_cmd : t_lut_cmd := c_lut_cmd2;
end generate;

berndl schrieb:
> Mit 'generics' denke ich nicht.

Das würde auch gehen wenn du Generics z. B. als Index für ein Array 
verwendest.

signal lut_cmd : t_lut_cmd := LUTARRAY(Generic);

[berndl (Gast)]

ui, das ging ja schnell, danke!

Was ist:

$signal

 und woher kommt das?
Ich moechte ja die Komponente mehrfach einbauen, halt jeweils mit 
verschiedenen Initialisierungen ueber die 'constant' im Package.

Danke schon mal!

[berndl (Gast)]

... andersrum gefragt: Kann ich einen 'generic' beim Instanziieren 
nehmen und den bei der Deklaration von Signalen verwenden? Das waer ja 
geil!

[berndl (Gast)]

Gustl B. schrieb:
...
>
> berndl schrieb:
>> Mit 'generics' denke ich nicht.
>
> Das würde auch gehen wenn du Generics z. B. als Index für ein Array
> verwendest.
>
> signal lut_cmd : t_lut_cmd := LUTARRAY(Generic);

Hab' drueber nachgedacht, geht so aber denke ich nicht. Weil: Da wuerde 
ich ja ein viel groesseres Array anlegen, also eigentlich wuerde ich 
"alle" Instanzen ins Array packen und halt per Offset den passenden 
Eintrag auswaehlen. Das waere aber eine gewaltige 
Resourcenverschwendung...
Mir geht's darum: Eine VHDL-Komponente, die eine LUT anzieht. Diese LUT 
soll je nach Komponenteninstanziierung unterschiedlich mit Default-Daten 
befuellt werden.
Uebrigens: Die LUT soll natuerlich spaeter zur Laufzeit auch noch 
veraenderbar/beschreibbar sein, bietet sich fuer Testzwecke geradezu an

[Gustl B. (gustl_b)]

berndl schrieb:
> Was ist:
> $signal

Damit meinte ich ein beliebiges Signal. Das darfst du dir ausdenken.

berndl schrieb:
> Kann ich einen 'generic' beim Instanziieren nehmen und den bei der
> Deklaration von Signalen verwenden?

Wie meinst du das genau?

berndl schrieb:
> Das waere aber eine gewaltige Resourcenverschwendung

Wieso? Da wird doch immer nur ein Index ausgewählt und dessen Inhalt 
landet im FPGA, der Rest des Arrays nicht.

[berndl (Gast)]

Gustl B. schrieb:
...
> berndl schrieb:
>> Kann ich einen 'generic' beim Instanziieren nehmen und den bei der
>> Deklaration von Signalen verwenden?
>
> Wie meinst du das genau?
...

Moin, was ich versuche ist folgendes:

architecture dings of bumms is
    signal lut_cmd ; t_lut_cmd := c_lut_cmd1;
...
begin
...

in Abhaengigkeit eines Parameters entweder mit 'c_lut_cmd1' oder 
'c_lut_cmd2' oder ... zu initialisieren.
Wenn ich das richtig sehe, dann kann ich in dem Teil der architecture 
(also dem Deklarationsteil vor dem begin) kein generate verwenden.

Dein Vorschlag mit dem Index koennte funktionieren, probiere ich mal 
aus. Evtl. ginge auch Initialisierung per function und mitgegebenem 
Parameter/Generic beim Aufruf...

[berndl (Gast)]

so, mit der Initialisierung per function scheints zu tun:

entity hier_steht_ein_name is
generic (C_LUT_INIT : integer := 1);
port (
    ...
);
end;

architecture dings of bumms is
    function init_lut (num : integer) return t_lut_cmd is
    begin
        if num = 1 then
            return c_lut_cmd1;
        elsif num = 2 then
            return c_lut_cmd2;
        else
            return c_lut_cmd3;
        end if;
    end function;

    signal lut_cmd : t_lut_cmd := init_lut (C_LUT_INIT);
    ...
begin

Ist schoen uebersichtlich. Danke fuer die Denkanstoesse. Vielleicht kann 
ja jemand anderes auch was damit anfangen...