Komisches Arduino-Phänomen mit PROGMEM und DCF77-Empfang

[Martin (Gast)]

Ich brüte aktuell über einem LCD-Uhrenprojekt als Vorbereitung für eine 
Word-Clock.

Derzeit werte ich ein DCF77-Modul aus, stelle damit regelmäßig die 
DS3132 RTC und habe auch noch einen DHT22-Temperatur/Feuchtigkeitssensor 
angeschlossen. Daneben nutze ich auch 2 JQ6500 MP3-Soundmodule zum 
Abspielen von Glockenschlägen und Uhrenticken.

Jetzt wollte ich noch eine Kalenderfunktionalität einbauen. Dazu wird im 
Sketch am Anfang eine Struktur definiert und einmal am Tag geprüft, ob 
relevante Ereignisse vorliegen. Diese werden dann abwechselnd auf dem 
LCD-Display ausgegeben.

Die Kalenderdaten liegen im PROGMEM, um Variablenspeicher zu sparen.
Sobald ich die Einleseroutine mit kompiliere, fkt. der DCF-Emfang nicht 
mehr und bei der Soundausgabe gibt es auch Probleme. Gerade als ob im 
Speicher etwas durcheinander gekommen wäre.

Was mache ich hier falsch? Kann man den PROGMEM-Speicher so mit memcpy_P 
() einlesen? Irgendwo ein ', ", & etc. vergessen?

Hier die Struktur:

struct event_type
{
    // Struktur z.B. für Geburtstage
    byte Tag;
    byte Monat;
    int  Jahr;          // 9999 = Feiertag
    char Name[22];
    byte Typ;           // 1 = Geburtstag, 2 = Todestag, 3 = Jahrestag, 4 = Restmüll, 5 = Blaue Tonne, 6 = Gelbe Tonne, 7 = Biomüll
};

const event_type Ereignis[] PROGMEM =
{
    // hier die Datümer und die Namen auflisten
    {24, 12, 9999, "Heiligabend", 3},
    {25, 12, 9999, "1. Weihnachtstag", 3},
    {26, 12, 9999, "2. Weihnachtstag", 3},
    {7, 8, 9999, "Sylvester", 3},
    // ...
};

event_type Ereignis_SRAM;                   // wird für die Kopie in den Variablenspeicher benötigt

Tägliches Abfragen (hier kommen anscheinend die Probleme her):

        DateTime RTC_Zeit = rtc.now();
    
        if (RTC_Zeit.day() != Tag_alt)      // wenn neuer Tag, dann Termine einlesen
        {
            Tag_alt = RTC_Zeit.day();
            Flag_Tagesereignis = false;
    
            for (int i = 0; i < sizeof(Ereignis) / sizeof(event_type); i++)
            {
                // über die Tabelle loopen und Tag/Monat mit aktuellem Datum vergleichen
                // dann den Namen anzeigen etc.
    
                memcpy_P (&Ereignis_SRAM, &Ereignis[i], sizeof(event_type));       // zuerst einen Eintrag des PROGMEM-Arrays ins SRAM (Variablenspeicher) kopieren
    
                if (Ereignis_SRAM.Tag == RTC_Zeit.day() && Ereignis_SRAM.Monat == RTC_Zeit.month())
                {
                    switch (Ereignis_SRAM.Typ)                                // 1 = Geburtstag, 2 = Todestag, 3 = Jahrestag
                    {
                        case 1:
                            Ereignis_Typ = '*';
                            break;
                        case 2:
                            Ereignis_Typ = '+';
                            break;
                        case 3:
                            Ereignis_Typ = ' ';
                            break;
                    }
    
                    Flag_Tagesereignis = true;                                          // wir haben ein Ereignis an diesem Tag gefunden, das angezeigt werden soll
    
                    Serial.println (Ereignis_SRAM.Name);
                    Serial.println (Ereignis_SRAM.Tag);
                    Serial.println (Ereignis_SRAM.Monat);
                    Serial.println (Ereignis_SRAM.Jahr);
                    Serial.println (Ereignis_SRAM.Typ);
    
                    strcpy (Ereignis_Name, Ereignis_SRAM.Name);                         // String2 = String1 geht nicht, daher strcpy nutzen !
    
                }
            }
        }

    if (Flag_Tagesereignis == true)
    {
        // Infos abwechselnd darstellen

        Anzeige_s++;            // Anzeigedauer in Sekunden hochzählen, startet bei 0

        if (Display == 0)
        {
            if (Anzeige_s == 1)
            {
                lcd.setCursor(0, 2);
                lcd.print(F("                    "));

                lcd.setCursor(0, 2);
                lcd.print(Wochentag[RTC_Zeit.dayOfTheWeek()]);

                lcd.setCursor(10, 2);
                char buf3[] = "DD.MM.YYYY";
                lcd.print(RTC_Zeit.toString(buf3));
            }
            if (Anzeige_s == 5)
            {
                Anzeige_s = 0;
                Display   = 1;
            }
        }
        else
        {
            if (Anzeige_s == 1)
            {
                lcd.setCursor(0, 2);
                lcd.print(F("                    "));

                lcd.setCursor((10 - (strlen(Ereignis_Name) + 2) / 2), 2);       // mittig ausgeben
                lcd.print(Ereignis_Name);
                lcd.print(' ');
                lcd.print(Ereignis_Typ);
            }
            if (Anzeige_s == 5)
            {
                Anzeige_s = 0;
                Display   = 0;
            }
        }
    }

[jo mei (Gast)]

Martin schrieb:
> Was mache ich hier falsch?

Erstelle ein Minimal-Programm welches den Fehler repoduziert bzw.
repoduzierbar macht und poste es hier.

Dann kann man weiter sehen.

--> Längeren Sourcecode nicht im Text einfügen,
--> sondern als Dateianhang.

Du siehst schon an der Re-Formatierung deiner Source-Fragmente
dass es so wie es jetzt ist, eine Qual ist, abgesehen vom
fehlenden Gesamt-Programm.

[EAF (Gast)]

struct Event_type
{
    // Struktur z.B. für Geburtstage
    byte Tag;
    byte Monat;
    int  Jahr;          // 9999 = Feiertag
    char Name[22];
    byte Typ;           // 1 = Geburtstag, 2 = Todestag, 3 = Jahrestag, 4 = Restmüll, 5 = Blaue Tonne, 6 = Gelbe Tonne, 7 = Biomüll
};
const Event_type ereignis[] PROGMEM =
{
    // hier die Datümer und die Namen auflisten
    {24, 12, 9999, "Heiligabend", 3},
    {25, 12, 9999, "1. Weihnachtstag", 3},
    {26, 12, 9999, "2. Weihnachtstag", 3},
    {7, 8, 9999, "Sylvester", 3},
    // ...
};

void setup() 
{
  Serial.begin(9600);
  for(const Event_type &e:ereignis)
  { 
    Serial.println((const __FlashStringHelper*)e.Name);
  } 
}

void loop() 
{

}

Ausgabe:

Heiligabend
1. Weihnachtstag
2. Weihnachtstag
Sylvester

Für die anderen Felder könntest du pgm_read_byte() und seine Freunde 
nutzen.

[Martin (Gast)]

Beim Erstellen der Minimalversion ist mit aufgefallen, dass der 
Kalenderabfrageteil viel zu oft aufgerufen wird und vorher immer wieder

DateTime RTC_Zeit = rtc.now();

zur Übernahme der Real-Time-Clock-Zeit aufgerufen wurde.

Habe nun den Block verschoben, dass er nur jede Sekunde aufgerufen wird.
Dort konnte ich mir das DateTime sparen, da RTC_Zeit schon gesetzt war.

Nun funktioniert´s, aber warum, kann ich nicht sagen ...

Komisch war vorher nur: Compiler nölt nicht, Prg. macht trotzdem 
seltsame Dinge ;-)

@EAF: Mit pgm_read und Konsorten ist es mir nicht gelungen, den Text 
einzulesen. Da sitzt das Problem ws. wieder 80 cm vor dem Bildschirm ...

[EAF (Gast)]

Martin schrieb:
> Mit pgm_read und Konsorten ist es mir nicht gelungen, den Text
> einzulesen.

Warum willst du das?

[jo mei (Gast)]

Martin schrieb:
> Mit pgm_read und Konsorten ist es mir nicht gelungen, den Text
> einzulesen.

Oft vergisst man dabei dass pgm_read_byte(..) (als Beispiel)
ein Argument vom Datentyp PGM_P verlangt, also einen Pointer
auf Daten im Flash. Mit normalen Pointer auf einen String im
RAM funktioniert das nicht.

void uart_putstring_progmem (PGM_P ss)
{
    uint8_t val;
    while ( (val=pgm_read_byte(ss++)) != 0 )
      uart_putchar(val);
} /* --- uart_putstring_progmem --- */

[EAF (Gast)]

jo mei schrieb:
> Oft vergisst man dabei dass pgm_read_byte(..) (als Beispiel)
> ein Argument vom Datentyp PGM_P verlangt, also einen Pointer
> auf Daten im Flash. Mit normalen Pointer auf einen String im
> RAM funktioniert das nicht.

Gerne wird vergessen/unterschlagen, dass das Arduino Print, welches 
seine Eigenschaften an Serial, Wire, LCD und viele weitere vererbt, 
schon von hause aus Progmem Strings lesen und ausgeben kann.

Es macht also Null Komma gar keinen Sinn, Strings aus dem Progmem zu 
lesen, wenn man sie unverändert ausgeben(printen) möchte.

[Sebastian (Gast)]

Welcher uC? Atmega1284P?

LG, Sebastian

[Dietrich L. (dietrichl)]

Martin schrieb:
> Nun funktioniert´s, aber warum, kann ich nicht sagen ...
>
> Komisch war vorher nur: Compiler nölt nicht, Prg. macht trotzdem
> seltsame Dinge ;-)

Spekulation: Das Timing für den DCF77-Empfang reicht nicht, da das 
sonstige Programm zuviel Verarbeitungszeit verbraucht. Das merkt der 
Compiler natürlich nicht...

[Lok-Doc (Gast)]

Da das DCF77-Signal ja recht langsam ist (1 Bit pro Sekunde) und im 
Sketch selbst nicht so wahnsinnig viel passiert, sollte das Timing schon 
passen. Ich verwende auch keine delays(); alles wird brav über millis() 
abgefackelt.

Evtl. werden Timer oder Interrupts von den libraries parallel genutzt, 
das muss ich gelegentlich noch prüfen. Wenn dem so wäre, müßte es jedoch 
öfter Fehler geben.

Werde berichten.