Arduino schlafen legen und aufwachen mit interrupt

[Tobias H. (tobivanhernobi)]

Hallo,

ich habe leider Probleme damit, einen Arduino schlafen zu legen.

#include <avr/sleep.h>

const int Taster = 2;
int buttonState = 0;
int lastButtonState = 0;
int buttonPushCounter = 0;

void setup()
{
  Serial.begin(115200);
  pinMode(2, INPUT_PULLUP);
}

void loop()
{
  buttonState = digitalRead(Taster);
  //Überprüfen auf Veränderung
  if (buttonState != lastButtonState) {
    // Wenn letzter Wert nicht gleich:
    if (buttonState == HIGH) {
      buttonPushCounter += 1;
      ausgabe();
      Serial.print("number of button pushes: ");
      Serial.println(buttonPushCounter);
    }
  }
  delay(50); //Entprellen quick-and-dirty
  lastButtonState = buttonState; //für nächsten loop-Durchgang speichern
}

void ausgabe()
{
  if (buttonPushCounter == 4)
  {
    enterSleepMode();
  }
}

void isrAwake()
{
}

void enterSleepMode()
{
  Serial.println("in enterSleepMode");
  attachInterrupt(digitalPinToInterrupt(Taster), isrAwake, FALLING);
  set_sleep_mode(SLEEP_MODE_PWR_DOWN);
  sleep_mode();
}

Konkret, er legt sich nicht schlafen...Der Zähler geht hoch, 1, 2, 3 und 
dann geht er beim nächsten Tastendruck in "void enterSleepMode()" und 
sofort wieder in loop().

Woran kann das liegen?
Vielen Dank für Tipps.

[Stefan F. (Gast)]

Welcher Mikrocontroller ist das konkret?

Ich frage, weil der mit dem ich das mal ausprobiert habe für diesen 
Zweck keine Flanken (FALLING) benutzen kann.

[Tobias H. (tobivanhernobi)]

m328p auf dem Arduino
CHANGE? RISING?

[Stefan F. (Gast)]

sleep_enable(); fehlt

[Stefan F. (Gast)]

Tobias H. schrieb:
> RISING

Das ist auch eine Flanke.

Es geht nur LOW oder HIGH. Im Sleep Modus kann der Atmega328 keine 
Flanken erkennen, nur Pegel.

[Tobias H. (tobivanhernobi)]

Probiere ich, danke.

[Gerald B. (gerald_b)]

Du hast mit dem Delay zwar sowas Ähnliches, wie Entprellung für Arme 
gemacht. Das greift aber nicht beim Interrupt. Wenn da das Kabel länger 
ist und der Eingang gar noch offen ist, dann ist das Ding eine bessere 
Wünschelrute und wacht bei jedem bisschen Ladung auf, die 
rumvagabundiert. Also relativ niederohmigen Pullup/down (Richtwert 10K, 
erhöhen zum Stromsparen kann man immernoch) und 100n über den Taster.
Somit hast du elektrisch entprellt und der Controller kann sich auch mal 
unbehelligt schlafen legen ;-)

[Stefan F. (Gast)]

Damit dein AVR einschlafen kann musst du sleep_enable() aufrufen.

Stefan F. schrieb:
> Es geht nur LOW oder HIGH

Ich glaube das war falsch. Es geht wohl nur mit LOW, denn Arduino 
unterstützt hier nur die Pins 2 (INT0) und 3 (INT1).

Arduino erlaubt laut Doku 
(https://www.arduino.cc/reference/de/language/functions/external-interrupts/attachinterrupt/) 
noch eine Erkennung von HIGH, aber davon weder etwas im Datenblatt des 
AVR, noch im Quelltext 
(https://github.com/arduino/ArduinoCore-avr/blob/63092126a406402022f943ac048fa195ed7e944b/cores/arduino/WInterrupts.c#L73), 
Vielleicht gilt das nur für andere Mikrocontroller.

Dann gibt es beim ATmega328 noch den Pin-Change Interrupt auf so 
ziemlich allen Pins, aber den unterstützt Arduino scheinbar nicht auf 
dem Uno/Nano Board. Ein Blick in den Quellcode erhärtet den Verdacht:
https://github.com/arduino/ArduinoCore-avr/blob/63092126a406402022f943ac048fa195ed7e944b/cores/arduino/WInterrupts.c#L372

So viel zum Thema: Arduino ist ganz einfach, weil man die Details in der 
Doku weg lässt.

[Ob S. (Firma: 1984now) (observer)]

Stefan F. schrieb:

> Es geht nur LOW oder HIGH. Im Sleep Modus kann der Atmega328 keine
> Flanken erkennen, nur Pegel.

Nein, das ist natürlich Unsinn. Man darf halt dafür nur nicht INTx 
verwenden, sondern PCINTx. Letzteres kann überhaupt nur Flanken erkennen 
und kann immer auch als WakeUp-Quelle aus dem PowerDown dienen.

Sämtliche 328 (ob ohne was dran oder mit P oder mit PB dran) können das. 
Seit Jahrzehnten schon, möchte man hinzufügen.

[Stefan F. (Gast)]

Ob S. schrieb:
> Nein, das ist natürlich Unsinn. Man darf halt dafür nur nicht INTx
> verwenden, sondern PCINTx.

Dann zeige mal, wie du das mit Arduino erreichen willst. Hast du meine 
zweiter Erklärung (die mit den Screenshots und Links zur Doku und 
Quelltext) nicht gelesen?

[Stefan F. (Gast)]

Hier ist das "Problem" mit den Interrupts ausführlich beschrieben. Auch 
wie man am Arduino Framework vorbei die Pin Change Interrupts verwendet: 
https://dronebotworkshop.com/interrupts/

[Ob S. (Firma: 1984now) (observer)]

Stefan F. schrieb:

> Dann zeige mal, wie du das mit Arduino erreichen willst.

An Arduino vorbei programmieren natürlich. Arduino ist zwar ziemlicher 
Mist, geht aber nicht so weit, einem Direktzugriffe auf Register oder 
eigene Interrupthandler zu verbieten. Wobei letztere, wenn sie nur dem 
Zweck des Aufwachens dienen, ja obendrein leer sind, also 
programmiertechnisch keine nennenswerte Herausforderung darstellen 
dürften.

[Peter D. (peda)]

Stefan F. schrieb:
> Dann zeige mal, wie du das mit Arduino erreichen willst.

Nur weil eine IDE nicht für alles und jedes einen Befehl haben kann, ist 
es nicht verboten, es selber zu programmieren.

In den Urzeiten der Computerei gab es z.B. PEEK und POKE, um am Basic 
vorbei die dollsten Sachen zu programmieren.

[Tobias H. (tobivanhernobi)]

Vielen Dank, Gerald B., das ist die Lösung. Mit einem Kondensator 
klappt's wunderbar. Hätte ich mir eigentlich denken müssen, Taster 
wollen entprellt werden...

sleep_enable() ist nicht notwendig, mit sleep_mode() aus der sleep.h 
wird das se-bit automatisch gesetzt/wieder gelöscht.
FALLING/RISING/CHANGE geht übrigens auch alles.

[M. K. (sylaina)]

Tobias H. schrieb:
> sleep_enable() ist nicht notwendig, mit sleep_mode() aus der sleep.h
> wird das se-bit automatisch gesetzt/wieder gelöscht.
> FALLING/RISING/CHANGE geht übrigens auch alles.

Das ist richtig, was ich mich aber auch frage: Warum setzt du den 
Sleepmode immer wieder neu? Würde reichen, den in setup() einmal zu 
setzen ;)
Ähnliches gilt für attachInterrupt() ;)

[Peter D. (peda)]

Tobias H. schrieb:
> mit sleep_mode() aus der sleep.h
> wird das se-bit automatisch gesetzt/wieder gelöscht.

Wobei dieses Macro nicht interruptfest ist! Im günstigsten Fall geht nur 
ein Interrupt verloren (Uhr geht nach), im worst case schläft der MC für 
immer (bis zum nächsten CPU-Reset).
Und das Löschen von SE nach dem Sleep ist eh überflüssig, es reicht 
völlig das einmalige Setzen im Initcode.

[Rolf (rolf22)]

Ob S. schrieb:

>> Dann zeige mal, wie du das mit Arduino erreichen willst.
>
> An Arduino vorbei programmieren natürlich.

Wieso "vorbei"? In der Arduino IDE und auch in der Alternative 
"PlatformIO" von Visual Studio Code kann man in C++ alle Register 
ansprechen, und zwar mit Symbolen, die in diesen IDEs vordefiniert sind 
und genau denen entsprechen, die in der Prozessor-Doku benutzt werden.

@Stefan F.
Über die Register-Programmierung kann man man den 328P auch aus dem 
Deep-Sleep wecken, sowohl über die INT-Pins als auch über die 
PCINT-Pins. Bei den PCINT-Pins gibt es "Pin Change" als Event, bei den 
INT-PINS gibt es zusätzlich die Möglichkeiten "Low level", "Rising edge" 
und "Falling edge". Prozessor-Doku S. 80/82.

Steht alles in der Prozessor-Doku. Wer sich auf die Arduino-Doku und 
-Lib verlässt, muss eben "unten" bleiben und erfährt von vielen 
Möglichkeiten niemals etwas.

[Jörg (lixtop)]

#include <avr/sleep.h>

const byte LEDLOOP = 8;
const byte LEDWAKE = 9;

ISR (PCINT1_vect)
 {
 // handle pin change interrupt for A0 to A5 here
 
 // toggle LED
 digitalWrite (LEDWAKE, !digitalRead (LEDWAKE));
 }  // end of PCINT1_vect

void setup () 
  {
  pinMode (LEDWAKE, OUTPUT);
  pinMode (LEDLOOP, OUTPUT);
  digitalWrite (A0, HIGH);  // enable pull-up
  
  // pin change interrupt
  PCMSK1 |= bit (PCINT8);  // want pin A0
  PCIFR  |= bit (PCIF1);   // clear any outstanding interrupts
  PCICR  |= bit (PCIE1);   // enable pin change interrupts for A0 to A5
  
  }  // end of setup

void loop () 
{
  
  set_sleep_mode (SLEEP_MODE_PWR_DOWN);  
  sleep_mode ();  

  // flash to indicate we got out of sleep
  digitalWrite (LEDLOOP, HIGH);
  delay (100);
  digitalWrite (LEDLOOP, LOW);
  delay (100);
  
  } // end of loop

Quelle: http://gammon.com.au/interrupts

"Example of waking from sleep with a Pin Change Interrupt"