Ist das Verhalten so OK?

[Gustl B. (-gb-)]

Hallo, vielleicht ist es zu spät und ich bin Matsche im Kopf, aber das 
finde ich seltsam, also ein Minimalbeispiel:

library ieee; 
use ieee.std_logic_1164.all; 
use ieee.numeric_std.all;

entity tb_while is
end tb_while;

architecture tb of tb_while is

  signal counter                        : integer := 0;

begin

  process
  begin
    while counter < 15 loop
      wait for 10 ns;
      counter <= counter + 1;
    end loop;

    wait;
  end process;

end;

Welchen Wert nimmt counter maximal an?
Ja, richtig, 16.

Warum ist das so?
Weil

while counter < 15 loop

dann schon wieder ausgewertet wird wenn die Addition/Zuweisung

counter <= counter + 1;

noch nicht fertig ist.
Schreibt man noch einen kurzen wait dazu

counter <= counter + 1;
wait for 1 ps;

funktioniert es wie gewünscht.

Meine Frage ist, ob das jetzt schlicht normales Verhalten ist, also 
alles OK, oder ob das in aktuelleren Modelsim Versionen anders ist. Ich 
verwende die letzte freie von Intel, 2020.1.

Vielen Dank!

[Markus F. (mfro)]

Gustl B. schrieb:
> Meine Frage ist, ob das jetzt schlicht normales Verhalten ist,

Das kannst Du dir selber mit der Antwort auf die fundamentale Frage: 
"wann werden Signale in einem Prozess aktualisiert?" beantworten.

[Lothar M. (Firma: Titel) (lkmiller) (Moderator)]

Markus F. schrieb:
> wann werden Signale in einem Prozess aktualisiert?
Immer beim nächsten "wait".

Und dann die "Ausnahme" zum Verwirren von Anfängern: der Anfang eines 
Prozesses mit Sensitivliste ist ein implizierter "wait on".

  process (a,b,c) begin
    :
  end process;

  -- entspricht 

  process begin
    wait on a,b,c;
    :
  end process;

Und weil nach dem "Bearbeiten" eines Prozesses sofort wieder an dessen 
Anfang gesprungen wird, ergibt sich das "gefühlte" Verhalten, dass 
Signale in Prozessen mit Sensitivliste "am Prozessende" aktualisiert 
werden. Korrekterweise werden sie aber erst beim nächsten Prozessanfang, 
also beim nächsten impliziten "wait on" aktualisiert.

Man müsste hier also lediglich den counter in die Sensitivliste 
aufnehmen, dann wäre bei 15 Schluss.

[Gustl B. (-gb-)]

Lothar M. schrieb:
> Und dann die "Ausnahme" zum Verwirren von Anfängern

Exakt! Denn so hatte ich das gelernt, dass die neuen Werte am Ende vom 
Prozess zugewiesen werden.

Klar, mit dem wait macht natürlich Sinn, das habe ich verstanden. Ich 
hatte irgendwie angenommen, dass auch vor einer Abfrage wie while die 
Werte aktualisiert werden die im Code auch noch weiter oben steht.
Wieder was gelernt.

[Udo K. (udok)]

Die Logik in deinem Prozess ist mit dem while unnötig kompliziert. Das 
wait sollte immer nur einmal im Prozess vorkommen, normalerweise am 
Anfang oder in der Sensitivity Liste.

    process
    begin
        wait for 10 ns;
        if counter < 15 then
            counter <= counter + 1;
        end if;
    end process;

Schleifen würde ich nur mit Variablen und nicht mit Signalen verwenden, 
Variablen werden direkt bei der ":=" Zuweisung geändert, und entsprechen 
dann der üblichen C-Programmierlogik.

[Rick D. (rickdangerus)]

@udok: Deine Variante zählt zwar richtig, aber hat kein 'Ende'.
Ich verwende gerne Testbenches bzw. Simulationen, die sich von selbst 
beenden.
Dazu dürfen keine Events mehr offen sein:

...
   signal simulation_run : boolean := true;
...
begin

   tb_clk <= not tb_clk after tb_clk_period/2 when simulation_run;
...        
   stim_proc: process
   begin
      -- do some stimulus
      wait for 200 ns;

      -- do some more stimulus
      wait for 20 us;

      simulation_run <= false;
      wait;
   end process;
end architecture;