Richtiges OLED-Display, SSD1306 vs. SH1106

[Lutz S. (lutzs)]

Hallo,

ich bin dabei, dieses Projekt nachzubauen:

https://www.youtube.com/watch?v=K_SCrEY4aLs

https://github.com/VK2ARH/Pi-PicoRx

0,96" Display mit SSH1306 hatte ich da, damit funktioniert es. Ich würde 
aber gern ein Display mit 1,3" einsetzen (auf der Platine vorgesehen), 
finde aber nur Displays mit SH1106.

Im Sourcecode finde ich nur die Library für den 1306, in der BOM wird 
aber auch 1106 erwähnt.

Bin etwas verwirrt. Sind die weitgehend kompatibel, so dass es mit 
beiden funktionieren kann?

Danke für eure Tips.

[Nemopuk (nemopuk)]

Lutz S. schrieb:
> Sind die weitgehend kompatibel

Weitgehend, aber ganz ohne Codeänderung wird es nicht gehen. Beide 
Controller kann man gleich initialisieren, aber die Datenübertragung ins 
Display-RAM geht etwas anders.

Ich zeige dir das relevante Fragment aus meinem Arduino Code. Ich habe 
Feedback erhalten, dass er mit SH1106 funktioniert, selbst aber nur mit 
SSD1306 getestet.

void OLED::display()
{
    size_t index = 0;
    for (uint_fast8_t page = 0; page < pages; page++)
    {
        // Set memory address to fill
        i2c.beginTransmission(i2c_address);
        i2c.write(0x00); // command
        if (isSH1106)
        {
            i2c.write(0xB0 + page); // set page
            i2c.write(0x00); // lower columns address =0  // Some displays might need 0x02 here
            i2c.write(0x10); // upper columns address =0
        }
        else
        {
            i2c.write(0xB0 + page); // set page
            i2c.write(0x21); // column address
            i2c.write(0x00); // first column =0
            i2c.write(width - 1); // last column
        }
        i2c.endTransmission();

        // send one page of buffer to the display
        i2c.beginTransmission(i2c_address);
        i2c.write(0x40); // data
        for (uint_fast8_t column = 0; column < width; column++)
        {
            // Split the transaction into chunks of 32 bytes because that is a limitation of Arduino
            if (column>0 && (column % 31 == 0) )
            {
                i2c.endTransmission();
                i2c.beginTransmission(i2c_address);
                i2c.write(0x40); // data              
            }
            
            i2c.write(buffer[index++]);
        }
        i2c.endTransmission();
        yield(); // to avoid that the watchdog triggers
    }
}

Der Buffer wird hier verwendet, um das ganze Bild im RAM aufzubauen und 
es danach mit der oben gezeigten Funktion an das Display zu senden. Die 
Struktur entspricht dem Display.

width and height = Anzahl der Pixel vom Display
pages = (height + 7) / 8
bufsize = pages * width (Größe vom Buffer in Bytes)

Eine Page ist ein Balken, der 8 Pixel hoch ist und die ganze Breite des 
Display abdeckt. Jedes Byte steht für 8 untereinander liegende Pixel. 
Also wenn das Display 128 Pixel breit ist, dann ist jede Page 8 * 128 
Pixel groß, also 128 Bytes. Wenn das Display 32 Pixel hoch ist, dann hat 
es 4 Pages (vier Balken jeweils 8 Pixel hoch).

Die Stelle mit
> if (isSH1106) ...
ist für die Unterschiede zwischen den beiden Chips wichtig.

Der Kommentar
> Some displays might need 0x02 here
bezieht sich auf folgendes Fehlerbild: Das ganze Bild erscheint 
horizontal um zwei Pixel verschoben und am Rand erscheint ein zwei Pixel 
schmaler vertikaler Balken mit zufälligen Inhalt.

Die Zeilen 29-36 könnte man weg lassen, wenn Arduino nicht dieses blöde 
Limit auf maximal 32 Bytes pro I2C Transaktion hätte.