Wann out und wann sts benutzen?

[Roman (Gast)]

Hallo zusammen,

bei der Programmierung des MIDI Interfaces für meine Yamaha Orgel, ist 
mir aufgefallen das ich manche Einstellungen mit sts schreiben muss und 
manche mit out. Hier am Beispiel des externen Interuptes.

    ; Set EXTINT0
    ldi temp, (3<<ISC00)     ; Enable rising edge of INT0
    sts EICRA, temp
    
    ; Enable INT0    
    ldi temp, (1<<INT0)    ; Enable INT 0
    out EIMSK, temp

Ich verwende den mega88 und habe auch schon gelesen das der erweiterte 
I/O Bereich per in/out erreichbar ist. Welche Addressen sind das beim 
mega88?

Ferner habe ich das Problem das bei der Initialisierung des UART0 das 
einschalten des TX ein kopieren der Daten in UBR0H zur Folge hat.
Das heisst setzen des UCSR0B, danach ist UBRR0H identisch.

        ; Set Baudrate 
        ldi temp, LOW(UBRRVAL)
        sts UBRR0L, temp
        ldi temp, HIGH(UBRRVAL)
        sts UBRR0H, temp

        ; Frame-Format: 8 Bit
        ldi temp, (1<<UMSEL00)|(3<<UCSZ00)
        sts UCSR0C, temp
    
        ; Enable TX
        ldi temp, (1<<TXEN0)
        sts UCSR0B,temp

Muss ich hier auch einen anderen Befehl zum setzen des TXEN benutzen? 
Meine Versuche funktionierten alle nicht!

Jeder Rat ist willkommen.

Gruss

Roman

[Johannes M. (johnny-m)]

Schau mal ins Datenblatt. Am Ende des Datenblatts ist das Register 
Summary. Da kann man sehr schön sehen, welche Register zum normalen und 
welche zum extended I/O-Space gehören. Die Register, bei denen 
zusätzlich zur RAM-Adresse (in Klammern) noch eine Register-Adresse 
angegeben ist (0x00 bis 0x3F) sind per in und out ansprechbar. Alles 
darüber nur über lds und sts.

EDIT: Also alles bis zu dem dicken Strich in der Tabelle oberhalb vom 
SREG ist per in und out ansprechbar...

[Roman (Gast)]

Danke Johannes,

das ging aber schnell. Somit kann ich also über die m88def.inc festlegen 
ob ich die ASCR Adresse 0x30 mit out oder als 0x50 mit sts ansprechen 
will.

Hast Du eine Idee warum das mit dem setzen des TXEN nicht klappt. Per 
SBI komme ich da ja nicht hin. Also das ganze Register setzen und per 
sts hoch?

Gruss

Roman

[Johannes M. (johnny-m)]

Bitzugriff mit sbi/cbi (und auch mit den Skip-Befehlen sbis/sbic) geht 
nur für die unteren 32 Register (bis Register-Adresse 0x1F, da wo der 
andere dicke Strich ist). Alles darüber muss komplett geschrieben werden 
(bzw. Read-Modify-Write).

[ecslowhand (Gast)]

Probiers damit:

; ---------------------
; UART0 initialisieren
; ATMEGA 88
; ---------------------
USART_init:
cli            ; Interrupts sperren
ldi  r16, LOW((clock/(16*baudrate))-1)  ; Baudrate berechnen..
ldi  r17, HIGH((clock/(16*baudrate))-1)
sts  UBRR0L, r16        ; ...und setzen
sts  UBRR0H, r17

lds  r16, UCSR0B
sbr  r16, (1<<RXCIE0)      ; RX-Interrupt enable
sbr  r16, (1<<RXEN0)|(1<<TXEN0)
cbr  r16, (1<<UCSZ02)      ; 8 datenbits
sts  UCSR0B, r16

lds  r16, UCSR0C
cbr  r16, (1<<UCPOL0)      ; asyncron
cbr  r16, (1<<UMSEL01)|(1<<UMSEL00)    
cbr  r16, (1<<UPM01)|(1<<UPM00)    ; no parity
cbr  r16, (1<<USBS0)        ; 1 stopp-bit
cbr  r16, (1<<UCSZ02)      ; 8 datenbits
sbr  r16, (1<<UCSZ01)|(1<<UCSZ00)
sts  UCSR0C, r16

LG EC

[ecslowhand (Gast)]

Sorry, die Zeile für das UCSR0C-Register ist zu löschen !

cbr  r16, (1<<UCSZ02)      ; 8 datenbits

[Axel R. (Gast)]

Beitrag "Re: Fehler: "Operand out of range" bei out-Befehl"

[Roman (Gast)]

Danke an alle für die vielen Antworten. Vor allen Dingen die Macros 
scheinen Spitze zu sein, wenn ich sie denn dann verstanden habe ;-).

read-modify-write wie Johannes schon ausführte, allerdings ohne Stress 
wo steht das Register.

Danke und Gruss

Roman