Arduino als WOL server

[lens23 (Gast)]

Hallo,

ich möchte mit meinem Arduino und dem Ethernet Shield einen PC über WOL 
starten können.
Ich habe im Internet volgenden Code gefunden.
Warum funktioniert er nicht? PC wird nicht gestartet.

 

// Arduino Wake-On-LAN
// Needs Arduino > 1.0-beta3 with the new UDP API ( http://code.google.com/p/arduino/wiki/Arduino1 )

// Date: 04 September 2011
// Author: Michele Spagnuolo
// Email: [e-mail]
// Site: http://michele.spagnuolo.me

#include <SPI.h>
#include <Ethernet.h>
#include <EthernetUdp.h>

// ETHERNET CONFIGURATION
byte mac[] = { 0x90, 0xA2, 0xDA, 0x0D, 0xB1, 0xAC }; // Arduino's MAC address
byte ip[] = { 192, 168, 178, 21 }; // Arduino IP address
byte gw[] = { 192, 168, 178, 1}; // Gateway IP address
byte bc[] = { 192, 168, 178, 255 }; // Broadcast IP address

// WOL CONFIGURATION
byte pc_mac[] = {0x00, 0x24, 0x21, 0x7B, 0xA0, 0x07}; // PC's MAC address

EthernetUDP Udp;

char WOL_done = 0;

void setup() {
    Ethernet.begin(mac,ip,gw);
    delay(100);
    Udp.begin(7);
    delay(100);
}

void WOL(byte mac[]) {
    byte preamble[] = {0xFF, 0xFF, 0xFF, 0xFF, 0xFF, 0xFF};
    char i;

    Udp.beginPacket(bc, 7);
    Udp.write(preamble, sizeof preamble);
    
    for (i=0; i<16; i++)
      Udp.write(mac, sizeof mac);
    
    Udp.endPacket();
}

void loop() {
  if (WOL_done)
    WOL(pc_mac);
  WOL_done = 1;
}

[Cyblord -. (cyblord)]

Kannst du den PC denn überhaupt via WOL starten? Also mal von einem 2.PC 
über ein WOL-Tool versucht? Ist WOL korrekt aktiviert bei deinem PC?

[Bitflüsterer (Gast)]

Den Code habe ich mir jetzt nicht angeschaut.

Zum einen muss Deine Ethernetkarte Wake-On-LAN unterstützen. Nicht alle 
tun das.
Zum anderen kann es sein, dass das Feature erst an/in der Hardware oder 
per Software (evtl. BIOS) aktiviert werden muss.

[lens23 (Gast)]

Danke für eure schnellen Antworten.

Ich kann den PC von einem anderen PC aus ohne Probleme starten.

[Cyblord -. (cyblord)]

Hast du mal die korrekte Byteorder der ganzen Adressen überprüft?

[Patrick (Gast)]

Du rufst setup() einmal anfangs und dann loop() in einer Schleife auf?

Das da:

char WOL_done = 0;
...
void loop() {
  if (WOL_done)
    WOL(pc_mac);
  WOL_done = 1;
}

funktioniert somit natürlich nicht. Wahrscheinlich soll es

if (! WOL_done)
...

heißen.

[lens23 (Gast)]

hab es geändert, funktioniert trotzdem nicht :-(

[Εrnst B. (ernst)]

Dann: Am Ziel-PC wireshark laufen lassen, nachschauen, was für ein 
Packet dein Arduino da verbricht, und ob es überhaupt ankommt.

[micha (Gast)]

lens23 schrieb:
> Ich habe im Internet volgenden Code gefunden.
> Warum funktioniert er nicht? PC wird nicht gestartet.

Stimmt der IP Adressraum?

[Dirk B. (dirkb2)]

Das sizeof mac in der Funktion WOL liefert nicht den gewünschten Wert.
Da kommt sizeof (byte*) raus

Entweder du machst einen extra Paramter oder schreibst fest 6 rein.

[lens23 (Gast)]

Dirk B. schrieb:
> Das sizeof mac in der Funktion WOL liefert nicht den gewünschten
> Wert.
> Da kommt sizeof (byte*) raus
>
> Entweder du machst einen extra Paramter oder schreibst fest 6 rein.

ok, jetzt nochmals bitte für dummies. Wo muss ich die 6 reinschreiben?

[Jürgen S. (jurs)]

lens23 schrieb:
> ok, jetzt nochmals bitte für dummies. Wo muss ich die 6 reinschreiben?


Udp.write(mac, 6);

Weil Du das Array als Zeiger an die Funktion übergibst, ist "sizeof mac" 
nämlich nur 2 (= Größe des Zeigers).

[lens23 (Gast)]

danke, funktioniert einwandfrei.
Jetzt würde ich noch gerne einen 2. PC Starten können :D
Wie mach ich dass am elegantesten?

[Karl (Gast)]

lens23 schrieb:
> byte pc_mac[] = {0x00, 0x24, 0x21, 0x7B, 0xA0, 0x07}; // PC's MAC
> address

Die Adresse des 2. PC ebenfalls in ein Array schreien und dann aufrufen?

byte pc_mac_2[] = {0x00, 0x01, 0x02, 0x03, 0x04, 0x05}; // 2. PC's MAC

WOL(pc_mac_2);

[lens23 (Gast)]

alles klar, vielen Dank.
Funktioniert einwandfrei :-)

[ArminLinder (Gast)]

Tschuldigt, wenn ich hier so an diesen alten Therad anstückle, aber ich 
bin gerade dabei, mich in die Ardiuno Programmierung zu stürzen. Ich 
verstehe nicht, wieso die vorgeschlagene Lösung funktioniert.

byte mac[] = { 0x90, 0xA2, 0xDA, 0x0D, 0xB1, 0xAC };

definiert doch keinen Pointer, sondern ein statisches Array of Byte der 
Größe 6. Deswegen müsste sizeof mac eigentlich 6 zurückgeben, so wie das 
wohl auch die Absicht des Autors des ursprünglichen Codes war.

Um einen Pointer zu definieren, müsste ich doch in etwa sowas schreiben:

int (*mac)[] = { 0x90, 0xA2, 0xDA, 0x0D, 0xB1, 0xAC };

Ebenso bei der Übergabe an die WOL Funktion: ich sehe den Pointer nicht.

Kann jemand etwas genauer darlegen, wie der Pointer in den Code kommt, 
soass sizeof auf 2 kommt statt auf 6? Dass es so ist nehme ich mal an, 
denn sonst wäre das Problem keins gewesen. Ich kann aber beim besten 
Willen der Erklärung nicht folgen.

Vielen Dank,

Armin.

[Dirk B. (dirkb2)]

ArminLinder schrieb:
> Ebenso bei der Übergabe an die WOL Funktion: ich sehe den Pointer nicht.

Bei Funktionsparametern zerfällt das Array automatisch zu einem Pointer 
auf den Anfang des Arrays. C Grundlagen.

[Einer K. (Gast)]

ArminLinder schrieb:
> Deswegen müsste sizeof mac eigentlich 6 zurückgeben,

Vollkommen Richtig.
Tut es auch.
(wenn man es nicht vorher durch die Parameter Mühle verfälscht)

Dirk B. schrieb:
> Bei Funktionsparametern zerfällt das Array automatisch zu einem Pointer.
>  C Grundlagen.
Arduino spielt das Lied in C++
Man kann das also auch unterbinden. (Referenz übergeben oder/und als 
Array Typisieren)

ArminLinder schrieb:
> Ich kann aber beim besten
> Willen der Erklärung nicht folgen.
C++ führt die Größe im Datentype mit

using MyArrayType = byte[6];

MyArrayType macA { 0x90, 0xA2, 0xDA, 0x0D, 0xB1, 0xAC };


//--

byte macB[] { 0x90, 0xA2, 0xDA, 0x0D, 0xB1, 0xAC };

sizeof(MyArrayType) // sagt 6
sizeof(macA) // sagt 6
sizeof(macB) // sagt 6

Eine klügere Definition der Funktion sollte wohl in etwa so aussehen:

void WOL(const MyArrayType &mac) 
{
   Serial.println(sizeof mac);
}

[Dirk B. (dirkb2)]

Arduino Fanboy D. schrieb:
> Arduino spielt das Lied in C++

Das sind Raw-Arrays wie in C.

Was du da schreibst ist nicht das Problem.


Schau dir die Zeile

Udp.write(mac, sizeof mac);

im Eröffnungspost an und sag, wieviel Byte da gesendet werden.

[Einer K. (Gast)]

Dirk B. schrieb:
> und sag
Nix sage ich dazu!
Ist alles gesagt!

[Cyblord -. (cyblord)]

Arduino Fanboy D. schrieb:
> Dirk B. schrieb:
>> und sag
> Nix sage ich dazu!
> Ist alles gesagt!

Aber noch nicht von jedem. Merke dir: Die Oper ist erst zu Ende wenn die 
dicke Dame gesungen hat.

[John (Gast)]

Arduino Fanboy D. schrieb:

> Nix sage ich dazu!
> Ist alles gesagt!

Arduino Fanboy eben. Große Klappe und nix dahinter.

[Einer K. (Gast)]

John schrieb:
> Arduino Fanboy eben. Große Klappe und nix dahinter.

Schwachmat!


Wenn du nicht kapierst, wie man das

Dirk B. schrieb:
> zerfällt das Array automatisch zu einem Pointer
In C++ unterbindet, dann gute Nacht.