Multiplizierer für zwei 3 Bit-Zahlen

[Maria S. (Firma: KIT) (slowargent29)]

Multiplizierer für zwei 3 Bit-Zahlen

Anstatt der Addition aus Teil 1 soll nun eine Multiplikation ausgeführt 
werden. Im Fall einer Bereichsüberschreitung wird bei einem positiven 
Resultat die maximal mit Z darstellbare positive Zahl angezeigt. Ist das 
Resultat bei einer Bereichsüberschreitung negativ, so wird die minimal 
darstellbare negative Zahl angezeigt.


Unserer Vorüberlegung:

library ieee ;
use ieee.std_logic_1164.all;
use ieee.numeric_std.all;
entity Multi is
port(
   A, B : in signed(2 downto 0); 
    Z : out signed(7 downto 0)
     
    );
end entity Multi;
architecture behavior of Multi is
  
      signal X : signed (3 downto 0);
    signal Y : signed (3 downto 0);
     signal z1 : signed (7 downto 0);
    
 begin
  X<=('0' & A);
  Y<=('0' & B);
  main :process( X, Y)
     begin
            
   z1 <=   X * Y;
    if  z1  > "00000111"  then 
           z1 <= "00001111" ;
       elsif  z1 < "11111000" then 
              z1 <= "00001000"  ;
   end if ; 
    z<=z1;
  end process main;
       
   
end behavior;

-> erbitten um geeigneten Lösungsvorschlag :)

[Martin K. (mkmannheim)]

Da fehlt wohl noch ein ELSE für den Fall, dass der Bereich ok ist.

[Maria S. (Firma: KIT) (slowargent29)]

mit Else sind wir nicht zum Erfolg bekommen. Erbitte genaueren 
Lösungsvorschlag.

[Lothar M. (Firma: Titel) (lkmiller) (Moderator)]

Maria S. schrieb:
> -> erbitten um geeigneten Lösungsvorschlag :)
Was funktioniert mit dem geposteten Vorschlag nicht? Was erwartet ihr, 
was passiert stattdessen? Was sagt der Simulator? Wie lässt sich das 
erklären?

Martin K. schrieb:
> Da fehlt wohl noch ein ELSE für den Fall, dass der Bereich ok ist.
Das ist nicht das Problem, denn wenn alles ok ist, muss nach der 
Multiplikation eh' nichts mehr gemacht werden.

Das einfach Problem hier ist das Verhalten von Signalen in Prozessen. 
Das Signal z1 übernimmt das Ergebnis der Multiplikation nicht sofort, 
sondern erst am Ende des Prozesses. Für solche Berechnungen muss das 
Zwischenergebnis z1 eine Variable sein.

Alternativ würde es reichen, wenn z1 in die Sensitivliste aufgenommen 
wird, damit der Prozess nach Zuweisung eines neuen Wertes an z1 noch 
einmal durchlaufen wird.

Alternativ: die Aufgabe einfach ohne Prozess lösen. Und genau so würde 
ich das machen:

library ieee ;
use ieee.std_logic_1164.all;
use ieee.numeric_std.all;
entity Multi is
port(
   A, B : in signed(2 downto 0); 
    Z : out signed(7 downto 0)
     
    );
end entity Multi;
architecture behavior of Multi is
  
   signal X  : signed (3 downto 0);
   signal Y  : signed (3 downto 0);
   signal z1 : signed (7 downto 0);
    
begin

   X <= ('0' & A);
   Y <= ('0' & B);
         
   z1 <=   X * Y;

   z <= "00001111" when  z1 > "00000111"  else 
        "00001000" when  z1 < "11111000"  else
        z1;
   
end behavior;

Wozu für jeden Witz einen Prozess anfangen?

[Duke Scarring (Gast)]

Maria S. schrieb:
>     if  z1  > "00000111"  then
>            z1 <= "00001111" ;
>        elsif  z1 < "11111000" then
>               z1 <= "00001000"  ;
>    end if ;

Da hier der Datentyp signed verwendet wird, kann man das lesbarer mit 
Integern hinschreiben:

  if  z1 > 7 then
    z1 <= to_signed( 15, z1'length);
  elsif  z1 < -8 then
    z1 <= to_signed(  8, z1'length);
  else
    z1 <= z1;   -- überflüssig, erhöht aber ebenfalls das Verständnis beim Lesen
  end if ;

Dann fällt eventuell auch auf, warum das nicht wie gewünscht 
funktioniert.

Der Tipp von Lothar erhöht m.E. ebenfalls die Lesbarkeit, wobei ich noch 
anzumerken hätte, das statt
> X <= ('0' & A);
> Y <= ('0' & B);
resize angebracht wäre, damit es auch mit negativen Zahlen stimmt:

  X <= resize( A, X'length);
  Y <= resize( B, Y'length);

Duke

[Lothar M. (Firma: Titel) (lkmiller) (Moderator)]

Duke Scarring schrieb:
> Der Tipp von Lothar erhöht m.E. ebenfalls die Lesbarkeit, wobei ich noch
> anzumerken hätte, das statt
>> X <= ('0' & A);
>> Y <= ('0' & B);
> resize angebracht wäre, damit es auch mit negativen Zahlen stimmt:
Korrekt, denn sonst müsste man nicht hinterher den negativen Bereich 
abfragen, weil ja eh' nur positive Werte herauskommen können...

Wers unbedingt zu Fuß machen will, der kann auch einfach das MSB nochmal 
vorn anhängen:

  X <= A(2) & A;
  Y <= B(2) & B;