[ASM] AND von 2 Registern

[BaeumeKommunizierenElektromagnetisch (Gast)]

Hallo zsm,

ich habe mir eine Routine fuer eine 4x4 Tasten Matrix geschrieben welche 
funktioniert und im Einsatz ist. Nun bin ich am Optimieren meiner Zeilen 
und habe keine Erklaerung dafuer warum ich den Befehl AND nicht so 
anwenden kann wie er gedacht ist.

Hier ein kleiner Auszug bei dem ich Reihe 1 auf High schalte und Spalte 
1 (Taste "1") abfrage ob sie gedrueckt worden ist, nach dieser Taste 
springe ich dann zur Abfrage Taste "2", "3", "A", .. naechste Reihe, 
etc:

; Bitmuster laden
lds  r1, 0b00000010  ; PORTB - PIN 1
lds  r2, 0b00000100  ; PORTB - PIN 2
lds  r3, 0b00001000  ; PORTB - PIN 3
lds  r4, 0b00000001  ; PORTC - PIN 0
; /Bitmuster laden Ende

Start_Scan:
sbi  PORTB, 0  ; Erste Reihe (1, 2, 3, A) auf high setzen  
nop
nop
nop

in  r19, PINB  ; Status vom Port einlesen
and  r19, r1    ; Nur wenn Taste auf High war, dann ist Bit 2 nun auch High
cpi  r19, 0b00000010      
brne  row1_ende  ; BRanche if Not Equal
rcall  delay5ms  ; kurz warten
      
in  r19, PINB  ; Nochmal Status einlesen      
and  r19, r1    ; gezieltes Bit auf High setzen      
cpi  r19, 0b00000010  ; War sie gedrueckt?
brne  row1_ende

ldi  r16, '1'  ; Dann machen wir was, wenn nicht dann restliche Tasten abfragen
rcall  LCD_DATA

row1_ende:
      
cbi  PORTB, 0
rcall  D250_ms    ; Kleine Verzoegerung um doppeltes Druecken zu vermeiden

rjmp  Start_Scan

Ziel ist es flexibel zu sein und anhand der Verdrahtung das jeweiligen 
Bitmuster oben in vier untere Register zu laden. Doch der AND Befehl 
funktioniert nicht, es findet keine uebereinstimmung statt brne springt 
immer zum Punkt "row1_ende"

Ersetze ich

and  r19, r1

mit ANDI (UND Register -> Konstante) direkt mit der Konstante:

andi  r19, 0b00000010

dann funktioniert es. Diese Feststellung habe ich am Mega328P gemacht 
und auf einem anderen Controller noch nicht getestet.

Kann mir Jemand ein Tipp geben?

[(prx) A. K. (prx)]

BaeumeKommunizierenElektromagnetisch schrieb:
> lds  r1, 0b00000010  ; PORTB - PIN 1

Wenn das kein Xmega ist, ist das R1 = R2.

[S. Landolt (Gast)]

lds ist nicht ldi (was auf r1 ohnehin nicht geht)

[Marc V. (Firma: Vescomp) (logarithmus)]

BaeumeKommunizierenElektromagnetisch schrieb:
> Kann mir Jemand ein Tipp geben?

Ja.

   lds  r1, 0b00000010  ; PORTB - PIN 1

Das ist sicher nicht PB.1, du hast r1 mit Inhalt der Adresse 0x02 
geladen.
Richtig wäre:

   ldi  r16, 0b00000010  ; PORTB - PIN 1
   mov r1, r16

[Marc V. (Firma: Vescomp) (logarithmus)]

BaeumeKommunizierenElektromagnetisch schrieb:
> Nun bin ich am Optimieren meiner Zeilen

Wenn es um Optimieren geht:
Folgendes:

lds  r1, 0b00000010  ; PORTB - PIN 1
lds  r2, 0b00000100  ; PORTB - PIN 2
lds  r3, 0b00001000  ; PORTB - PIN 3
lds  r4, 0b00000001  ; PORTC - PIN 0

ersetzen mit:

.EQU Spalte0 = 0x01 ; Tasten an PINC.1
.EQU Spalte1 = 0x02 ;
.EQU Spalte2 = 0x04 ;
.EQU Spalte3 = 0x08 ;
.EQU AnyKey  = 0x0E ; Irgendeine Taste an PINB.1 - PINB.3

Warum?
Weil es nicht sehr smart ist, irgendwelche register (und insbesondere
r0/r1) mit konstanten Werten zu laden und somit vom späteren
Gebrauch auszuschließen.

Und dann folgendes:

in  r19, PINB          ; Status einlesen      
and  r19, r1           ; gezieltes Bit auf High setzen      
cpi  r19, 0b00000010   ; War sie gedrueckt?
brne  row1_ende

mit folgendem ersetzen:

KeyChk_B:
in    r19, PINB        ; Status einlesen      
andi  r19, AnyKey      ; War überhaupt irgendeine Taste gedrückt?
breq  row1_ende        ; Keine Taste gedrückt, überspringe alle weiteren prüfungen für PINB
;***  Irgendeine Taste in 3 Reihen für PINB war gedrückt
in    r19, PINB        ; Nochmal Status einlesen      
andi  r19, Spalte1     ; War sie gedrueckt?      
breq  row1_ende

Nicht ausprobiert, keine Garantie.
CopyLeft by ich, All Wrongs Reserved.