Mehrere Zufallsgeneratoren an verschiedenen PWM Ausgängen

[Nur geklaut (Gast)]

Guten Abend euch.

Bei meinem kleinen Projekt dachte ich, dass ich nicht auf Probleme 
stoße, aber dann kam es doch dazu und meine Experimente schlugen alle 
fehl.

Ich habe einen Attiny44a mit 4 PWM Aushängen, die ich alle mit jeweils 
einer LED belegt habe. Das soll nur ein kleines Programm für 4 "Kerzen" 
sein. Ich möchte aber bei jeder Kerze einen anderen Zufallsgenerator 
haben, also Helligkeit und Intervall einstellen.
Das Grundprogramm habe ich nur geklaut und etwas angepasst:

int LED1 = 8;

int LED2 = 7;

int LED3 = 6;

int LED4 = 5;

int val = 0;                     // variable Helligkeit

int delayval = 0;                // variable Wartezeit

void setup() {

randomSeed(0);                // Zufallszahlengenerator

pinMode(LED1, OUTPUT);

pinMode(LED2, OUTPUT);

pinMode(LED3, OUTPUT);

pinMode(LED4, OUTPUT);
}

void loop() {

val = random(70, 200);
  analogWrite(LED1, val);

val = random(40, 255);
  analogWrite(LED2, val);

val = random(100, 230);
  analogWrite(LED3, val);

val = random(10, 190);
  analogWrite(LED4, val);

delayval = random(250, 800);
  delay(delayval);
}


Nun ist mir schon klar, dass mein Intervall der Wartezeit so auf alle 4 
LEDs zutrifft. Aber ich habe es nicht hinbekommen, dass ich für jede LED 
ein eigenes Intervall bekomme. Also z.B. LED1 flimmert durchgehend sehr 
langsam (100, 250), LED2 durchgehend sehr schnell (600, 800) usw.. Bei 
mir flimmert es nur dunkel im Kopf... ich befürchte, das ist ein ganz 
simples Ding. Oder ist das wieder ein typisches "das geht nicht mit 
delay"?

Ich bedanke mich für Lösungen,Anregungen und Schimpfe ;)

Schöne Grüße

[Jim M. (turboj)]

Nur geklaut schrieb:
> Aber ich habe es nicht hinbekommen, dass ich für jede LED
> ein eigenes Intervall bekomme

Wieso eigentlich nicht? Ein Zähler + etwas Modulo Artithmetik pro LED. 
Idee ist das nicht jede LED bei jedem Delay geändert wird sondern nur 
bei jedem 2. oder 3. oder ähnlich...

[Wolfgang (Gast)]

Nur geklaut schrieb:
> Oder ist das wieder ein typisches "das geht nicht mit
> delay"?

Richtig, du solltest nicht mit einem gemeinsamen, zufälligen Delay 
arbeiten.
Nimm ein festes, kurzes delay() oder werte besser mit millis() den 
Millisekundentaktgeber aus. Wie häufig eine LED ihren Zustand ändert, 
legst du dann mit einem für jede LED persönlich zugeordneten Zähler 
zufällig fest.

[Nur geklaut (Gast)]

Danke euch Beiden.
Von Jim verstehe ich leider gar nichts, das ist mir ne Nummer zu hoch.
Das was Wolfang hört sich schon einfacher an, aber es war auch meine 
Befürchtung. Mit millis habe ich noch nie rumgespielt, wird dann wohl 
viel zu lesen. Gibt es gute Tutorials auf Deutsch?

[Nur geklaut (Gast)]

Nur geklaut schrieb:
> Wolfang

Das erste g wollte leider nicht mit ;)

[Falk B. (falk)]

Nur geklaut schrieb:

> mir flimmert es nur dunkel im Kopf... ich befürchte, das ist ein ganz
> simples Ding. Oder ist das wieder ein typisches "das geht nicht mit
> delay"?

BINGO! DU bist der 735503635te, der das Thema Multitasking entdeckt.

Beitrag "Re: 20 LEDs unterschiedlich blinken lassen"

Dort kann man auch live Zufallszahlen füttern.

[EAF (Gast)]

Nur geklaut schrieb:
> das ist mir ne Nummer zu hoch.
Ja, das kann ich dir bieten!

 
class SimpleTimer
{
  private:
  uint32_t timeStamp;      // Zeitmerker
  bool reached;            // default Status: timer abgelaufen

  public:
  SimpleTimer():timeStamp(0),reached(true){}
  
  void start()
  {
    timeStamp   = millis();
    reached     = false;
  }
  
  void reset()
  {
     reached     = true;
  }

  bool operator()(const uint32_t interval) 
  {
    if(!reached) reached = millis() - timeStamp >= interval;
    return reached;
  }
};


class PWMmacher
{
  private:
  const byte pin;
  unsigned long interval;
  SimpleTimer timer;

  public:
  PWMmacher(const byte pin):pin{pin}{}
  void run()
  {
    if(timer(interval))
    {
      timer.start();
      interval = random(400,3000);
      analogWrite(pin,random(0,256));
    }
  }
};

PWMmacher pwm[]{3,5,6,9,10,11,};// UNO pwm pins

void setup() {}

void loop() 
{
  for(auto &p:pwm)p.run();
}

[EAF (Gast)]

Nachtrag: (der Konstruktor sollte evtl so aussehen)
PWMmacher(const byte pin):pin{pin},interval{0}{}

[Da Baby (Gast)]

Nimm einen Timer und stelle die Frequenz so ein, dass ein Überlauf der 
obersten Intervallgrenze entspricht. Pro Takt wird der Zähler um eins 
hochgezählt. Dann rätst du 4 Zufallszahlen und aktivierst je nach 
Zählerstand eine der vier LEDs. Danach kannst du das selbe machen um die 
LEDs wieder auszuschalten.

[Jobst M. (jobstens-de)]

Nur geklaut schrieb:
> Wartezeit

Wieso meinst Du, dass Du die zufälligen Helligkeitswerte mit zufälligen 
Zeiten takten musst?
Du benötigst einen Tiefpass, sonst wirkt das immer etwas hektisch.

Gruß
Jobst

[Nur geklaut (Gast)]

Danke allen! Ich nehme mir das zu Herzen und gehe es morgen mal alles in 
Ruhe durch. Das ist für mich zwar viel Fachchinesisch, aber die paar 
Tipps lassen mich dann auch besser googlen ;)

[Da Baby (Gast)]

Nur geklaut schrieb:
> Danke allen! Ich nehme mir das zu Herzen und gehe es morgen mal
> alles in
> Ruhe durch. Das ist für mich zwar viel Fachchinesisch, aber die paar
> Tipps lassen mich dann auch besser googlen ;)

Im Grunde musst du nur das von EAF kopieren. Das ist eine fertig Lösung.
Nur eben in C++

[EAF (Gast)]

Ach....


Eigentlich wollte ich diesen Zustand
> Bei mir flimmert es nur dunkel im Kopf
etwas optimieren.
Quasi das Maximum raus holen.

[Wolfgang (Gast)]

Da Baby schrieb:
> Im Grunde musst du nur das von EAF kopieren. Das ist eine fertig Lösung.

Eher nicht.
An Stelle der direkten Ausgabe von Zufallszahl mit analogWrite()
ist es schon ratsam, die Werte erstmal durch ein digitales 
Tiefpassfilter laufen zu lassen und erst die geglätteten Werte zur 
Steuerung der Ausgangs-PWM zu verwenden.

Jobst M. schrieb:
> Du benötigst einen Tiefpass, sonst wirkt das immer etwas hektisch.